Cara Mencari Perenggan Satu-ayat dengan pantas dalam Dokumen Word Anda

Dalam catatan ini, kami ingin menunjukkan kepada anda cara cepat untuk mencari semua perenggan satu ayat dalam dokumen Word anda melalui VBA.

Sesekali, beberapa dokumen boleh mempunyai keperluan yang sangat spesifik untuk format dan strukturnya. Contohnya, anda mungkin tidak dibenarkan memiliki perenggan dengan hanya satu ayat. Perenggan-perenggan ini tidak sukar dikenali, tetapi memerlukan masa, terutama dokumen yang panjang.

Hari ini, kami akan menawarkan cara yang pantas untuk menentukan semua perenggan satu ayat dalam dokumen anda.

Cari Semua Perenggan Satu-ayat dalam Satu Dokumen

1. Pertama, Word mengira titik sebagai ayat. Jadi jika ada kata-kata seperti "Mr." atau "Ms.", Word menganggapnya sebagai ayat. Untuk mengecualikan gangguan seperti itu, anda perlu mengganti "Mr." dengan "Mr". Apabila selesai mencari perenggan ayat tunggal, anda boleh mengubahnya kembali. Untuk menggantikan perkataan, anda boleh merujuk pautan ini: Cara Mencari dan Mengganti Beberapa Item dalam Dokumen Word Anda
2. Kedua, tekan "Alt + F11" untuk mencetuskan editor VBA.
3. Kemudian klik projek "Normal".
4. Klik tab "Masukkan" pada bar menu dan pilih "Modul" pada menu lungsur.
5. Seterusnya klik dua kali pada modul untuk membukanya.
6. Tampal kod berikut pada modul:

Sub HighlightParagraphsWithSingleSentence()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim nHighlightNum As Integer
 
  nCountParagraph = ActiveDocument.Paragraphs.Count
  nHighlightNum = 0
 
  For nParagraphNum = 1 To nCountParagraph
    Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
    nCountSentence = objParagraphRange.Sentences.Count
    ' Highlight all paragraphs with single-sentence.
    If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
      nHighlightNum = nHighlightNum + 1
      objParagraphRange.HighlightColorIndex = wdYellow
    End If
  Next

  If nHighlightNum > 0 Then
    MsgBox ("There are " & nHighlightNum & " paragraphs with single sentence and they are highlighted.")
  Else
    MsgBox ("There are no paragraphs with single sentence")
  End If

End Sub

7. Akhir sekali, klik butang "Jalankan" atau tekan "F5".

Anda akan menerima kotak mesej seperti itu, memberitahu anda bahawa pekerjaan telah selesai.

Cari Semua Perenggan Satu-ayat dalam Pelbagai Dokumen

1. Untuk bermula, anda perlu meletakkan semua dokumen sasaran dalam folder.
2. Kemudian pasang dan jalankan makro berikut:

Sub HighlightParagraphsWithSingleSentenceInMultipleFiles()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim nHighlightNum As Integer
  Dim strSummary As String

  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)

  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No Folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.doc*", vbNormal)
 
  While strFile <> ""
    nHighlightNum = 0
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    Set objDoc = ActiveDocument
    nCountParagraph = ActiveDocument.Paragraphs.Count
 
    For nParagraphNum = 1 To nCountParagraph
      Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
      nCountSentence = objParagraphRange.Sentences.Count
      ' Highlight all paragraphs with single-sentence.
      If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
        nHighlightNum = nHighlightNum + 1
        objParagraphRange.HighlightColorIndex = wdYellow
      End If
    Next
    objDoc.ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
    objDoc.Save
    If nHighlightNum = 0 Then
      objDoc.Close
    End If
 
    strSummary = strSummary & strFile & " : " & nHighlightNum & " paragraphs with single sentence." & vbCrLf
    strFile = Dir()
  Wend
  MsgBox (strSummary)
 
End Sub

3. Di tetingkap "Browse" terbuka, pilih folder tempat anda menyimpan dokumen dan klik "OK".

Makro kemudian akan menyoroti semua perenggan satu ayat dan membiarkan dokumen terbuka. Sekiranya dokumen tidak mengandungi perenggan satu ayat, dokumen itu akan ditutup. Selain itu, ada kotak pesan, yang menunjukkan jumlah perenggan satu ayat dalam setiap dokumen.

Tangani Insiden Kehilangan Data

Kesalahan pengguna dan pemadaman elektrik secara tiba-tiba boleh mengakibatkan Word mati. Walaupun perkataan yang runtuh tidak hanya dapat mempengaruhi pekerjaan harian, tetapi juga membawa kepada kerosakan docIni bukanlah bahagian yang paling menjengkelkan dalam bencana data. Adalah lebih baik untuk mendapatkan utiliti pembaikan untuk memulihkan data dengan segera.

Pengenalan Pengarang:

Vera Chen adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk pulih cemerlang dan pdf membaiki produk perisian. Untuk maklumat lebih lanjut, lawati www.datanumen.com