2 métodos para excluir em lote todos os contatos sem endereço de e-mail no Outlook

Se você descobrir que alguns contatos não têm endereço de e-mail no Outlook, convém processar cada pasta de contatos para excluir todos esses contatos. Este Post irá compartilhar 2 meios com você.

Talvez você tenha muitos contatos no Outlook e alguns deles não tenham endereço de e-mail. Se você acha que eles não são mais úteis, você deve excluir todos os contatos sem endereço de e-mail. Da maneira padrão, você pode usar a “Pesquisa instantânea” para localizá-los e excluí-los manualmente, como no Método 1 a seguir. No entanto, é um pouco tedioso. Por isso, no Método 2, vamos te ensinar outra forma mais eficiente.

Método 1: Excluir manualmente após encontrar contatos sem endereço de e-mail

1. Para comotart, pressione as teclas “Ctrl + 3” para acessar o painel “Contatos”.
2. Em seguida, clique na caixa de pesquisa.
3. Em seguida, na faixa “Pesquisar” emergente, clique em “Todos os itens de contato”.
4. Em seguida, clique em “Tem endereço” > “Tem endereço de e-mail”.
5. Depois disso, o critério “NOT emailaddresses:=[]” será adicionado à caixa de pesquisa. Você precisa remover o “NÃO”.
6. Posteriormente, todos os contatos sem endereço de e-mail serão listados.
7. Agora, você deve selecionar manualmente os contatos nos resultados da pesquisa, pois seus grupos de contatos também devem estar na lista.
8. Por fim, pressione o botão da tecla “Del” para excluir todos os contatos selecionados.

Método 2: Excluir em lote todos os contatos sem endereço de e-mail com VBA

1. Primeiro, toque em “Alt + F11” para iniciar o editor VBA no Outlook.
2. Na nova tela, copie o seguinte código VBA em um módulo.

Sub BatchDeleteAllContactsWithoutEmailAddress()
    Dim objStore As Outlook.Store
    Dim lTotalCount As Long
 
    lTotalCount = 0
    'Process all stores in your Outlook
    For Each objStore In Application.Session.Stores
       Call ProcessContactFolders(objStore.GetRootFolder.Folders, lTotalCount)
    Next
 
    MsgBox lTotalCount & " contacts are deleted!", vbInformation + vbOKOnly, "Delete Contacts"
End Sub

Sub ProcessContactFolders(ByVal objFolders As Outlook.Folders, lCount As Long)
    Dim objFolder As Outlook.Folder
    Dim i As Long
    Dim objContact As Outlook.ContactItem
    Dim objSubfolder As Outlook.Folder

    For Each objFolder In objFolders
        If (objFolder.DefaultItemType = olContactItem) And (objFolder.Name <> "Skype Contacts") Then
           For i = objFolder.Items.Count To 1 Step -1
               If objFolder.Items(i).Class = olContact Then
                  Set objContact = objFolder.Items(i)
                  'Delete the contact w/o email address
                  If (objContact.Email1Address = "") And (objContact.Email2Address = "") And (objContact.Email3Address = "") Then
                     objContact.Delete
                     lCount = lCount + 1
                  End If
               End If
           Next
 
           'Process subfolders recursively
           If objFolder.Folders.Count > 0 Then
              Call ProcessContactFolders(objFolder.Folders, lCount)
           End If
       End If
    Next
End Sub

3. Posteriormente, clique na sub-rotina “BatchDeleteAllContactsWithoutEmailAddress”.
4. Eventualmente, pressione “F5” para acionar esta macro.
5. Ao concluir, você receberá uma mensagem sobre os resultados, como na imagem abaixo.
6. Todos os contatos sem endereço de e-mail foram movidos para a pasta “Itens Excluídos”.

Mantenha-se Longe de Todos os Riscos Potenciais

O Outlook pode ser danificado devido a vários fatores, como vírus, erros do usuário, falhas de software e de hardware. Você deve estar relutante em sofrer danos no Outlook, então você precisa manter todos esses riscos potenciais sob controle. Por exemplo, você precisa montar um software antivírus potente em seu PC. Além disso, você precisa fazer backup dos dados do Outlook regularmente. Por último, mas não menos importante, é melhor preparar uma ferramenta de reparo robusta e confiável, como DataNumen Outlook Repair. Ele pode corrigir o seu PST corrompido arquivo com facilidade.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo SQL Server corrupção e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com