Kako samodejno zabeležiti skupno število dohodnih e-poštnih sporočil vsak dan v datoteko Excel

Ta članek vas bo naučil, kako omogočiti Outlooku, da samodejno prešteje, koliko e-poštnih sporočil ste prejeli vsak dan, in zapiše številko v Excelovo datoteko.

Mnogi uporabniki morajo prešteti skupno število prejetih e-poštnih sporočil vsak dan. Poleg tega so mnogi za bolj priročno preverjanje v prihodnosti navajeni, da skupno število zapisujejo v datoteko Excel. V tem primeru se seveda lahko odločite za ročno štetje in beleženje vsak dan. Vendar je nekoliko težavno. In morda boste včasih pozabili to narediti. Zato si morate želeti priročno metodo, s katero lahko Outlook naredi samodejno. Kot odgovor na to zahtevo vas bomo v nadaljevanju naučili, kako uporabljati VBA za njeno realizacijo.

Samodejno zabeleži skupno število dohodnih e-poštnih sporočil vsak dan v datoteko Excel

1. Na začetku zaženite aplikacijo Outlook.
2. Nato v glavnem Outlookovem oknu pritisnite bližnjične tipke »Alt + F11«.
3. Nato v pojavnem oknu urejevalnika VBA odprite projekt »ThisOutlookSession«.
4. Nato v ta projekt kopirajte in prilepite naslednje kode VBA.

Private Sub Application_Reminder(ByVal Item As Object)
    If Item.Class = olTask And Item.Subject = "Update Email Count" Then
       Call GetAllInboxFolders
    End If
End Sub

Private Sub GetAllInboxFolders()
    Dim objInboxFolder As Outlook.Folder
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim lEmailCount As Long
 
    lEmailCount = 0
    Set objInboxFolder = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Call UpdateEmailCount(objInboxFolder, lEmailCount)
 
    ‘Change the path to the Excel file
    strExcelFile = "E:\Email\Email Count.xlsx"
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorksheet.Range("B" & nNextEmptyRow) = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
    objExcelWorksheet.Range("C" & nNextEmptyRow) = lEmailCount
 
    'Fit the columns from A to C
    objExcelWorksheet.Columns("A:C").AutoFit
   
    'Save the changes and close the Excel file
    objExcelWorkbook.Close SaveChanges:=True
End Sub

Private Sub UpdateEmailCount(objFolder As Outlook.Folder, ByRef lCurEmailCount As Long)
    Dim objItems As Outlook.Items
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim strDay As String
    Dim strReceivedDate As String
    Dim lEmailCount As Long
    Dim objSubFolder As Outlook.Folder
 
    Set objItems = objFolder.Items
 
    objItems.SetColumns ("ReceivedTime")
    strDay = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
 
    For Each objItem In objItems
        If objItem.Class = olMail Then
           Set objMail = objItem
           strReceivedDate = Year(objMail.ReceivedTime) & "-" & Month(objMail.ReceivedTime) & "-" & Day(objMail.ReceivedTime)
           If strReceivedDate = strDay Then
              lCurEmailCount = lCurEmailCount + 1
           End If
        End If
    Next
 
    'Process the subfolders in the folder recursively
    If (objFolder.Folders.Count > 0) Then
       For Each objSubFolder In objFolder.Folders
           Call UpdateEmailCount(objSubFolder, lCurEmailCount)
       Next
    End If
End Sub

5. Nato podpišite to kodo in spremenite nastavitve Outlookovih makrov, da omogočite podpisane makre.
6. Po tem morate vsak dan ustvariti ponavljajočo se nalogo.

• Najprej kliknite gumb »Novo opravilo« v podoknu opravil.
• V pojavnem oknu Novo opravilo kliknite gumb »Ponovitev«.
• Nato v naslednjem pogovornem oknu izberite »Dnevno«, »Vsak 1 dan(-e)« in »Brez končnega datuma« ter nazadnje pritisnite »V redu«.
• Pozneje spremenite predmet naloge in opomnik glede na vaše potrebe.
• Na koncu kliknite gumb »Shrani in zapri«.

7. Od zdaj naprej bo Outlook ob vsakem opozorilu opomnika za to opravilo samodejno preštel včeraj prejeta e-poštna sporočila in nato zabeležil številko v Excelovo datoteko, kot je ta posnetek zaslona:

Pobegnite pred trajno izgubo podatkov PST

Nihče ni pripravljen sprejeti trajne izgube podatkov PST. Vendar je datoteka Outlook PST nagnjena k poškodbam. Zato morate sprejeti ustrezne previdnostne ukrepe, kot je izdelava dosledne in posodobljene varnostne kopije podatkov PST in ohranjanje zmogljive Obnovitev PST orodje v bližini, všeč DataNumen Outlook Repair.

Uvod avtorja:

Shirley Zhang je strokovnjakinja za obnovitev podatkov v DataNumen, Inc., ki je vodilna na svetu na področju tehnologij za obnovitev podatkov, vključno z popravilo sql in obeti za popravilo programskih izdelkov. Za več informacij obiščite www.datanumen.com