Como imprimir rapidamente todos os anexos de imagem de um e-mail do Outlook em apenas uma página

Para economizar tinta e papel da impressora, alguns usuários desejam imprimir todas as imagens anexadas em um e-mail em apenas uma página, em vez de uma imagem por página. Agora, este artigo irá compartilhar um meio de realizá-lo.

Como todos sabemos, imprimir imagens é um desperdício de tinta de impressora. Assim, para economizar tinta e papel da impressora, talvez você prefira imprimir muitos anexos de imagem na mesma página em vez de imprimir imagens em páginas separadas. Embora o Outlook não ofereça esse recurso, você ainda pode alcançá-lo pelos seguintes meios.

Imprimir todos os anexos de imagem de um e-mail do Outlook em apenas uma página

1. Para começar, abra o aplicativo Outlook.
2. Em seguida, na janela do Outlook, toque nos botões de teclas “Alt + F11”.
3. Em seguida, você acessará a janela “Microsoft Visual Basic for Applications”, na qual você deverá primeiro habilitar a “Biblioteca de Objetos do Microsoft Word”.
4. Depois disso, você precisa abrir um módulo que não está sendo usado.
5. Posteriormente, copie e cole o seguinte código VBA neste módulo.

Sub PrintAllImageAttachmentsOnOnePage()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim objTempMail As Outlook.MailItem
    Dim objTempDocument As Word.Document
    Dim objWordApp As Word.Application
    Dim strImage As String
    Dim objImage As Word.InlineShape
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
       'Create a temp mail
       Set objTempMail = Outlook.Application.CreateItem(olMailItem)
       objTempMail.Display
       Set objTempDocument = objTempMail.GetInspector.WordEditor
       Set objWordApp = objTempDocument.Application
 
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.attachments
           'Get the Image attachments, instead of inserted Images
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          strImage = "E:\" & objAttachment.filename
                          objAttachment.SaveAsFile strImage
 
                          'Insert the images into the temp mail
                          Set objImage = objWordApp.Selection.InlineShapes.AddPicture(filename:=strImage, LinkToFile:=False, SaveWithDocument:=True)
                          objWordApp.Selection.TypeText Text:=" "
 
                          'shrink the images to insure that they are on one page
                          objImage.ScaleHeight = 20
                          objImage.ScaleWidth = 20
 
                          Kill strImage
             End Select
           End If
       Next
 
       objTempMail.PrintOut
       objTempMail.Close olDiscard
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

6. Mais tarde, você pode voltar para a lista de e-mail. Escolha ou abra um e-mail cujos anexos de imagem você deseja imprimir.
7. Em seguida, acione esta macro. Na janela macro atual, basta pressionar a tecla “F5” ou clicar no ícone “Executar” na barra de ferramentas.
8. Por fim, quando a execução da macro terminar, todos os anexos de imagem do e-mail de origem serão impressos em uma página, como na captura de tela a seguir:

Lidar com arquivos corrompidos do Outlook

Com mais e mais dados armazenados em seu Outlook, seu arquivo do Outlook está cada vez mais vulnerável. Ele pode ficar comprometido devido a vários fatores internos e externos. Além disso, é difícil prever a corrupção do Outlook. Portanto, o que você pode fazer é garantir um resgate imediato e eficaz ao enfrentar corrupções do Outlook. Por exemplo, você tem que manter uma equipe especializada Reparação de PST ferramenta, como DataNumen Outlook Repair nas proximidades. Ele irá verificar e restaurar arquivos danificados como uma brisa.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo recuperar Sql Server e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com