Como excluir em lote todos os recibos de leitura em seu Outlook

Para confirmar que os destinatários leram seu e-mail, você pode solicitar uma confirmação de leitura ao redigi-lo. Nesse caso, sua caixa de entrada pode ficar cheia dessas confirmações. Este artigo ensinará como excluí-las permanentemente em lote.

Depois de ler o artigo “Como excluir em lote todos os recibos de entrega em seu Outlook“, você pode pensar sobre a abordagem para excluir em massa todas as confirmações de leitura. De fato, a diferença manifesta entre os dois tipos de recibos está em seus assuntos. O recibo de entrega contém "Entregue" no assunto, mas o recibo de leitura contém "Lido". Portanto, você pode usar a mesma maneira de excluir em lote todas as confirmações de leitura. A seguir, ensinaremos os passos concretos em detalhes.

Excluir em lote todos os recibos de leitura

1. Para começar, abra o Outlook.
2. Em seguida, vá para o editor VBA do Outlook via “Alt + F11” de acordo com “Como executar o código VBA no seu Outlook".
3. Em seguida, na nova janela, abra um módulo vazio e coloque o seguinte código nele.

Dim objOutlookFile As Outlook.Folder

Sub BatchDeleteAllReadReceipts()
    Dim objStore As Outlook.Store
    Dim objFolder As Outlook.Folder
    Dim lTotalCount As Long
 
    lTotalCount = 0
   'Process all Outlook files
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olMailItem Then
               Call ProcessFolders(objFolder, lTotalCount)
            End If
        Next
    Next
 
    'Prompt you of the results
    MsgBox lTotalCount & " read receipts are deleted!", vbInformation + vbOKOnly
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder, lCount As Long)
    Dim i As Long
    Dim objDeliveryReceipt As Outlook.ReportItem
    Dim objSubfolder As Outlook.Folder
    Dim objDeletedItems As Outlook.Items
    Dim objItem As Object
 
    For i = objCurrentFolder.Items.Count To 1 Step -1
        'Find read receipts
        If (TypeOf objCurrentFolder.Items(i) Is ReportItem) And (Left(objCurrentFolder.Items(i).Subject, 5) = "Read:") Then
           Set objDeliveryReceipt = objCurrentFolder.Items.Item(i)
           objDeliveryReceipt.Delete
 
           lCount = lCount + 1
 
           'Permanently delete them
           Set objDeletedItems = objOutlookFile.Folders("Deleted Items").Items
           For Each objItem In objDeletedItems
               If (TypeOf objItem Is ReportItem) And (Left(objItem.Subject, 5) = "Read:") Then
                  objItem.Delete
               End If
           Next
         End If
    Next
 
    'Loop subfolders recursively
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder, lCount)
       Next
    End If
End Sub

4. Depois disso, clique na primeira sub-rotina.
5. Finalmente, pressione o botão de tecla “F5”.
6. Ao mesmo tempo, a macro funcionará para excluir todas as confirmações de leitura do seu Outlook.
7. Quando terminar, você receberá um prompt sobre o resultado, como na captura de tela abaixo.
8. No momento, você pode verificar suas pastas de e-mail. Todos os recibos de leitura desapareceram.

Defender dados do Outlook

Embora o arquivo do Outlook seja reconhecidamente suscetível à corrupção, podemos tomar medidas para protegê-lo. Por exemplo, devemos manter o arquivo do Outlook em tamanho pequeno, protegê-lo de fatores maliciosos e fazer backup regularmente. Por último, mas não menos importante, é melhor você preparar uma potente ferramenta externa de reparo de PST, como DataNumen Outlook Repair. Fará grandes impactos na reparação Outlook corrompido arquivo.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo reparo do sql e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com