Como anexar rapidamente as páginas específicas de um documento do Word a um e-mail do Outlook

O MS Word possui um recurso direto que oferece suporte aos usuários para enviar o documento do Word atual como um anexo de e-mail. Mas, às vezes, você pode esperar apenas anexar as páginas específicas de um documento do Word a um e-mail do Outlook. Agora, este artigo irá compartilhar um método.

Para enviar um documento inteiro do Word como anexo de e-mail no aplicativo MS Word, basta ir ao menu “Arquivo” e mudar para a guia “Salvar e enviar”, na qual você pode encontrar o botão “Enviar como anexo”. No entanto, às vezes, o que você deseja enviar pode ser apenas páginas específicas do documento. Nessa situação, você pode usar o método apresentado a seguir para realizá-lo.

Anexe as páginas específicas de um documento do Word a um e-mail

1. Primeiro, você deve abrir o documento de origem do Word cujas páginas específicas você deseja enviar por e-mail.
2. Então, depois de entrar na janela do MS Word, você precisa pressionar os botões "Alt + F11".
3. Em seguida, você terá acesso ao editor VBA no MS Word.
4. Em seguida, você precisa habilitar a “Biblioteca de Objetos do Microsoft Outlook”. Para isso, acesse “Ferramentas” > “Referências”.
5. Posteriormente, você deve copiar o seguinte código VBA em um módulo que não está em uso.

Sub AttachSpecificPagesToOutlookEmail()
    Dim strDocumentName As String
    Dim objSelectedPages As Word.Range
    Dim objTempDocument As Word.Document
    Dim objTempRange As Word.Range
    Dim i As Long
    Dim strTempDocument As String
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    strDocumentName = Left(ActiveDocument.Name, InStr(ActiveDocument.Name, ".") - 1)
 
    'Copy the contents from Page 2 to 4
    'You can change the page as per your own needs
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=2
    Set objSelectedPages = Selection.Range
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=4
    objSelectedPages.End = Selection.Bookmarks("\Page").Range.End
    objSelectedPages.Select
    objSelectedPages.Copy
 
    'Paste the copied contents into a new Word Document
    Set objTempDocument = Word.Application.Documents.Add
    objTempDocument.Activate
    Set objTempRange = objTempDocument.Range(0, 0)
    objTempRange.PasteAndFormat (wdFormatOriginalFormatting)

    For i = objTempDocument.Paragraphs.Count To 1 Step -1
        If Len(objTempDocument.Paragraphs(i).Range) = 1 Then
           objTempDocument.Paragraphs(i).Range.Delete
        Else
           Exit For
        End If
    Next i
 
    'Save this document
    strTempDocument = "E:\" & strDocumentName & " (Excerpt).doc"
    objTempDocument.SaveAs2 strTempDocument, wdFormatDocument
 
    'Attach the new document to a new Outlook email
    On Error Resume Next
    Set objOutlookApp = GetObject(, "Outlook.Application")
    If objOutlookApp Is Nothing Then
       Set objOutlookApp = CreateObject("Outlook.Application")
    End If
 
    Set objMail = objOutlookApp.CreateItem(olMailItem)
    objMail.Attachments.Add (strTempDocument)
    objMail.Display
 
    objTempDocument.Close False
    Kill strTempDocument
End Sub

6. Finalmente, você pode executar esta macro. Basta pressionar o botão da tecla F5 ou tocar no ícone “Executar” na barra de ferramentas.
7. Depois que a macro terminar, um novo e-mail do Outlook será exibido, anexado a um trecho do documento do Word de origem, como na captura de tela a seguir:

Extraia o máximo de dados do arquivo corrompido do Outlook

Se você usa o Outlook há décadas, pode ter se deparado com vários problemas do Outlook, incluindo mensagens de erro internas pop-up, travamentos repentinos e sérios danos aos arquivos. Devido ao fato de ScanpstName, ferramenta de reparo embutida, só pode lidar com os pequenos problemas, é melhor você manter uma poderosa ferramenta de correção externa à mão, digamos DataNumen Outlook Repair. Ele é capaz de extrair o máximo de dados do arquivo de dados do Outlook danificado.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo correção de sql e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com