2 maneiras rápidas de exportar a lista de todos os e-mails sinalizados do Outlook para o Excel

Se você deseja exportar a lista de todos os e-mails sinalizados de sua caixa de correio do Outlook para o Excel, pode usar um dos dois métodos compartilhados neste artigo.

Por exemplo, para lidar com todos os e-mails sinalizados mais rapidamente ou compartilhá-los com outra pessoa, você pode exportá-los para uma planilha do Excel. Aqui vamos apresentar 2 abordagens para realizá-lo. O primeiro usa o recurso padrão “Importar e exportar” depois de encontrar e-mails sinalizados. Para ser honesto, é um pouco tedioso. Assim, neste último, ensinaremos uma maneira mais conveniente de aplicar o VBA.

Método 1: Exportar manualmente todos os e-mails sinalizados encontrados

1. Primeiro de tudo, clique na caixa de pesquisa acima da lista de e-mail.
2. Em seguida, clique em “Todos os itens de correio” no grupo “Escopo” na guia “Pesquisar”.
3. Em seguida, clique no botão “Sinalizado” no grupo “Definir”.
4. Depois de todos os e-mails sinalizados mostrados na lista, selecione um e-mail e pressione “Ctrl + A” para selecionar todos eles.
5. Em seguida, pressione os atalhos de tecla “Ctrl + Shift + V”.
6. Na nova caixa de diálogo, crie uma nova pasta no arquivo do Outlook.
7. Posteriormente, selecione a nova pasta criada e clique em “OK”, que irá mover todos os e-mails sinalizados encontrados para a nova pasta.
8. Depois, clique em “Arquivo” > “Abrir” > “Importar”,
9. Na caixa de diálogo pop-up, escolha “Exportar para um arquivo” > “Avançar” > “Microsoft Excel 97-2003” > “Avançar”.
10. Na nova tela, selecione a pasta correta e clique em “Avançar”.
11. Posteriormente, siga os assistentes para concluir “Exportar”.
12. Você obterá um novo arquivo do Excel, mostrado na captura de tela a seguir.

Método 2: Exportar a lista de todos os e-mails sinalizados via VBA

1. No Outlook, pressione “Alt + F11” para acionar o editor VBA.
2. Em seguida, habilite “MS Excel Object” de acordo com “Como adicionar uma referência à biblioteca de objetos em VBA".
3. Em seguida, copie o código VBA abaixo em um módulo.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllFlaggedEmailsToExcel()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
  
    'Select a source PST file
    Set objOutlookFile = Outlook.Application.Session.PickFolder
 
    If Not (objOutlookFile Is Nothing) Then
       'Create a new Excel file
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
       objExcelApp.Visible = True
 
       With objExcelWorksheet
           .Cells(1, 1) = "Subject"
           .Cells(1, 1).Font.Bold = True
           .Cells(1, 2) = "Start Date"
           .Cells(1, 2).Font.Bold = True
           .Cells(1, 3) = "Due Date"
           .Cells(1, 3).Font.Bold = True
           .Cells(1, 4) = "From"
           .Cells(1, 4).Font.Bold = True
           .Cells(1, 5) = "To"
           .Cells(1, 5).Font.Bold = True
      End With
 
      For Each objFolder In objOutlookFile.Folders
          If objFolder.DefaultItemType = olMailItem Then
             Call ProcessMailFolders(objFolder)
          End If
      Next
 
      objExcelWorksheet.Columns("A:E").AutoFit

      MsgBox "Completed!", vbInformation + vbOKOnly, "Export Emails"
    End If
End Sub

Sub ProcessMailFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objFlaggedMail As Outlook.MailItem
    Dim nLastRow As Integer
    Dim objSubfolder As Outlook.Folder
 
    For i = 1 To objCurrentFolder.Items.Count
        If objCurrentFolder.Items(i).Class = olMail Then
           'Export the information of each flagged email to Excel
           Set objMail = objCurrentFolder.Items(i)
           If objMail.IsMarkedAsTask = True And objMail.FlagStatus <> olFlagComplete Then
              Set objFlaggedMail = objMail
 
              With objExcelWorksheet
                   nLastRow = .Range("A" & .Rows.Count).End(xlUp).Row + 1
                   .Range("A" & nLastRow) = objFlaggedMail.Subject
                   .Range("B" & nLastRow) = objFlaggedMail.TaskStartDate
                   .Range("C" & nLastRow) = objFlaggedMail.TaskDueDate
                   .Range("D" & nLastRow) = objFlaggedMail.SenderName
                   .Range("E" & nLastRow) = objFlaggedMail.To
              End With
          End If
        End If
    Next i
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessMailFolders(objSubfolder)
       Next
    End If
End Sub

4. Por fim, coloque o cursor na sub-rotina “ExportAllFlaggedEmailsToExcel” e pressione o botão “F5”.
5. Em seguida, selecione um arquivo do Outlook na nova caixa de diálogo.
6. Quando você receber o prompt “Concluído”, também receberá um novo arquivo do Excel, como na imagem abaixo.

Proteja seu Outlook contra corrupção

O Outlook é propenso a erros e corrupção, tornando a proteção dos nossos dados uma tarefa árdua. Sem dúvida, a maneira mais eficaz e prática é fazer backups regulares dos dados do Outlook. Além disso, também é necessário obter uma ferramenta de reparo do Outlook poderosa e confiável, como... DataNumen Outlook Repair. Será útil se ferramenta de reparo da caixa de entrada não faz efeito.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo fixo SQL Server e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com