2 načina za tiskanje seznamov Outlook nalog z različnimi kategorijami na različnih straneh

Če ste opravilom v Outlooku dodelili različne barvne kategorije in želite na različne strani natisniti sezname opravil z različnimi kategorijami, se lahko obrnete na ta članek. Tukaj vam bomo delili 2 metodi, kako to dobiti.

Da bi razvrstili in dobro upravljali svoje naloge, ste morda za svoje naloge uporabili barvne kategorije. Če želite zdaj na različne strani natisniti sezname svojih nalog z različnimi kategorijami, preberite. V nadaljevanju vam bomo predstavili dva načina, kako ga dobiti.

1. način: Ročno natisnite sezname opravil enega za drugim

1. Najprej v Outlooku odprite podokno »Opravila«.
2. Nato odprite mapo Opravila.
3. Nato pritisnite »Ctrl + E«, da aktivirate trak »Iskanje«.
4. Po tem na zavihku »Išči« kliknite gumb »Kategoriziraj«.
5. Na spustnem seznamu izberite barvno kategorijo.
6. Nato bodo na seznamu ostale samo naloge z izbrano kategorijo.
7. Zdaj pojdite na "File"> "Print", da natisnete ta seznam opravil.
8. Nato na enak način ročno natisnite sezname opravil z drugimi barvnimi kategorijami.

2. način: paketno tiskanje seznamov opravil s strani VBA

1. Na začetku sprožite urejevalnik VBA v skladu z “Kako zagnati kodo VBA v Outlooku".
2. Nato dodajte sklic na »Knjižnico objektov MS Excel«, kot je navedeno v »Kako dodati referenco knjižnice objektov v VBA".
3. Nato v modul kopirajte naslednjo kodo VBA.

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. Nato pritisnite tipko “F5”, da takoj zaženete ta makro.
5. Ko se makro konča, bodo seznami nalog z različnimi kategorijami natisnjeni na različnih straneh, kot je prikazano na naslednjem posnetku zaslona.

Vrnite dragocene podatke iz ogrožene datoteke PST

Če imate nedostopno datoteko PST, je vaš naslednji korak nedvomno Popravilo PST. V tem primeru lahko najprej preizkusite orodje za popravilo mape »Prejeto«. Če ne uspe, lahko nadaljujete s poskusom drugega zunanjega orodja, kot je DataNumen Outlook Repair. Podatke PST lahko hitro obnovi.

Uvod avtorja:

Shirley Zhang je strokovnjakinja za obnovitev podatkov v DataNumen, Inc., ki je vodilna na svetu na področju tehnologij za obnovitev podatkov, vključno z izterjati mdf in obeti za popravilo programskih izdelkov. Za več informacij obiščite www.datanumen.com