Cara Mencegah Penghantaran Email ke Alamat E-mel Khusus di Outlook Anda

Ramai pengguna berharap dapat menyekat menghantar e-mel secara tidak sengaja ke alamat e-mel tertentu di Outlook. Oleh itu, dalam artikel ini, kami akan memperkenalkan kaedah untuk merealisasikannya.

Outlook tidak menyediakan ciri asli untuk menyekat penghantaran e-mel ke alamat e-mel tertentu. Oleh itu, jika anda ingin merealisasikannya, sedikit skrip diperlukan. Sekarang, dalam perkara berikut, kami akan berkongsi sekeping kod VBA sedemikian. Jika anda tidak tahu cara menggunakan VBA, anda boleh membaca siaran sebelumnya – “Cara Menjalankan Kod VBA di Outlook Anda".

Cegah Menghantar E-mel ke Alamat E-mel Khusus

1. Pada mulanya, akses editor Outlook VBA melalui "Alt + F11".
2. Kemudian, masukkan kod berikut ke dalam projek "ThisOutlookSession".

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    Dim objMail As Outlook.MailItem
    Dim objRecipients As Outlook.Recipients
    Dim ContactGroupFound As Boolean
    Dim i, n As Long
    Dim objRecipient As Outlook.Recipient
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Expand the contact groups in Recipients
       ContactGroupFound = True
       Do While ContactGroupFound = True
          Set objRecipients = objMail.Recipients
          ContactGroupFound = False
 
          For i = objRecipients.Count To 1 Step -1
              If objRecipients(i).AddressEntry.DisplayType <> olUser Then
                 For n = 1 To objRecipients(i).AddressEntry.Members.Count
                     If objRecipients(i).AddressEntry.Members.Item(n).DisplayType = olUser Then
                        objMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Address)
                     Else
                        objMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Name)
                        ContactGroupFound = True
                     End If
                 Next
                 objRecipients(i).Delete
              End If
          Next i
          objRecipients.ResolveAll
       Loop
 
       'Remove specific email address
       For Each objRecipient In objRecipients
           If objRecipient.Address = "shelly@datanumen.com" Then
              If MsgBox("Do you want to email to " & Chr(34) & "shelly@datanumen.com" & Chr(34) & "?", vbExclamation + vbYesNo) = vbNo Then
                 objRecipient.Delete
              End If
           End If
       Next
    End If
End Sub

3. Setelah itu, keluar dari tetingkap "Microsoft Visual Basic for Applications".
4. Akhirnya, cubalah dengan langkah berikut.

• Sebagai permulaan, tuliskan e-mel dan isikan penerima.
• Kemudian, klik butang "Hantar".
• Sekaligus, makro akan berfungsi untuk memperluas kumpulan kenalan dalam penerima jika ada dan mengetahui sama ada penerima mengandungi alamat e-mel tertentu.
• Sekiranya alamat dijumpai, anda akan mendapat mesej, seperti yang ditunjukkan dalam gambar berikut.
• Sekiranya anda memilih "Tidak", alamat e-mel tertentu akan dihapus dengan segera.
• Selepas surat dihantar, anda boleh memeriksa penerima, yang pastinya tidak mengandungi alamat e-mel tertentu.

Perbaiki Fail Outlook Anda yang Rosak

Pernahkah fail Outlook anda rosak? Itulah masalah yang paling menjengkelkan dalam Outlook. Apabila terdedah kepadanya, anda perlu memanipulasi Pembaikan PST, yang agak rumit. Seperti biasa, anda akan memikirkan penggunaan Scanpst pada kali pertama. Tetapi, malangnya, ia mungkin gagal dalam kes seperti itu. Tempat peranginan anda mestilah alat yang lebih berpengalaman, seperti DataNumen Outlook Repair, atau perkhidmatan pemulihan PST profesional.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk pembaikan sql dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com