Como definir automaticamente horários de lembrete diferentes para reuniões do Outlook em diferentes categorias de cores

Se você estiver classificando as reuniões do Outlook por categorias de cores e quiser definir horários de lembrete diferentes para reuniões em diferentes categorias de cores, consulte este artigo. Aqui vamos ensiná-lo a realizá-lo com o Outlook VBA.

Por exemplo, imagine que você está dividindo reuniões em dois grupos. Um grupo está na categoria "Remoto", pois o local da reunião é muito distante, e o outro está na categoria "Presencial", pois o local é aqui mesmo. Agora, você deseja que o Outlook defina automaticamente o lembrete para reuniões "remotos" com 1 hora de antecedência e para reuniões "presenciais" com 15 minutos de antecedência. Considerando esse requisito, compartilharemos a seguir um método rápido.

Defina automaticamente lembretes diferentes para reuniões em diferentes categorias de cores

1. Para começar, inicie seu aplicativo Outlook.
2. Em seguida, pressione as teclas “Alt + F11” para acessar a janela do editor VBA.
3. Em seguida, na janela seguinte, copie e cole o código VBA abaixo no projeto “ThisOutlookSession”.

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

4. Posteriormente, você precisará clicar na sub-rotina “Application_Startup” e pressionar a tecla “F5” para executar esta macro.
5. Desde então, toda vez que uma nova reunião é adicionada ao calendário padrão ou você altera uma reunião existente, o Outlook verifica automaticamente as categorias da reunião e define automaticamente o horário do lembrete diferente.

Elimine erros do Outlook

O Outlook pode apresentar diversos problemas ocasionalmente. Portanto, é extremamente importante que os usuários aprendam a lidar com esses problemas. Para começar, é recomendável fazer backups regulares dos dados do Outlook. Além disso, se possível, é aconselhável manter um sistema de backup robusto. Reparo do Outlook ferramenta próxima, como DataNumen Outlook Repair. Ele pode escanear seu arquivo PST para descobrir problemas do Outlook e resolvê-los com facilidade.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo recuperação sql e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com