Kako paketno izbrisati vsa potrdila o branju v vašem Outlooku

Da bi potrdili, da so prejemniki prebrali vaše e-poštno sporočilo, lahko med pisanjem e-poštnega sporočila zahtevate potrdilo o branju. V tem primeru je vaš poštni predal lahko poln takšnih potrdil o branju. V tej objavi se boste naučili, kako jih trajno izbrisati.

Po branju članka “Kako paketno izbrisati vsa potrdila o dostavi v Outlooku«, lahko pomislite na pristop k množičnemu brisanju vseh potrdil o branju. Pravzaprav je očitna razlika med obema vrstama prejemkov njihov predmet. Potrdilo o dostavi v zadevi vsebuje »Dostavljeno«, potrdilo o branju pa namesto tega vsebuje »Prebrano«. Zato lahko uporabite enak način za paketno brisanje vseh potrdil o branju. V nadaljevanju vas bomo podrobno naučili konkretnih korakov.

Paketno brisanje vseh potrdil o branju

1. Na začetku zaženite Outlook.
2. Nato pojdite v urejevalnik Outlook VBA prek »Alt + F11« glede na »Kako zagnati kodo VBA v Outlooku".
3. Nato v novem oknu odprite prazen modul in vanj vstavite naslednjo kodo.

Dim objOutlookFile As Outlook.Folder

Sub BatchDeleteAllReadReceipts()
    Dim objStore As Outlook.Store
    Dim objFolder As Outlook.Folder
    Dim lTotalCount As Long
 
    lTotalCount = 0
   'Process all Outlook files
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olMailItem Then
               Call ProcessFolders(objFolder, lTotalCount)
            End If
        Next
    Next
 
    'Prompt you of the results
    MsgBox lTotalCount & " read receipts are deleted!", vbInformation + vbOKOnly
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder, lCount As Long)
    Dim i As Long
    Dim objDeliveryReceipt As Outlook.ReportItem
    Dim objSubfolder As Outlook.Folder
    Dim objDeletedItems As Outlook.Items
    Dim objItem As Object
 
    For i = objCurrentFolder.Items.Count To 1 Step -1
        'Find read receipts
        If (TypeOf objCurrentFolder.Items(i) Is ReportItem) And (Left(objCurrentFolder.Items(i).Subject, 5) = "Read:") Then
           Set objDeliveryReceipt = objCurrentFolder.Items.Item(i)
           objDeliveryReceipt.Delete
 
           lCount = lCount + 1
 
           'Permanently delete them
           Set objDeletedItems = objOutlookFile.Folders("Deleted Items").Items
           For Each objItem In objDeletedItems
               If (TypeOf objItem Is ReportItem) And (Left(objItem.Subject, 5) = "Read:") Then
                  objItem.Delete
               End If
           Next
         End If
    Next
 
    'Loop subfolders recursively
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder, lCount)
       Next
    End If
End Sub

4. Nato kliknite prvi podprogram.
5. Na koncu pritisnite tipko "F5".
6. Naenkrat bo makro deloval tako, da bo iz Outlooka izbrisal vsa potrdila o branju.
7. Ko se konča, boste prejeli poziv o rezultatu, kot je spodnji posnetek zaslona.
8. Trenutno lahko preverite svoje poštne mape. Vsa potrdila o branju so izginila.

Zaščitite Outlookove podatke

Čeprav je Outlookova datoteka res dovzetna za poškodbe, jo lahko zaščitimo. Outlookovo datoteko bi morali na primer imeti majhno, jo zaščititi pred zlonamernimi dejavniki in jo redno varnostno kopirati. Nenazadnje je bolje, da pripravite močno zunanje orodje za popravilo PST, kot je DataNumen Outlook Repair. To bo močno vplivalo na popravilo pokvarjen Outlook Datoteka.

Uvod avtorja:

Shirley Zhang je strokovnjakinja za obnovitev podatkov v DataNumen, Inc., ki je vodilna na svetu na področju tehnologij za obnovitev podatkov, vključno z popravilo sql in obeti za popravilo programskih izdelkov. Za več informacij obiščite www.datanumen.com