Como salvar automaticamente todos os anexos de remetentes em um domínio específico via Outlook VBA

Se você deseja permitir que o Outlook salve automaticamente todos os anexos dos remetentes cujos endereços de email estão em um domínio específico, leia este artigo. Aqui vamos apresentar um método rápido para você.

Talvez todos os funcionários da sua empresa usem os endereços de e-mail que estão no mesmo domínio. Como você costuma enviar e-mails com vários anexos entre si, convém que o Outlook salve automaticamente os anexos desses e-mails. Nesse caso, o Outlook será solicitado a verificar automaticamente o domínio do remetente do email e salvar automaticamente os anexos. Agora, a seguir, compartilharemos um pedaço de código VBA que é capaz de realizá-lo com facilidade e sem esforço.

Salvar automaticamente todos os anexos de remetentes em um domínio específico

1. Em primeiro lugar, execute o editor VBA do Outlook de acordo com “Como executar o código VBA no seu Outlook".
2. Em seguida, coloque o código a seguir em um módulo não utilizado.

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
   Set objInboxItems = Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
   Dim objMail As Outlook.MailItem
   Dim strSenderAddress As String
   Dim strSenderDomain As String
   Dim objAttachment As Attachment
   Dim strFolderPath As String
   Dim strFileName As String

   If Item.Class = olMail Then
      Set objMail = Item

      'Get sender domain
      strSenderAddress = objMail.SenderEmailAddress
      strSenderDomain = Right(strSenderAddress, Len(strSenderAddress) - InStr(strSenderAddress, "@"))

      'Change to the specific domain as per your needs
      If strSenderDomain = "datanumen.net" Then
         If objMail.Attachments.Count > 0 Then
            For Each objAttachment In objMail.Attachments
                'Change the folder path where you want to save attachments
                strFolderPath = "E:\Attachments\"
                strFileName = objMail.Subject & " " & Chr(45) & " " & objAttachment.FileName
                objAttachment.SaveAsFile strFolderPath & strFileName
            Next
         End If
      End If
   End If
End Sub

3. Em seguida, reinicie o Outlook para ativar essa macro.
4. Desde então, sempre que um e-mail entra em sua caixa de entrada, o Outlook verifica automaticamente o domínio do remetente. Se for igual ao domínio predefinido e contiver anexos, o Outlook salvará automaticamente os anexos em uma pasta local específica.

Nunca abra anexos de remetentes em domínios desconhecidos

É aconselhável não confiar prontamente e baixar os anexos daqueles em domínios desconhecidos. É porque eles podem vir dotados de malware ou vírus. Depois de abri-los, o arquivo do Outlook pode ser atacado. Em outras palavras, você pode estar sujeito à corrupção de arquivos do Outlook. Naquela época, mesmo ScanpstName é incapaz de ajudá-lo. Seu único recurso é uma ferramenta mais poderosa ou um serviço especializado de recuperação de PST.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo mdf corrompido e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com