Como exportar rapidamente as informações de tamanho de todas as pastas em um arquivo PST para um arquivo do Excel

Se você deseja verificar as informações de tamanho de cada pasta em um arquivo PST, pode usar o método exposto neste artigo. Ele exportará rapidamente as informações de tamanho de todas as pastas em um arquivo PST para um arquivo do Excel.

Quando o arquivo PST for muito grande, verifique o tamanho de cada pasta. Isso ajudará você a descobrir facilmente quais são os maiores e fazer o arquivamento adequado com base no tamanho. Em geral, para verificar o tamanho da pasta, basta clicar com o botão direito do mouse em uma pasta e escolher “Propriedades”. Na nova caixa de diálogo pop-up, você pode clicar no botão “Tamanho da pasta”. No entanto, se você criou muitas pastas, verificar as informações de tamanho uma a uma manualmente é consideravelmente problemático. Portanto, se você deseja obter em lote as informações de tamanho de todas as pastas em um arquivo PST, pode usar o seguinte código VBA. Ele exportará todos os nomes de pastas e informações de tamanho para um arquivo do Excel de uma só vez.

Exportar as informações de tamanho de todas as pastas em um arquivo PST para um arquivo do Excel

1. Para começar, abra o aplicativo Outlook.
2. Em seguida, mude para a guia “Desenvolvedor” e clique no botão “Visual Basic” ou pressione as teclas “Alt + F11” para acessar o editor VBA.
3. Em seguida, na janela “Microsoft Visual Basic for Applications”, abra um módulo que não esteja em uso.
4. Posteriormente, copie e cole os seguintes códigos VBA neste módulo.

Dim strExcelFile As String
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportFodlerSizetoExcel()
    Dim objSourcePST As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Folder"
    objExcelWorksheet.Cells(1, 2) = "Size"
 
    'Select a source PST file
    Set objSourcePST = Outlook.Application.Session.PickFolder

    For Each objFolder In objSourcePST.Folders
        Call ProcessFolders(objFolder)
    Next
 
    'Fit the columns from A to B
    objExcelWorksheet.Columns("A:B").AutoFit
 
    strExcelFile = "E:\Outlook\" & objSourcePST.Name & " Folder Size (" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim lCurrentFolderSize As Long
    Dim nNextEmptyRow As Integer
 
    objCurrentFolder.Items.SetColumns ("Size")
    For Each objItem In objCurrentFolder.Items
        lCurrentFolderSize = lCurrentFolderSize + objItem.Size
    Next
 
    'Convert byte to kilobyte
    'To convert to megabyte, use:
    'lCurrentFolderSize = (lCurrentFolderSize / 1024) / 1024
    lCurrentFolderSize = lCurrentFolderSize / 1024
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1

    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = objCurrentFolder.FolderPath
    objExcelWorksheet.Range("B" & nNextEmptyRow) = lCurrentFolderSize & " KB"
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

5. Depois disso, você deve definir o nível de segurança de macro do Outlook como baixo.
6. Eventualmente, você pode tentar.

• Pressione o botão da tecla F5 na janela de macro atual.
• Em seguida, você será solicitado a selecionar um arquivo PST, como na imagem a seguir:
• Depois de selecionar um arquivo de origem, o Outlook começará a exportar as informações de tamanho para o Excel.
• Depois que a macro terminar, você receberá uma mensagem como a captura de tela abaixo.
• Por fim, você poderá encontrar o arquivo Excel na pasta local predefinida. O arquivo do Excel terá a seguinte aparência:

Lide com erros frequentes de PST

Como o Outlook é propenso a erros, você pode ter sofrido muitos problemas em seu Outlook. Para lidar melhor e com mais flexibilidade com problemas frustrantes de PST, é aconselhável manter um utilitário de correção experiente e respeitável nas proximidades, como DataNumen Outlook Repair. É capaz de corrigir PST problemas como uma brisa.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo SQL Server recuperação e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com