3 načini za hitro vstavljanje prelomov razdelkov v vaš Wordov dokument

V tem članku se bomo osredotočili na to, da vam pokažemo 3 načine za hitro vstavljanje prelomov razdelkov v Wordov dokument.

Prelomi odsekov so uporabni za razdelitev dokumenta na odseke, poglavja itd. Poleg tega je vstavljanje prelomov odsekov nepogrešljiv del nastavljanja različnih glav ali nog na različnih straneh.

Običajno se bomo morali pomakniti do strani in poiskati kazalec na pravilnem položaju. Nato kliknite »Postavitev strani« in »Prelomi«. Nato v spustnem meniju izberite vrsto preloma razdelka. Takšen postopek je lahko včasih dolgočasen. Zato vas želimo rešiti običajne rutine in sprejeti hitro in umazano rešitev.

1. način: Vstavite prelom razdelka na določeno stran

1. Najprej v Wordu pritisnite »Alt+ F11«, da pokličete urejevalnik VBA.
2. Nato ustvarite nov modul s klikom na »Normal« v levem stolpcu.
3. Nato v menijski vrstici kliknite jeziček »Vstavi«.
4. In v spustnem meniju »Vstavi« izberite »Modul«.
5. Dvokliknite nov modul, da ga odprete.
6. Na območje kodiranja prilepite naslednji makro:

Sub InsertBreakOnSpecificPage()
  Dim strPageNum As String
  Dim nPageNum As Integer
 
  strPageNum = InputBox("Enter a page number: ")
  nPageNum = Int(strPageNum)
 
  Selection.GoTo What:=wdGoToPage, Which:=wdGoToNext, Name:=nPageNum
  ActiveDocument.Bookmarks("\page").Range.Select
  Selection.Collapse wdCollapseEnd
  Selection.InsertBreak Type:=wdSectionBreakContinuous
End Sub

7. Zdaj kliknite »Zaženi« ali pritisnite »F5«, da izvedete kode.
8. Nato v polje za poziv vnesite številko ciljne strani. In za nadaljevanje kliknite »V redu«.

Doslej ste vstavili prelom razdelka na koncu 2. strani.

Opombe:

Če želite več zaporednih strani ločiti kot odsek z uporabo prelomov odsekov, morate dvakrat vstaviti prelom odseka, enega na koncu zadnje strani prejšnjega odseka in enega na koncu zadnje strani tega novega odseka. .

V takem primeru si med vstavljanjem prvega preloma ne pozabite vnesti pravilne številke, ki je številka strani zadnje strani prejšnjega razdelka.

2. način: Vstavite prelom odseka na vsako stran dokumenta

1. Najprej namestite in zaženite makro natančno po zgornjih korakih.
2. Nato makro zamenjajte s tem:

Sub InsertBreakOnEachPage()
  Dim nTotalPageNumber As Integer
 
  For nTotalPageNumber = 1 To Selection.Information(wdNumberOfPagesInDocument)
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToNext, Name:=nTotalPageNumber
    Application.Browser.Target = wdBrowsePage
    ActiveDocument.Bookmarks("\page").Range.Select
    Selection.Collapse wdCollapseEnd
    Selection.InsertBreak Type:=wdSectionBreakContinuous
  Next
End Sub

Ta makro vstavi prelom razdelka na konec vsake strani trenutnega dokumenta.

3. način: Vstavite prelom razdelka na vsako stran več dokumentov

1. Za začetek shranite vse ciljne dokumente v isto mapo.
2. Nato podobno namestite in zaženite makro z ustreznimi navodili.
3. Tokrat uporabite te kode:

Sub InsertBreaksIntoMultiDoc()
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim nTotalPageNumber As Integer
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "No folder is selected! Please select the target folder."
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.docx", vbNormal)
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    For nTotalPageNumber = 1 To Selection.Information(wdNumberOfPagesInDocument)
      Selection.GoTo What:=wdGoToPage, Which:=wdGoToNext, Name:=nTotalPageNumber
      Application.Browser.Target = wdBrowsePage
      ActiveDocument.Bookmarks("\page").Range.Select
      Selection.Collapse wdCollapseEnd
      Selection.InsertBreak Type:=wdSectionBreakContinuous
    Next
    objDoc.Save
    objDoc.Close
    strFile = Dir()
  Wend
End Sub

4. Makro bo sprožil okno »Prebrskaj«. Izberite mapo, v kateri imate dokumente, in kliknite »V redu«.

Postopek ne sme trajati več kot nekaj sekund.

Priročno orodje za poškodovanje dokumentov

Naleteti na poškodovane dokumente je neprijetno. V takem primeru je dobro in zanesljivo orodje, ki lahko pomaga popravilo Word dokumenti bodo lahko precej razbremenili človekovo tesnobo. Zato morate biti pri izbiri orodja za popravilo zelo previdni. Nezadostna uporabnost lahko povzroči nadaljnjo škodo.

Uvod avtorja:

Vera Chen je strokovnjakinja za obnovitev podatkov v DataNumen, Inc., ki je vodilna na svetu na področju tehnologij za obnovitev podatkov, vključno z Excel obnovitev in pdf popravilo programskih izdelkov. Za več informacij obiščite www.datanumen.com