Cara Cepat Mengekstrak Semua Penerima dari Beberapa Fail Mesej Outlook (.msg)

Sebilangan pengguna ingin dengan cepat mengekstrak semua penerima dari beberapa fail mesej Outlook yang disimpan dari e-mel Outlook. Sekarang, hlm iniost akan melihat ini untuk berkongsi pendekatan pantas.

Untuk mengekstrak penerima dari satu fail mesej Outlook, anda hanya boleh dua kali klik untuk membukanya dan kemudian menyalin penerima di tetingkap Mesej yang dibuka. Tetapi, jika anda perlu menangani sekumpulan fail mesej Outlook, kaedah manual tidak cukup cekap. Oleh itu, anda mungkin mencari kaedah yang lebih cekap. Di sini kami akan memperkenalkan yang demikian kepada anda. Teruskan membaca untuk mendapatkan maklumatnya.

Ekstrak Semua Penerima dari Beberapa Fail Mesej Outlook (.msg)

1. Untuk sebagaitart, dapatkan akses ke Outlook VBA editor sesuai dengan "Cara Menjalankan Kod VBA di Outlook Anda".
2. Seterusnya, salin dan tampal kod VBA berikut ke modul kosong.

Dim strRecipients As String

Sub ExtractRecipientsFromOutlookMSGFiles()
    Dim objShell, objWindowsFolder As Object
 
    strRecipients = ""
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       Call ProcessWindowsFolders(objWindowsFolder.self.Path & "\")
       'Display a Message
       MsgBox "Recipients: " & vbCrLf & strRecipients, vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessWindowsFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.Recipient
    Dim objSubfolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
 
    For Each objFile In objFolder.Files
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              Set objMail = objItem
              'Extract recipients' email addresses
              For Each objRecipient In objMail.Recipients
                  strRecipients = strRecipients & objRecipient.Address & vbCr
              Next
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
               Call ProcessWindowsFolders(objSubfolder.Path)
           End If
       Next
    End If
End Sub

3. Kemudian, gerakkan kursor di subrutin pertama.
4. Selepas itu, klik butang "Jalankan" atau tekan kekunci "F5".
5. Kemudian, dalam kotak dialog pop timbul, pilih folder Windows yang mengandungi fail mesej Outlook sumber (.msg).
6. Setelah memilih, klik "OK" untuk membiarkan makro terus berjalan.
7. Apabila makro selesai, mesej yang menyenaraikan semua alamat e-mel penerima yang diekstrak akan muncul, seperti yang ditunjukkan dalam tangkapan skrin berikut.

Lindungi Data Outlook Anda dari Jeopardy

Data Outlook diyakini terdedah kepada rasuah. Oleh itu, adalah tugas yang sangat berat untuk melindungi data Outlook. Ia mengharuskan anda untuk terus berusaha membuat cadangan tetap untuk data Outlook. Sekiranya mungkin, adalah wajar dan disarankan untuk menyediakan Outlook yang berpengalaman dan profesional Pembaikan PST alat, seperti DataNumen Outlook Repair, supaya anda dapat memperoleh penyelamatan segera dan tepat waktu sekiranya berlaku kerosakan Outlook.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk pulih Sql Server dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com