Como exportar rapidamente todos os hiperlinks em vários e-mails do Outlook para o Excel

Quando você precisa extrair todos os hiperlinks de um ou mais e-mails, copiá-los um por um é um desperdício. Este artigo ensinará um método para exportar rapidamente todos os hiperlinks de vários e-mails para o Excel.

Por alguns motivos, como registrar os hiperlinks em todos os e-mails enviados, você precisará extrair os hiperlinks. Sem dúvidas, é desaconselhável extraí-los e copiá-los manualmente. Você deve desejar uma abordagem muito mais inteligente, como usar o VBA. Aqui vamos compartilhar com você um pedaço de código VBA, que é capaz de exportar todos os hiperlinks em muitos e-mails para o Excel com um simples clique.

Exportar todos os hiperlinks em vários e-mails para o Excel

1. Para começar, abra o Outlook normalmente.
2. Em seguida, na janela do Outlook, você precisa pressionar os botões de tecla “Alt + F11”.
3. Imediatamente, você terá acesso ao editor VBA do Outlook.
4. Em seguida, você precisa habilitar a “Biblioteca de Objetos do Microsoft Word”, bem como a “Biblioteca de Objetos do Microsoft Excel”. Clique em “Ferramentas” > “Referências” e habilite-as na caixa de diálogo que aparecer.
5. Em seguida, você precisa abrir um módulo não utilizado, no qual você deve copiar o código VBA abaixo para este módulo.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllHyperlinksInMultipleEmailsToExcel()
    Dim objSelection As Selection
    Dim objMail As MailItem
    Dim objMailDocument As Document
    Dim objHyperlink As Hyperlink
    Dim i As Long
 
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    If Not (objSelection Is Nothing) Then
 
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
       objExcelApp.Visible = True
       objExcelWorkbook.Activate
 
       With objExcelWorksheet
            .Cells(1, 1) = "No."
            .Cells(1, 2) = "Displaying Text"
            .Cells(1, 3) = "Address"
            .Cells(1, 4) = "Source Mail"
      End With
 
      On Error Resume Next
      i = 0
      For Each objMail In objSelection
          objMail.Display
          Set objMailDocument = objMail.GetInspector.WordEditor
          If objMailDocument.Hyperlinks.Count > 0 Then
             For Each objHyperlink In objMailDocument.Hyperlinks
                 If InStr(objHyperlink.Address, "www.") > 0 Then
                    i = i + 1
                    Call ExportToExcel(i, objMail, objHyperlink)
                 End If
             Next
          End If
          objMail.Close olDiscard
      Next
 
      objExcelWorksheet.Columns("A:D").AutoFit
    End If
End Sub

Sub ExportToExcel(n As Long, objCurrentMail As MailItem, objCurrentHyperlink As Hyperlink)
    Dim nLastRow As Integer
 
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    objExcelWorksheet.Range("A" & nLastRow) = n
    objExcelWorksheet.Range("B" & nLastRow) = objCurrentHyperlink.TextToDisplay
    objExcelWorksheet.Range("C" & nLastRow) = objCurrentHyperlink.Address
    objExcelWorksheet.Range("D" & nLastRow) = objCurrentMail.Subject
End Sub

6. Depois disso, você pode sair da janela atual do editor VBA.
7. Posteriormente, acesse “Opções do Outlook” para personalizar a Barra de Ferramentas de Acesso Rápido para adicionar a macro recém-adicionada à Barra de Ferramentas de Acesso Rápido.
8. Finalmente, você pode tirar uma foto:

• Primeiro, na lista de e-mails, selecione os e-mails cujos hiperlinks você deseja extrair.
• Em seguida, clique no botão macro na Barra de Ferramentas de Acesso Rápido.
• Quando a macro terminar, você obterá um arquivo do Excel, como a imagem abaixo:

Corrigir problemas inesperados do Outlook

Problemas com o Outlook podem ocorrer ocasionalmente, sem aviso prévio. No entanto, em casos de pequenos erros, o Outlook pode ser recuperado com uma simples reinicialização ou pelo seu próprio sistema de segurança. ferramenta de reparo da caixa de entrada. Mas se encontrar alguns problemas graves, os meios internos não farão efeito. Neste ponto, seu último recurso é definitivamente uma ferramenta mais confiável e robusta, como DataNumen Outlook Repair.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo mdf corrompido e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com