Como exportar rapidamente um e-mail do Outlook como um arquivo de imagem

Alguns usuários gostariam de exportar um e-mail do Outlook como um arquivo de imagem, como um arquivo jpg. Portanto, neste artigo, apresentaremos como obtê-lo por meio do código VBA do Outlook.

Você deve ter aprendido uma variedade de truques para exportar um e-mail como arquivo de texto, documento do Word e assim por diante. Então, que tal exportar um e-mail como imagem como arquivo JPG? Aparentemente, o Outlook não tem essa função. Mas, a seguir, compartilharemos um meio rápido com você.

Exporte rapidamente um e-mail do Outlook como um arquivo de imagem

1. Para começar, abra o aplicativo Outlook.
2. Em seguida, na janela principal do Outlook, acesse o editor VBA de acordo com o artigo – “Como executar o código VBA no seu Outlook".
3. Em seguida, habilite “Biblioteca de Objetos do MS Word” e “MS PowerPoint Biblioteca de Objetos”, fazendo referência ao artigo – “Como adicionar uma referência à biblioteca de objetos em VBA".
4. Em seguida, copie e cole o seguinte código VBA em um módulo em branco.

Sub ExportEmailAsImage()
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim strWordDocument As String
    Dim objWordApp As Word.Application
    Dim objWordDocument As Word.Document
    Dim objDocumentRange As Word.Range
    Dim objPowerPointApp As PowerPoint.Application
    Dim objPresentation As PowerPoint.Presentation
    Dim objShape As PowerPoint.Shape
 
    On Error Resume Next
    'Export the email as Word document
    Set objMail = Outlook.Application.ActiveExplorer.Selection(1)
    strFileName = Replace(objMail.Subject, "/", " ")
    strFileName = Replace(strFileName, "\", " ")
    strFileName = Replace(strFileName, ":", "")
    strFileName = Replace(strFileName, "?", " ")
    strFileName = Replace(strFileName, Chr(34), " ")
    strWordDocument = Environ("Temp") & "\" & strFileName & ".doc"
 
    objMail.SaveAs strWordDocument, olDoc

    Set objWordApp = CreateObject("Word.Application")
    Set objWordDocument = objWordApp.Documents.Open(strWordDocument)
    objWordApp.Visible = True
 
    objWordApp.Selection.Find.ClearFormatting
    objWordApp.Selection.Find.Replacement.ClearFormatting
 
    With objWordApp.Selection.Find
        .Text = "^p^p"
        .Replacement.Text = "^p"
        .Wrap = wdFindContinue
    End With
 
    'Insert the document into a PowerPoint Presentation slide as an object
    objWordApp.Selection.Find.Execute Replace:=wdReplaceAll
    Set objDocumentRange = objWordDocument.Range()
    objDocumentRange.Font.Name = "Calibri"
    objDocumentRange.Font.Size = 10
    objWordDocument.Close True
    objWordApp.Quit
 
    Set objPowerPointApp = CreateObject("PowerPoint.Application")
    Set objPresentation = objPowerPointApp.Presentations.Add
    objPowerPointApp.Visible = msoTrue
 
    With objPresentation
        .PageSetup.SlideHeight = 792
        .PageSetup.SlideWidth = 612
        .Slides.AddSlide 1, .SlideMaster.CustomLayouts(1)
    End With
 
    'Export the slide
    With objPresentation.Slides(1)
         Set objShape = .Shapes.AddOLEObject(0, 0, 612, 792, , strWordDocument)
        .Export "E:\Email_" & strFileName & ".jpg", "JPG"
    End With
 
    objPresentation.Saved = msoTrue
    objPresentation.Close
    objPowerPointApp.Quit
End Sub

5. Depois disso, você precisa adicionar a macro à Barra de Ferramentas de Acesso Rápido.
6. Posteriormente, você pode fechar o editor VBA.
7. Mais tarde, selecione um e-mail e clique no botão de macro na Barra de Ferramentas de Acesso Rápido.
8. Quando a macro for concluída, você poderá ir para a pasta local predefinida para encontrar o arquivo de imagem exportado deste e-mail.

Recuperar dados do Outlook de arquivo corrompido

Pode ser bastante frustrante se o seu arquivo do Outlook sofrer danos graves. Nesse cenário, você precisará extrair os dados do arquivo comprometido. Alguns usuários recorrem à ferramenta de reparo da caixa de entrada, mas, na maioria das vezes, ela não surte efeito. Portanto, é melhor ter uma solução robusta e confiável. correção PST ferramenta, como DataNumen Outlook Repair. Ele pode digitalizar o arquivo corrompido e recuperar o máximo de dados sem problemas.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo conserto de mdf e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com