Como exportar rapidamente o tempo total gasto nos compromissos do Outlook em cada categoria de cor

Se você deseja criar um relatório sobre o tempo total gasto nos compromissos em cada categoria de cor, pode utilizar o método apresentado neste artigo. Ele pode ajudá-lo a fazer isso rapidamente, sem a necessidade de contar manualmente.

Muitos usuários estão acostumados a registrar a maior parte de suas atividades no calendário do Outlook. Além disso, para facilitar o gerenciamento e a diferenciação, eles atribuem categorias a cada uma delas. Nesse caso, alguns usuários gostariam de gerar um relatório mostrando o tempo total gasto nos itens do calendário em cada categoria de cor. Sem dúvida, contar e inserir esses dados manualmente é trabalhoso. Portanto, compartilharemos aqui uma maneira de realizar essa tarefa com um simples clique.

Exportar o tempo total gasto nos compromissos em cada categoria de cor

1. Em primeiro lugar, inicie seu aplicativo Outlook.
2. Então, depois de entrar na janela do Outlook, você pode tocar nos botões de tecla “Alt + F11”.
3. Posteriormente, você terá acesso à janela “Microsoft Visual Basic for Applications”.
4. Em seguida, você precisará habilitar a “Biblioteca de Objetos do Microsoft Excel”. Para isso, clique em “Ferramentas” > “Referências”.
5. Então, você deve encontrar e abrir um módulo que não está em uso.
6. Depois disso, você precisa copiar o seguinte código VBA para este módulo.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. Finalmente, você pode acionar esta macro, não importa clicando no ícone “Executar” na barra de ferramentas ou pressionando o botão “F5”.
8. Em seguida, você será solicitado a selecionar um calendário específico.
9. Depois de selecionar e clicar em “OK”, a macro continuará a ser executada. Depois que terminar, haverá um novo arquivo do Excel exibido em segundo plano.
10. Você pode acessá-lo. Será semelhante à seguinte captura de tela:

Fique de olho nas ameaças potenciais em torno do seu Outlook

Os usuários do Outlook devem ficar atentos a todos os riscos potenciais, incluindo anexos de e-mail desconhecidos, links incorporados e erros humanos. Caso contrário, seu Outlook pode ser corrompido a qualquer momento. Além disso, fazer backups regulares dos dados do Outlook e manter uma ferramenta de reparo especializada são questões de necessidade. DataNumen Outlook Repair é uma das ferramentas de reparo mais recomendadas. Ela pode reparar o Outlook problemas em um instante.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo mdf danificado e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com