Cara Cepat Mengeksport Semua Lampiran Gambar E-mel Outlook ke a PDF File

Sekiranya anda ingin cepat mengeksport semua lampiran gambar dari e-mel Outlook ke PDF fail, anda boleh menggunakan kaedah yang diperkenalkan dalam artikel ini. Ini menggunakan sekeping kod VBA untuk mewujudkan "eksport" tersebut dalam waktu yang cepat.

Kadang-kadang, anda mungkin mahu menggabungkan banyak gambar dengan a PDF fail, seperti mengeksport semua lampiran gambar e-mel ke PDF fail. Kedengarannya agak sukar. Tetapi berikut ini, kami akan menunjukkan kaedah, yang dapat mencapainya dengan cepat tanpa perlu repot.

Eksport Semua Lampiran Imej E-mel ke a PDF File

1. Untuk sebagaitart, lancarkan program Outlook anda seperti biasa.
2. Kemudian, di tetingkap Outlook utama, ketuk butang kunci "Alt + F11".
3. Selepas itu, anda akan melihat tetingkap "Microsoft Visual Basic for Applications" pop timbul.
4. Di tetingkap ini, anda perlu mengakses modul yang tidak digunakan.
5. Seterusnya, anda boleh menyalin dan menampal kod VBA berikut ke dalam modul ini.

Sub ExportAllImageAttachmentsIntoPdfFile()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim objWordApp As Word.Application
    Dim objTempDocument As Word.Document
    Dim strImage As String
    Dim objInlineShape As Word.InlineShape
    Dim strPDF As String
 
    Set objSourceMail = Application.ActiveInspector.currentItem
 
    If Not (objSourceMail Is Nothing) Then
 
       Set objWordApp = CreateObject("Word.Application")
       Set objTempDocument = objWordApp.Documents.Add
       objWordApp.Visible = True
       objTempDocument.Activate
 
       strTempFolder = Environ("Temp") & "\" & Format(Now, "yyyymmddhhmmss") & "\"
       MkDir (strTempFolder)
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.Attachments
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                           objAttachment.SaveAsFile strTempFolder & objAttachment.filename
              End Select
           End If
       Next
 
       strImage = Dir(strTempFolder & "*.*", vbNormal)

       Do Until Len(strImage) = 0
          With Selection
               .InlineShapes.AddPicture (strTempFolder & strImage)
               .TypeParagraph
               .Collapse Direction:=wdCollapsEnd
               .ParagraphFormat.Alignment = wdAlignParagraphCenter
               .TypeParagraph
          End With
          strImage = Dir()
       Loop

       For Each objInlineShape In objTempDocument.InlineShapes
           objInlineShape.Select
           Selection.ParagraphFormat.Alignment = wdAlignParagraphCenter
           objInlineShape.ScaleHeight = 50
           objInlineShape.ScaleWidth = 50
       Next
 
       'Change the path to save the PDF file
       strPDF = "E:\Image Attachments.pdf"
 
       'Export the temp Word document as a PDF file
       objTempDocument.ExportAsFixedFormat strPDF, wdExportFormatPDF
  
       objTempDocument.Close False
       objWordApp.Quit
 
       MsgBox "Complete!" 
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

6. Selepas itu, anda boleh menutup tetingkap semasa.
7. Kemudian, anda boleh pergi ke "File"> "Options"> "Quick Access Toolbar". Sekarang anda boleh menambahkan makro baru ke Bar Alat Akses Pantas.
8. Akhirnya, anda boleh mencuba makro ini.

• Pertama, buka e-mel yang lampiran gambarnya ingin anda eksport ke PDF fail.
• Kemudian, klik butang makro di Bar Alat Akses Pantas.
• Apabila makro selesai, anda akan mendapat mesej.
• Selepas itu, anda boleh menuju ke folder tempatan yang telah ditentukan untuk mencari a PDF fail, yang mengandungi semua gambar yang dilampirkan pada e-mel terbuka.

Ambil Data Outlook yang Berkompromi

Sekiranya Outlook rosak, anda harus berusaha untuk memulihkan data yang rosak. Dalam kes ini, pertama sekali anda boleh mencuba alat pembaikan terpasang - Scanpst. Dengan mengandaikan bahawa itu bukan tugas membaiki fail Outlook, anda juga boleh menggunakan alat luaran, seperti DataNumen Outlook Repair. Ia bagus untuk memulihkan Outlook yang rosak fail dengan rasuah minimum.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk pembaikan mdf dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com