Cara Cepat Melampirkan Fail Terakhir Diubah Suai dalam Folder Windows pada E-mel Outlook Anda

Kadangkala, anda mungkin ingin mencari dan melampirkan fail terakhir diubah suai dengan cepat dalam folder Windows tertentu pada e-mel Outlook. Dalam kes ini, anda boleh menggunakan kaedah yang diperkenalkan dalam artikel ini.

Sesetengah pengguna ingin membiarkan Outlook mencari dan menambahkan fail terakhir yang diubah suai dalam folder Windows ke e-mel dengan cepat, seperti fail yang paling baru dibuat, diubah atau disimpan. Walau bagaimanapun, Outlook tidak menawarkan ciri langsung dan asli sedemikian. Oleh itu, berikut, kami akan mendedahkan sekeping kod VBA, yang boleh melaksanakannya dengan mudah.

Lampirkan Fail Terakhir Diubah Suai dalam Folder Windows ke E-mel

1. Pada awalnya, anda harus melancarkan aplikasi Outlook anda.
2. Kemudian, selepas anda masuk ke tetingkap Outlook utama, anda boleh menekan butang kekunci "Alt + F11".
3. Seterusnya anda akan mengakses tetingkap editor Outlook VBA dalam kejayaan.
4. Selepas itu, anda perlu mencari dan membuka modul yang tidak digunakan.
5. Dan kemudian salin dan tampal kod VBA berikut ke dalam tetingkap modul ini.

Sub AttachLastModifiedSpecificFile()
    Dim objShell As Object
    Dim objSelectedFolder As Object
    Dim objFileSystem As Object
    Dim strSourceFolderPath As String
    Dim objSourceFolder As Object
    Dim objFile As Object
    Dim dLastModifiedDate As Date
    Dim strLastModifiedFilePath As String
    Dim objMail As Outlook.MailItem
 
    On Error GoTo ErrorHandler
    'Select a local source folder
    Set objShell = CreateObject("Shell.Application")
    Set objSelectedFolder = objShell.BrowseForFolder(0, "Select the source folder", 0, "")
    strSourceFolderPath = objSelectedFolder.self.Path
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objSourceFolder = objFileSystem.GetFolder(strSourceFolderPath)
 
    If objSourceFolder.Files.Count > 0 Then
       For Each objFile In objSourceFolder.Files
           'Find the last modified file within "xlsx" file type in the selected Windows folder
           If (objFile.DateLastModified > dLastModifiedDate) And (objFileSystem.GetExtensionName(objFile) = "xlsx") Then
              'You can add or change criteria, such as
              'Left(objFile.Name, 4) = "Test" ---> file whose name begins with "Test"
              '(objFile / 1024) / 1024 > 2 --> File exceeds 2 MB
              'Note: Use "And" to connect more than one criteria
              strLastModifiedFilePath = objFile.Path
              dLastModifiedDate = objFile.DateLastModified
           End If
       Next
 
       If strLastModifiedFilePath <> "" Then
          'Confirm attaching it to the current outlook email
          strMsg = "The last modified file in the " & Chr(34) & strSourceFolderPath & Chr(34) & " is: " & vbCrLf & vbCrLf & "File: " & strLastModifiedFilePath & vbCrLf & "Date: " & dLastModifiedDate & vbCrLf & vbCrLf & "Do you want to attach it?"
          nPrompt = MsgBox(strMsg, vbQuestion + vbYesNo, "Confirm Attaching Last Modified File")
 
          If nPrompt = vbYes Then
             Set objMail = Outlook.Application.ActiveInspector.CurrentItem
             objMail.Attachments.Add strLastModifiedFilePath
         End If
      Else
         MsgBox "No file in the selected folder can meet your predefined criteria!", vbExclamation + vbOKOnly
      End If
    Else
      MsgBox "No file exists in the selected Windows folder!", vbExclamation + vbOKOnly
    End If
 
ErrorHandler:
    Exit Sub
End Sub

6. Selepas itu, anda boleh keluar dari tetingkap editor VBA semasa dan teruskan menambah makro baharu pada Bar Alat Akses Pantas atau reben tetingkap Mesej.
7. Kemudian anda perlu mengubah tahap keselamatan makro Outlook anda menjadi rendah.
8. Akhirnya anda boleh mencuba.

• Pertama, buat dan karang e-mel Outlook baharu seperti biasa.
• Kemudian tekan butang makro dalam Bar Alat Akses Pantas, seperti imej di bawah:
• Seterusnya anda akan diminta untuk memilih folder Windows sumber dan tekan "OK".
• Jika terdapat fail sedemikian dalam folder Windows yang dipilih, anda akan mendapat gesaan seperti tangkapan skrin berikut:
• Apabila anda menekan "Ya", fail ini akan dilampirkan sekali gus.

Selesaikan Masalah Outlook Secepat Mungkin

Setiap kali anda menghadapi sebarang isu Outlook, adalah disyorkan untuk menyelesaikannya secepat mungkin. Dalam keadaan ini, lebih baik anda menyediakan yang mantap Pembaikan Outlook alat di muka, seperti DataNumen Outlook Repair. Ia mampu membetulkan ralat PST dan menyelamatkan data Outlook anda dengan berkesan.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk mdf rosak dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com