Como exportar em lote fotos e informações de vários contatos com o Outlook VBA

Se você deseja extrair as fotos dos contatos e suas informações primárias para uma pasta em seu disco local em lotes, você precisa usar o Outlook VBA. Este artigo ensinará como alcançá-lo em detalhes.

O Outlook permite que você exporte as informações de contato por meio do recurso “Importar e exportar”. Você pode ir em “Arquivo” > “Imprimir” > “Importar” > “Exportar para um arquivo”.

No entanto, esse recurso não permite exportar as fotos dos contatos. Portanto, se você deseja extrair as informações de contato e as fotos, deve recorrer ao Outlook VBA. A seguir estão os códigos VBA e as etapas que podem salvar as fotos de contato em uma pasta local especificada e extrair as informações de contato em um arquivo de texto.

Exportação em lote de fotos e informações de vários contatos

1. Em primeiro lugar, inicie o Outlook e pressione os botões de tecla “Alt + F11”.
2. Então você terá acesso ao editor VBA. Agora você deve abrir um módulo que não está em uso ou criar um novo módulo em “Inserir” > “Módulo”.
3. Posteriormente, copie e cole os seguintes códigos VBA no novo módulo.

Sub BatchExportContactPhotosandInformation()
    Dim objContacts As Outlook.Items
    Dim objContact As ContactItem
    Dim strContactInfo As String
    Dim objFileSystem As Object
    Dim objTextfile As Object
    Dim objAttachments As Attachments
    Dim objAttachment As Attachment
    Dim strName As String
 
    'Specify the contacts in the default contact folder
    Set objContacts = Outlook.Application.Session.GetDefaultFolder(olFolderContacts).Items
 
    For Each objContact In objContacts
        If TypeOf objContact Is ContactItem Then
           'Get the contact's primary informtaion
           strContactInfo = "Name: " & objContact.FullName & vbCrLf & "Email: " & objContact.Email1Address & vbCrLf & "Company: " & objContact.Companies & vbCrLf & "Job Title: " & objContact.JobTitle & vbCrLf & "Business Address: " & objContact.BusinessAddress & vbCrLf & "Business Phone: " & objContact.BusinessTelephoneNumber
           'Create a Text file
           Set objFileSystem = CreateObject("Scripting.FileSystemObject")
           'You can change the folder path as per your needs
           Set objTextfile = objFileSystem.CreateTextFile("C:\Outlook Contacts\" & objContact.FullName & ".txt", True)
           objTextfile.WriteLine (strContactInfo)
 
           'Save the contact photos
           If objContact.Attachments.Count > 0 Then
              Set objAttachments = objContact.Attachments
              For Each objAttachment In objAttachments
                  If InStr(LCase(objAttachment.filename), "contactpicture.jpg") > 0 Then
                     strName = objContact.FullName & ".jpg"
                     objAttachment.SaveAsFile ("C:\Outlook Contacts\" & strName)
                  End If
              Next
           End If
       End If
    Next
End Sub

Nota: Os códigos acima irão exportar as fotos e informações dos contatos em sua pasta de contatos padrão. Você pode alterar os contatos especificados.

• Se você deseja exportar as fotos e informações dos contatos na pasta aberta no momento, substitua “Set objContacts = …..” por:

Set objContacts = Outlook.Application.ActiveExplorer.CurrentFolder.Items

• Se você deseja apenas exportar as fotos e informações dos contatos selecionados, pode usar as seguintes linhas:

Dim objSelection as Selection
Set objSelection = Outlook.Application.ActiveExplorer.Selection
For each objContact in objSelection

4. Depois disso, você pode fechar o editor VBA e adicionar o novo projeto à Barra de Ferramentas de Acesso Rápido como de costume.
5. Finalmente, você pode clicar no botão de macro na Barra de Ferramentas de Acesso Rápido. Imediatamente, as fotos e informações do contato serão exportadas para a pasta especificada no disco local.

Você pode abrir um arquivo de texto, no qual as informações primárias serão listadas, como na captura de tela a seguir:

Lidar com corrupção inesperada do Outlook

É um fato inquestionável que o Outlook é vulnerável. Portanto, se você sofre corrupção do Outlook, o que deve fazer primeiro é se acalmar. Então você pode continuar a reparar o e-mail PST do Outlook corrompido. Você pode usar a ferramenta de reparo da caixa de entrada para tentar. Se falhar, você não terá escolha a não ser empregar uma ferramenta muito mais poderosa, como DataNumen Outlook Repair.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo reparar banco de dados SQL mdf danificado e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com