Cara Cepat Mengeksport Jumlah Item dalam Setiap Folder Outlook ke Excel

Sekiranya anda ingin mendapatkan laporan mengenai jumlah item di setiap folder Outlook, anda boleh menggunakan kaedah yang diperkenalkan dalam artikel ini. Ia akan membuat pengiraan dan mengeksport hasilnya ke dalam fail Excel dengan cepat.

Dalam artikel saya sebelum ini - “Cara Dapatkan Jumlah Item dengan Cepat dalam Folder dan Semua Subfoldernya melalui Outlook VBA", Anda boleh mempelajari kaedah menggunakan VBA untuk mendapatkan jumlah item dalam folder. Namun, dengan cara itu, jika anda ingin mengira item dalam semua folder, anda harus memilih setiap folder dan menjalankan makro satu demi satu. Agak membosankan. Oleh itu, kami akan mengajar anda kaedah lain, yang akan mengeksport kiraan ke fail Excel.

Eksport Jumlah Jumlah Item di Setiap Folder Outlook ke Excel

1. Pada awalnya, lancarkan program Outlook anda.
2. Kemudian tekan butang kekunci "Alt + F11" di tetingkap Outlook utama.
3. Seterusnya anda akan masuk ke tetingkap "Microsoft Visual Basic for Applications", di mana anda perlu membuka modul yang tidak digunakan.
4. Selepas itu, salin dan tampal kod VBA berikut ke dalam modul ini.

Public strExcelFile As String
Public objExcelApp As Excel.Application
Public objExcelWorkbook As Excel.Workbook
Public objExcelWorksheet As Excel.Worksheet

Sub Export_CountOfItems_InEachFolder_toExcel()
    Dim objSourcePST As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Create a new Excel file
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Folder"
    objExcelWorksheet.Cells(1, 2) = "Count Items"
 
    'Select a source PST file
    Set objSourcePST = Outlook.Application.Session.PickFolder

    For Each objFolder In objSourcePST.folders
        Call ProcessFolders(objFolder)
    Next
 
    'Fit the columns from A to B
    objExcelWorksheet.Columns("A:B").AutoFit
 
    strExcelFile = "E:\Outlook\" & objSourcePST.Name & " Folder Items Count (" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim lCurrentFolderItemCount As Long
    Dim nLastRow As Integer
 
    lCurrentFolderItemCount = objCurrentFolder.Items.Count
 
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1

    'Add the values into the columns
    objExcelWorksheet.Range("A" & nLastRow) = objCurrentFolder.FolderPath
    objExcelWorksheet.Range("B" & nLastRow) = lCurrentFolderItemCount
 
    If objCurrentFolder.folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

5. Selepas itu, anda perlu mengubah tahap keselamatan makro Outlook anda menjadi rendah.
6. Kemudian anda boleh kembali ke makro yang baru ditambahkan dan tekan butang F5 untuk menjalankan makro ini.
7. Seterusnya anda perlu memilih fail PST sumber dan tekan "OK".
8. Selepas makro selesai, anda boleh pergi ke folder tempatan yang telah ditentukan untuk mencari fail Excel baru, yang akan kelihatan seperti tangkapan skrin berikut:

Selesaikan Kesalahan PST yang Mengganggu

Mungkin anda pernah menemui pelbagai masalah semasa menggunakan Outlook. Untuk menangani masalah kecil, anda boleh menggunakan jalan keluar alat pembaikan peti masuk. Walaupun begitu, jika masalahnya sangat serius sehingga melebihi apa yang dapat dilakukan oleh alat inbuilt, anda harus menggunakan alat yang lebih kuat, seperti DataNumen Outlook Repair.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk pembaikan mdf dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com