2 načina za skupinsko brisanje vseh stikov brez e-poštnega naslova v vašem Outlooku

Če ugotovite, da nekateri stiki v Outlooku nimajo e-poštnega naslova, boste morda želeli obdelati vsako mapo s stiki, da izbrišete vse take stike. V tej objavi bomo z vami delili dva načina.

Morda imate v Outlooku veliko stikov in nekateri od njih nimajo e-poštnega naslova. Če menite, da niso več uporabni, upajte, da boste izbrisali vse stike brez e-poštnega naslova. Na običajen način lahko uporabite »Takojšnje iskanje«, da jih poiščete in nato ročno izbrišete, kot je naslednja 1. metoda. Vendar je nekoliko dolgočasno. Zato vas bomo v 2. metodi naučili drugega učinkovitejšega načina.

1. način: ročno brisanje po iskanju stikov brez e-poštnega naslova

1. Za začetek pritisnite tipki »Ctrl + 3« za dostop do podokna »Stiki«.
2. Nato kliknite v iskalno polje.
3. Nato v nastajajočem traku »Iskanje« kliknite »Vsi elementi stikov«.
4. Nato kliknite »Ima naslov« > »Ima e-poštni naslov«.
5. Po tem bo v iskalno polje dodan kriterij »NOT emailaddresses:=[]«. Odstraniti morate "NE".
6. Nato bodo navedeni vsi stiki brez e-poštnega naslova.
7. Zdaj bi morali ročno izbrati stike v rezultatih iskanja, saj morajo biti na seznamu tudi vaše skupine stikov.
8. Na koncu pritisnite gumb »Del«, da izbrišete vse izbrane stike.

2. način: paketno brisanje vseh stikov brez e-poštnega naslova z VBA

1. Najprej tapnite »Alt + F11«, da zaženete urejevalnik VBA v Outlooku.
2. Na novem zaslonu kopirajte naslednjo kodo VBA v modul.

Sub BatchDeleteAllContactsWithoutEmailAddress()
    Dim objStore As Outlook.Store
    Dim lTotalCount As Long
 
    lTotalCount = 0
    'Process all stores in your Outlook
    For Each objStore In Application.Session.Stores
       Call ProcessContactFolders(objStore.GetRootFolder.Folders, lTotalCount)
    Next
 
    MsgBox lTotalCount & " contacts are deleted!", vbInformation + vbOKOnly, "Delete Contacts"
End Sub

Sub ProcessContactFolders(ByVal objFolders As Outlook.Folders, lCount As Long)
    Dim objFolder As Outlook.Folder
    Dim i As Long
    Dim objContact As Outlook.ContactItem
    Dim objSubfolder As Outlook.Folder

    For Each objFolder In objFolders
        If (objFolder.DefaultItemType = olContactItem) And (objFolder.Name <> "Skype Contacts") Then
           For i = objFolder.Items.Count To 1 Step -1
               If objFolder.Items(i).Class = olContact Then
                  Set objContact = objFolder.Items(i)
                  'Delete the contact w/o email address
                  If (objContact.Email1Address = "") And (objContact.Email2Address = "") And (objContact.Email3Address = "") Then
                     objContact.Delete
                     lCount = lCount + 1
                  End If
               End If
           Next
 
           'Process subfolders recursively
           If objFolder.Folders.Count > 0 Then
              Call ProcessContactFolders(objFolder.Folders, lCount)
           End If
       End If
    Next
End Sub

3. Pozneje kliknite podprogram »BatchDeleteAllContactsWithoutEmailAddress«.
4. Sčasoma pritisnite "F5", da sprožite ta makro.
5. Ko se konča, boste prejeli sporočilo o rezultatih, kot je spodnja slika.
6. Vsi stiki brez e-poštnega naslova so bili premaknjeni v mapo »Izbrisani predmeti«.

Držite se daleč stran od vseh možnih tveganj

Outlook se lahko poškoduje zaradi različnih dejavnikov, kot so virusi, uporabniške napake, napake programske opreme in strojne opreme. Verjetno neradi doživite škode Outlooka, zato se morate izogibati vsem tem potencialnim tveganjem. Na primer, v računalnik morate namestiti zmogljivo protivirusno programsko opremo. Poleg tega morate redno varnostno kopirati svoje Outlookove podatke. Nenazadnje si raje pripravite robustno in zanesljivo orodje za popravilo, kot je npr DataNumen Outlook Repair. Lahko popravi vašo pokvarjen PST datoteko z lahkoto.

Uvod avtorja:

Shirley Zhang je strokovnjakinja za obnovitev podatkov v DataNumen, Inc., ki je vodilna na svetu na področju tehnologij za obnovitev podatkov, vključno z SQL Server korupcija in obeti za popravilo programskih izdelkov. Za več informacij obiščite www.datanumen.com