3 maneiras rápidas de excluir linhas e colunas em branco em sua tabela do Word

Neste post, explicaremos 3 maneiras rápidas de excluir linhas e colunas em branco em sua tabela do Word.

As tabelas são essenciais para um documento, especialmente para armazenar vários tipos de dados. Às vezes, uma tabela longa pode exceder uma página e se estender por várias. Então, quando uma tabela fica longa e complicada, existem medidas que você pode tomar para simplificá-la. Por exemplo, você pode excluir linhas e colunas em branco desnecessárias.

A seguir estão 3 métodos que você pode usar.

Método 1: Excluir linhas e colunas em branco manualmente

1. Em primeiro lugar, selecione uma linha ou coluna em branco.
2. Em seguida, clique com o botão direito para obter o menu contextual. No menu, selecione “Excluir linhas” ou “Excluir colunas” de acordo.

Infelizmente, você não pode selecionar várias linhas ou colunas não consecutivas e excluí-las dessa maneira. Para esta demanda, você pode consultar nosso artigo anterior: 5 métodos rápidos para excluir em lote várias linhas ou colunas em sua tabela do Word

Método 2: Excluir em lote todas as linhas e colunas em branco em uma tabela

O método 1 tem sua limitação. Portanto, ofereceremos a você a maneira de remover em lote linhas e colunas em uma tabela por meio de códigos VBA.

1. Para começar, coloque o cursor dentro da tabela de destino.
2. Segundo, acione o editor VBA pressionando “Alt+F11”.
3. No editor, clique primeiro no projeto “Normal”.
4. Em seguida, clique na guia "Inserir" na barra de menus.
5. No menu suspenso, escolha “Módulo”.
6. Clique duas vezes no módulo para abri-lo e cole os seguintes códigos lá:

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. Por fim, clique no botão “Executar” na barra de menu ou pressione “F5”.

Em segundos, você removerá todas as linhas e colunas em branco dessa tabela.

Método 3: Excluir em lote todas as linhas e colunas em branco em todas as tabelas de um documento

1. Primeiro, repita as etapas do método 2 para instalar e executar uma macro.
2. Só que desta vez, substitua essa macro pelo seguinte:

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

Recuperar Documento Quebrado

Hoje em dia, existem diversas maneiras de recuperar dados perdidos. Por exemplo, fazer backups continua sendo a principal prioridade. Se isso não for suficiente para recuperar as informações mais recentes, você pode tentar uma solução alternativa. reparação de documentos ferramenta.

Introdução do autor:

Vera Chen é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo reparação de xlsx e pdf reparar produtos de software. Para mais informações visite www.datanumen.com