Cara Cepat Mengeksport Jumlah Masa yang Dibelanjakan pada Janji Temu Outlook di Setiap Kategori Warna

Sekiranya anda ingin membuat laporan mengenai jumlah waktu yang anda habiskan untuk janji temu dalam setiap kategori warna, anda dapat menggunakan kaedah yang diperkenalkan dalam artikel ini. Ini dapat membantu anda mencapainya dalam masa yang cepat tanpa perlu mengira secara manual.

Ramai pengguna sudah biasa merekodkan kebanyakan aktiviti mereka dalam kalendar Outlook. Selain itu, untuk mengurus dan membezakannya dengan lebih mudah, mereka menetapkan kategori kepada setiap satunya. Dalam kes ini, sesetengah pengguna ingin menjana laporan yang menunjukkan jumlah masa yang dihabiskan untuk item kalendar dalam setiap kategori warna. Tidak syak lagi, adalah menyusahkan untuk mengira dan memasukkan secara manual. Oleh itu, di sini kami akan berkongsi cara yang boleh menyelesaikan tugas ini melalui satu klik mudah.

Eksport Jumlah Masa yang Dibelanjakan untuk Janji Temu di Setiap Kategori Warna

1. Pertama, lancarkan aplikasi Outlook anda.
2. Kemudian, setelah memasuki jendela Outlook, Anda dapat mengetuk tombol "Alt + F11".
3. Selepas itu, anda akan mendapat akses ke tetingkap "Microsoft Visual Basic for Applications".
4. Seterusnya, anda dikehendaki mendayakan “Microsoft Excel Object Library”. Anda boleh mengklik “Tools” > “Reference” untuk melakukannya.
5. Kemudian, anda harus mencari dan membuka modul yang tidak digunakan.
6. Selepas itu, anda perlu menyalin kod VBA berikut ke dalam modul ini.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. Akhirnya anda boleh mencetuskan makro ini, tidak kira dengan mengklik ikon "Jalankan" di bar alat atau menekan butang "F5".
8. Kemudian, anda akan diminta untuk memilih kalendar tertentu.
9. Selepas anda memilih dan tekan "OK", makro akan terus berjalan. Setelah selesai, akan ada fail Excel baru yang dipaparkan di latar belakang.
10. Anda boleh mengaksesnya. Ia akan kelihatan seperti tangkapan skrin berikut:

Awasi Potensi Ancaman Mengenai Outlook Anda

Pengguna Outlook harus memerhatikan semua potensi risiko, termasuk lampiran e-mel yang tidak diketahui, pautan tertanam dan kesalahan manusia. Jika tidak, Outlook anda boleh rosak pada bila-bila masa. Juga, membuat sandaran data Outlook secara berkala dan menyimpan alat pembaikan khusus adalah perkara penting. DataNumen Outlook Repair adalah salah satu alat pembaikan yang paling disyorkan. Ia boleh baiki Outlook masalah dalam sekejap.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk mdf rosak dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com