Cara Cepat Menyalin Struktur Folder dari Satu Outlook PST File ke yang lain melalui VBA

Sekiranya anda ingin menyalin struktur folder dari satu fail PST Outlook ke yang lain, anda boleh menggunakan kaedah yang diperkenalkan dalam artikel ini, yang akan mengajar anda bagaimana menggunakan VBA untuk mendapatkannya dalam satu masa.

Mungkin, untuk menguruskan e-mel anda dengan lebih baik, anda telah membuat beberapa folder tersuai di fail Outlook utama anda. Oleh itu, semasa membuat fail Outlook PST baru, anda mungkin mahu menerapkan struktur folder yang sama. Sebenarnya, dalam artikel saya sebelumnya - “2 Langkah untuk Mengekalkan Hierarki Folder Semasa dalam Fail Outlook Baharu", Anda dapat mempelajari kaedah tradisional, yang menggunakan ciri" Arkib "untuk mencapainya. Walaupun begitu, sebenarnya, ia masih agak membosankan. Berbanding dengannya, menggunakan kod VBA untuk mendapatkannya akan lebih cepat. Oleh itu, berikut ini, kami akan memberitahu anda langkah dan kod yang terperinci.

Salin Struktur Folder dari Satu Outlook PST File ke yang lain

1. Pada mulanya, mulakan program Outlook anda.
2. Kemudian di tetingkap Outlook, tekan butang kekunci "Alt + F11".
3. Selanjutnya anda akan memasuki tetingkap editor Outlook VBA.
4. Selepas itu, salin dan tampal kod VBA berikut ke modul baru.

Public objNewPSTFolder As Outlook.Folder
 
Sub CopyFolderStructure()
    Dim objFolders As Outlook.Folders
    Dim objFolder As Outlook.Folder
 
    'Get the folders of the source Outlook PST file
    Set objFolders = Outlook.Application.Session.Folders("Personal").Folders
 
    'Create the new pst file in your desired local folder and name
    Outlook.Application.Session.AddStore "E:\New PST File.pst"
    Set objNewPSTFolder = Session.Folders.GetLast()
 
    For Each objFolder In objFolders
        CreateFolder objFolder
    Next
 
    MsgBox "Completed!", vbOKOnly + vbInformation, "Copy Folder Structure"
End Sub
 
Sub CreateFolder(objFolder As Outlook.Folder)
    Dim objSubFolder As Outlook.Folder
 
    'Only copy the mail folder
    If (objFolder.DefaultItemType = olMailItem) Then
       'New Outlook PST file auto includes the "Deleted Items" folder, so skip it
       'Skip the useless mail folders - "Conversation Action Settings" and "Quick Step Settings"
       If (objFolder.Name <> "Deleted Items") And (objFolder.Name <> "Conversation Action Settings") And (objFolder.Name <> "Quick Step Settings") Then
 
          'Create the new folder
          objNewPSTFolder.Folders.Add objFolder.Name
          Set objNewPSTFolder = objNewPSTFolder.Folders.Item(objFolder.Name)
 
          For Each objSubFolder In objFolder.Folders
              CreateFolder objSubFolder
          Next
 
          Set objNewPSTFolder = objNewPSTFolder.parent
       End If
    End If

End Sub

5. Selepas itu, ubah tahap keselamatan makro anda ke rendah.
6. Kemudian kembali ke tetingkap editor VBA dan tekan butang kekunci "F5" untuk menjalankan makro.
7. Akhirnya, setelah makro selesai berfungsi, anda akan mendapat mesej, yang meminta "Selesai!".
8. Pada ketika ini, anda boleh pergi ke panel navigasi mel. Anda akan melihat Fail Data Outlook baru yang berada dalam struktur folder yang sama dengan fail PST sumber, seperti gambar di bawah:

Mengatasi Masalah PST yang Mengganggu

Oleh kerana Outlook PST terdedah kepada ralat, ramai di antara anda pasti menghadapi pelbagai masalah di Outlook. Menghadapi mereka, pertama-tama anda dapat menggunakan alat perbaikan kotak masuk Outlook untuk mencuba. Sekiranya gagal, anda kemudian boleh menggunakan alat pihak ketiga yang lebih kuat, seperti DataNumen Outlook Repair, yang boleh betulkan Outlook Kesalahan PST seperti angin.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk SQL Server menetapkan dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com