Cara Membuat Kumpulan Kenalan dengan Cepat dari Semua Kenalan Outlook dengan Tajuk Pekerjaan Tertentu

Untuk berkomunikasi dengan kenalan dengan tajuk pekerjaan tertentu dengan lebih mudah, anda mungkin mahu membuat kumpulan kenalan dengan cepat daripada kenalan ini. Sekarang, dalam artikel ini, kami akan berkongsi kaedah pantas dengan anda.

Jika anda kerap menghantar e-mel, tugasan atau jemputan mesyuarat secara berkumpulan kepada kenalan yang mempunyai tajuk pekerjaan tertentu, adalah lebih mudah jika anda membuat kumpulan kenalan daripada mereka. Secara amnya, dalam cara standard, anda perlu membuat kumpulan kenalan baharu dahulu dan kemudian menambah kenalan pada kumpulan sebagai ahli satu demi satu. Ia agak menyusahkan. Oleh itu, dalam perkara berikut, kami akan mengajar anda cara yang lebih cepat untuk mendapatkannya.

Buat Kumpulan Kenalan daripada Semua Kenalan dengan Tajuk Kerja Tertentu

1. Pada mulanya, dalam folder Kenalan, pilih kenalan yang mempunyai tajuk kerja tertentu.
2. Kemudian, tekan "Alt + F11" untuk mengakses editor Outlook VBA.
3. Seterusnya, salin kod VBA berikut ke dalam modul atau projek kosong.

Dim objContact As Outlook.ContactItem
Dim strJobTitle As String
Dim objNewGroup As Outlook.DistListItem
Dim objTempMail As Outlook.MailItem

Sub CreateContactGroupfromContactsSameJobTitle()
    Dim objStore As Outlook.Store
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objContact = Outlook.Application.ActiveExplorer.Selection(1)
    strJobTitle = objContact.JobTitle
 
    Set objNewGroup = Outlook.Application.CreateItem(olDistributionListItem)
    Set objTempMail = Outlook.Application.CreateItem(olMailItem)
 
    'Process all Contacts folders
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olContactItem Then
               Call ProcessContactsFolders(objFolder)
            End If
        Next
    Next
 
    objNewGroup.AddMembers objTempMail.Recipients
    objNewGroup.Display
End Sub

Sub ProcessContactsFolders(ByVal objCurFolder As Outlook.Folder)
    Dim objItem As Object
    Dim objSubfolder As Outlook.Folder
 
    For Each objItem In objCurFolder.Items
        If objItem.Class = olContact Then
           If objItem.JobTitle = strJobTitle Then
              'Add the contact having the specific job title to the new group
              objTempMail.Recipients.Add (objItem.Email1Address)
              objTempMail.Recipients.ResolveAll
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objCurFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurFolder.Folders
           Call ProcessContactsFolders(objSubfolder)
       Next
    End If
End Sub

4. Selepas itu, pindahkan kursor ke subrutin pertama.
5. Akhir sekali, ketik butang kekunci "F5" untuk menjalankan makro ini.
6. Apabila makro selesai, kumpulan kenalan baharu akan dipaparkan. Ia mengandungi semua kenalan dengan tajuk kerja yang sama bagi kenalan yang dipilih dalam Langkah 1.

Lindungi Data Outlook Dengan Berkesan

Walaupun Outlook kaya dengan ciri, ia tidak dapat menyingkirkan fakta bahawa ia terdedah. Jadi, jika anda tidak mahu kehilangan data Outlook berharga anda, anda perlu berusaha untuk melindunginya. Sebagai contoh, anda perlu membuat sandaran untuk data Outlook pada selang masa yang tetap. Juga, jika mampu milik, adalah disyorkan untuk mempunyai alat pembaikan PST yang canggih, seperti DataNumen Outlook Repair, yang boleh membaiki PST data dalam sekejap.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk sql rosak dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com