3 maneiras de obter estatísticas de contagem de palavras relacionadas a caixas de texto, notas de rodapé e notas finais em seu documento

No artigo de hoje, existem 3 maneiras rápidas de obter estatísticas de contagem de palavras relacionadas a caixas de texto, notas de rodapé e notas finais em seu documento.

Não é difícil obter a contagem total de palavras em um documento. Mas se você quiser obter o número de palavras de diferentes tipos de texto, mais operações serão necessárias. A seguir estão 3 métodos. Leia mais para ver o que você pode usar. 

Método 1: Contar palavras, incluindo textos de caixas de texto, notas de rodapé e notas finais

Por padrão, o Word conta todas as palavras que aparecem no documento, incluindo textos em caixas de texto e também palavras de notas de rodapé e notas de fim.

1. Em primeiro lugar, acesse a barra de status e clique em “Palavras” para abrir a caixa “Contagem de palavras”.
2. Lá você verá todos os tipos de estatísticas. Certifique-se de ter marcado a caixa “Incluir caixas de texto, notas de rodapé e notas de fim”.
3. Em seguida, clique em “Fechar”.
4. Se você não encontrar o comando “Palavras” na barra de status, clique com o botão direito ali.
5. Em seguida, verifique a "Contagem de palavras".

Método 2: excluir textos de caixas de texto, notas de rodapé e notas finais da contagem de palavras

Isso é o oposto do método 1. Então você só precisa desmarcar a caixa “Incluir caixas de texto, notas de rodapé e notas de fim”.

Método 3: Executar macro do Word para obter contagem separada de palavras de caixas de texto, notas de rodapé e notas finais

1. Em primeiro lugar, ative a caixa “Contagem de palavras” usando o método 1 e verifique se a caixa de opção está marcada.
2. Em seguida, pressione “Alt + F11” para abrir o editor VBA.
3. Em seguida, insira um novo módulo no projeto “Normal” clicando primeiro em “Normal”.
4. E clique em “Inserir” a seguir.
5. Escolha “Módulo” em seguida.
6. Clique duas vezes no módulo para abrir a área de codificação e cole os seguintes códigos lá:

Sub SeparateCountNumberOfTextboxFootnoteEndnote()
  Dim lTextboxWords As Long
  Dim lTextboxChars As Long
  Dim lDocumntWords As Long
  Dim lDocumntChars As Long
  Dim objTextboxShape As Shape
  Dim objTemp As Dialog
  Dim bDone As Boolean
  Dim objRange As Range
  Dim lFootnoteWords As Long
  Dim lFootnoteChars As Long
  Dim lEndnoteWords As Long
  Dim lEndnoteChars As Long
 
  Application.ScreenUpdating = False

 Do
   bDone = True
   For Each objTextboxShape In ActiveDocument.Shapes
     If objTextboxShape.Type = msoGroup Then
       objTextboxShape.Ungroup
       bDone = False
     End If
   Next objTextboxShape
 Loop Until bDone

 '  Count the words and characters in the whole document.
 Selection.HomeKey Unit:=wdStory
 Set objTemp = Dialogs(wdDialogToolsWordCount)
   objTemp.Update
   objTemp.Execute
   lDocumntWords = objTemp.Words
   lDocumntChars = objTemp.Characters
 
 With ActiveDocument
 '  Count the words and characters in all textboxes.
   lTextboxWords = 0
   lTextboxChars = 0
   If ActiveDocument.Shapes.Count > 0 Then
     For Each objTextboxShape In .Shapes
       objTextboxShape.Select
       objTemp.Execute
       lTextboxWords = lTextboxWords + objTemp.Words
       lTextboxChars = lTextboxChars + objTemp.Characters
     Next objTextboxShape
   Else
     MsgBox ("There is no text box in this document")
   End If

   '  Count the words and characters in all footnotes.
   lFootnoteWords = 0
   lFootnoteChars = 0
   If ActiveDocument.Footnotes.Count > 0 Then
     For Each objRange In .StoryRanges
       If objRange.StoryType = wdFootnotesStory Then
         objRange.Select
         objTemp.Execute
         lFootnoteWords = lFootnoteWords + objTemp.Words
         lFootnoteChars = lFootnoteChars + objTemp.Characters
       End If
     Next objRange
   Else
     MsgBox ("There is no footnote in this document")
   End If

   '  Count the words and characters in all endnotes. 
   lEndnoteWords = 0
   lEndnoteChars = 0
   If ActiveDocument.Endnotes.Count > 0 Then
     For Each objRange In .StoryRanges
       If objRange.StoryType = wdEndnotesStory Then
         objRange.Select
         objTemp.Execute
         lEndnoteWords = lEndnoteWords + objTemp.Words
         lEndnoteChars = lEndnoteChars + objTemp.Characters
       End If
     Next objRange
   Else
     MsgBox ("There is no Endnote in this document")
   End If
 End With
 
 Application.ScreenUpdating = True

 MsgBox (" In this document there are totally" & vbCr _
   & Str(lDocumntWords) & " word(s) and" & Str(lDocumntChars) & " characters" & vbCr & vbCr _
   & "Including:" & vbCr _
   & Str(ActiveDocument.Shapes.Count) & " textboxes contain(s)" & vbCr _
   & Str(lTextboxWords) & " word(s)," & Str(lTextboxChars) & " characters" & vbCr & vbCr _
   & Str(ActiveDocument.Footnotes.Count) & " footnotes contain(s)" & vbCr _
   & Str(lFootnoteWords) & " word(s)," & Str(lFootnoteChars) & " characters" & vbCr & vbCr _
   & Str(ActiveDocument.Endnotes.Count) & " Endnotes contain(s)" & vbCr _
   & Str(lEndnoteWords) & " word(s)," & Str(lEndnoteChars) & " characters")
End Sub

7. Por fim, clique no botão “Executar”.

Se não houver caixa de texto, nota de rodapé ou nota final, você receberá uma caixa de mensagem como esta:

Basta clicar em “OK” para prosseguir. Então você verá outra caixa, listando todos os detalhes da contagem de palavras.

Obtenha uma ferramenta de recuperação

Como o Word pode entrar em colapso repentinamente, é aconselhável obter um produto de reparo avançado para fazer o trabalho de reparo. Essa ferramenta pode ser uma grande economia para Palavra corrompida. Portanto, aproveite o tempo para obter um o mais rápido possível.

Introdução do autor:

Vera Chen é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo corrigir xls e pdf reparar produtos de software. Para mais informações visite www.datanumen.com