Como exportar rapidamente os detalhes de todos os membros em um grupo de contatos do Outlook para o Excel

Por padrão, você só pode ver os nomes dos membros e endereços de e-mail em um grupo de contatos. Se você deseja obter outros detalhes dos membros, pode usar o caminho apresentado neste artigo.

Quando você clica duas vezes em um grupo de contatos para abri-lo, em sua janela, você pode ver apenas os nomes e endereços de e-mail dos membros do grupo. Você não consegue obter outros detalhes dos membros, como empresa, cargo, número de telefone ou endereço comercial, etc. Em geral, para obter esses detalhes, você deve encontrar os contatos correspondentes aos membros em sua pasta de contatos manualmente. É muito problemático. Aqui mostraremos um pedaço de código VBA, que pode exportar rapidamente esses detalhes para uma pasta de trabalho do Excel.

Exportar os detalhes de todos os membros em um grupo de contatos para o Excel

1. Para começar, abra o aplicativo Outlook.
2. Em seguida, você deve pressionar os atalhos de tecla “Alt + F11” na janela principal do Outlook.
3. Em seguida, na nova janela “Microsoft Visual Basic for Applications”, você precisa abrir um módulo não em uso ou inserir diretamente um novo módulo.
4. Posteriormente, copie e cole o seguinte código VBA neste módulo.

Sub ExportMemberContactDetailsToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objGroupMember As Outlook.recipient
    Dim objContacts As Outlook.Items
    Dim objFoundContact As Outlook.ContactItem
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strFilename As String
 
    Set objContactGroup = Application.ActiveExplorer.Selection(1)
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkBook = objExcelApp.Workbooks.Add
    Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
    'Set the seven column headers
    With objExcelWorkSheet
         .Cells(1, 1) = "Name"
         .Cells(1, 2) = "Email Address"
         .Cells(1, 3) = "Company"
         .Cells(1, 4) = "Job Title"
         .Cells(1, 5) = "Phone Number"
         .Cells(1, 6) = "Mailing Address"
         .Cells(1, 7) = "Birthday"
    End With
 
    Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items.Restrict("[Email1Address]>''")
 
    nRow = 2
    For i = 1 To objContactGroup.MemberCount
        Set objGroupMember = objContactGroup.GetMember(i)
 
        strFilter = "[Email1Address] = '" & objGroupMember.Address & "'"
        Set objFoundContact = objContacts.Find(strFilter)
 
        If Not (objFoundContact Is Nothing) Then
           'Input the Contact Details
           With objExcelWorkSheet
                .Cells(nRow, 1) = objFoundContact.FullName
                .Cells(nRow, 2) = objFoundContact.Email1Address
                .Cells(nRow, 3) = objFoundContact.CompanyName
                .Cells(nRow, 4) = objFoundContact.JobTitle
                .Cells(nRow, 5) = objFoundContact.BusinessTelephoneNumber
                .Cells(nRow, 6) = objFoundContact.MailingAddress
             If objFoundContact.Birthday = #1/1/4501# Then
                .Cells(nRow, 7) = ""
             Else
                .Cells(nRow, 7) = objFoundContact.Birthday
             End If
           End With
       Else
           With objExcelWorkSheet
               .Cells(nRow, 1) = objGroupMember.Name
               .Cells(nRow, 2) = objGroupMember.Address
           End With
       End If
       nRow = nRow + 1
    Next
 
    'Fit the columns
    objExcelWorkSheet.Columns("A:G").AutoFit
 
    'Change the Path as per where you want to save the new Excel file
    strFilename = "E:\" & objContactGroup.DLName & " Member Contact Details.xlsx"
    'Save the Excel workbook
    objExcelWorkBook.Close True, strFilename
 
    MsgBox ("Complete!")
End Sub

5. Depois disso, para uma verificação conveniente, você pode adicionar o novo projeto VBA à barra de ferramentas de acesso rápido ou à faixa de opções.
6. Posteriormente, defina o nível de segurança de macro do Outlook como baixo.
7. Em última análise, você pode tentar.

• Primeiro, selecione um grupo de contatos.
• Em seguida, pressione o botão macro na barra de ferramentas de acesso rápido ou na faixa de opções.
• Imediatamente, a macro será executada.
• Quando terminar, você receberá um prompt de "Complete!"
• Depois disso, você pode ir para a pasta local de destino predefinida, na qual pode encontrar um novo arquivo do Excel.
• Abra-o, você verá os detalhes de contato dos membros do grupo, como na captura de tela a seguir:

Não entre em pânico diante dos problemas do Outlook

Ninguém está disposto a aceitar quaisquer problemas do Outlook, não importa a mensagem de erro pop-up ou Outlook corrompido arquivo de dados. Portanto, os usuários tendem a entrar em pânico ao se depararem com problemas do Outlook. Se você quiser manter a calma nesse caso, deve ter duas necessidades em mãos. Um deles são os backups de dados atuais do Outlook. O outro é um poderoso software de correção do Outlook, como DataNumen Outlook Repair.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo recuperação sql e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com