Como excluir automaticamente os e-mails do Outlook de um remetente específico após dias específicos

Para permitir que seu Outlook exclua automaticamente os e-mails de um remetente específico em dias específicos, você pode ler este artigo. Aqui, mostraremos as etapas detalhadas para usar o código VBA para obtê-lo.

Quando se trata de exclusão automática de e-mails, você pode pensar primeiro no recurso “AutoArquivar”. No entanto, ele não pode filtrar os remetentes específicos ao arquivar emails automaticamente. Portanto, por exemplo, se você deseja excluir automaticamente os e-mails de um remetente específico após x dias, use outro meio, como o seguinte.

Excluir automaticamente os e-mails de um remetente específico após X dias

1. Para começar, abra o aplicativo Outlook.
2. Em seguida, acione o editor VBA do Outlook de acordo com “Como executar o código VBA no seu Outlook".
3. Em seguida, copie o seguinte código VBA para o projeto “ThisOutlookSession”.

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
 
    Call DeleteEmailsFromSpecificSenderAfterXDays
End Sub

Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'From the specific sender
       If objMail.SenderEmailAddress = "bob_black@datanumen.com" Then
          'Set expiry time - after 5 days
          objMail.ExpiryTime = objMail.ReceivedTime + 4
          objMail.Save
       End If
    End If
End Sub

Private Sub DeleteEmailsFromSpecificSenderAfterXDays()
    Dim strFilter As String
    Dim objExpiredItems As Outlook.Items
    Dim objExpiredMail As Outlook.MailItem
 
    strFilter = "[ExpiryTime] <= " & Chr(34) & Now & Chr(34)
 
    'Get all expired items
    Set objExpiredItems = objInboxItems.Restrict(strFilter)
 
    For i = objExpiredItems.Count To 1 Step -1
        If objExpiredItems(i).Class = olMail Then
           Set objExpiredMail = objExpiredItems(i)
 
           'Auto delete expired emails from the specific sender
           If objExpiredMail.SenderEmailAddress = "bob_black@datanumen.com" Then
              objExpiredMail.Delete
           End If
        End If
    Next
End Sub

4. Em seguida, reinicie o Outlook para ativar essa macro.
5. Desde então, toda vez que um novo e-mail do remetente específico chega na caixa de entrada, ele recebe um tempo de expiração específico – os dias específicos após o recebimento.
6. Assim, sempre que você iniciar o Outlook, ele verificará e excluirá automaticamente os e-mails expirados do remetente específico.

Restaurar dados do Outlook após corrupção

Talvez você tenha encontrado uma variedade de erros e problemas no Outlook. Então, você já confrontou a corrupção do Outlook? Por exemplo, se você sair do Outlook incorretamente com frequência, seu arquivo PST tende a ficar danificado. Geralmente, nesse caso, você pode optar por recuperar dados do Outlook de backups. Ou você pode usar ferramenta de reparo da caixa de entrada ou uma ferramenta externa confiável, como DataNumen Outlook Repair.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo recuperar sql e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com