Como abrir em lote todos os hiperlinks com um domínio específico em seu e-mail do Outlook

Ao visualizar um e-mail do Outlook que contém muitos hiperlinks no corpo, às vezes, você pode apenas desejar abrir rapidamente os hiperlinks com um domínio específico. Aqui, compartilharemos um método para abrir esses hiperlinks em massa.

Diante de vários hiperlinks em um e-mail, você pode esperar verificar alguns deles, em vez de todos. Por exemplo, você só gostaria de abrir em lote os hiperlinks com um domínio específico. Em geral, você deve clicar um por um para abri-los. É muito problemático. Portanto, a seguir, ensinaremos uma maneira mais conveniente.

Lote abrir todos os hiperlinks com um domínio específico no e-mail

1. Para comotart, acesse o editor VBA do Outlook de acordo com “Como executar o código VBA no seu Outlook".
2. Posteriormente, na janela “Microsoft Visual Basic for Applications”, habilite a referência a “MS Word Object Library” com referência a “Como adicionar uma biblioteca de objetosrary Referência em VBA".
3. Em seguida, copie o código VBA a seguir em um módulo ou projeto não utilizado.

Sub BatchOpenHyperlinksWithSpecificDomain()
    Dim objMail As MailItem
    Dim objMailDocument As Word.Document
    Dim objHyperlink As Word.Hyperlink
    Dim objDictionary As Object
    Dim i As Integer
    Dim varHyperlinks As Variant
    Dim varHyperlink As Variant
    Dim objInternetExplorer As Object
 
    'Get the source email
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objMail = ActiveInspector.CurrentItem
           Case olExplorer
                Set objMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
    Set objMailDocument = objMail.GetInspector.WordEditor
    For Each objHyperlink In objMailDocument.Hyperlinks
        If InStr(1, objHyperlink.Address, "www.datanumen.com") > 0 Then
           'Add Hyperlinks to Dictionary
           If objDictionary.Exists(objHyperlink.Address) = False Then
              objDictionary.Add objHyperlink.Address, 1
           End If
        End If
    Next
 
    'Batch Open Hyperlinks on different tabs in same Internet Explorer window
    Set objInternetExplorer = CreateObject("InternetExplorer.Application")
    varHyperlinks = objDictionary.Keys
    For i = LBound(varHyperlinks) To UBound(varHyperlinks)
        varHyperlink = varHyperlinks(i)
 
        If i = 0 Then
           objInternetExplorer.Visible = True
           objInternetExplorer.navigate varHyperlink
        Else
           objInternetExplorer.navigate varHyperlink, CLng(2048)
        End If
    Next
End Sub

4. Em seguida, adicione esta macro à barra de ferramentas de acesso rápido ou à faixa de opções.
5. Por fim, siga as etapas a seguir para tentar.

• Primeiro, selecione ou abra um e-mail do Outlook.
• Em seguida, clique no botão macro.
• De uma só vez, os hiperlinks com o domínio pré-definido no e-mail serão abertos em lote no Internet Explorer, conforme a imagem a seguir:

Livre-se da irritante corrupção do Outlook

Embora o Outlook seja suscetível a erros e corrupção, na verdade, desde que você esteja atento a todos os riscos, poderá escapar deles com facilidade. Por exemplo, você precisa fazer backups de dados para o Outlook regularmente. Além disso, você deve ficar atento aos e-mails suspeitos que podem conter vírus. Por último, mas não menos importante, é melhor você preparar um Reparo do Outlook utilitário, como DataNumen Outlook Repair. É capaz de ajudá-lo em caso de corrupção do Outlook.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo corrupto SQL Server e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com