Cara Batch Convert & Attach Multiple Word Documents sebagai PDF Fail ke E-mel Outlook

Sangat mudah untuk melampirkan dokumen Word sebagai PDF failkan ke e-mel Outlook. Namun, jika anda ingin melampirkan beberapa dokumen Word sebagai PDF fail ke e-mel, anda boleh membaca artikel ini. Di sini kami akan menunjukkan kepada anda kaedah untuk mendapatkannya.

Untuk melampirkan dokumen Word sebagai PDF fail ke e-mel Outlook, anda boleh membuka dokumen Word terlebih dahulu dan pergi ke menu "Fail". Kemudian, anda boleh beralih ke tab "Simpan & Hantar", di mana terdapat butang "Hantar sebagai PDF", seperti tangkapan skrin berikut.

Oleh itu, cukup mudah untuk melampirkan dokumen Word sebagai PDF ke e-mel. Tetapi, jika anda ingin menukar dan melampirkan beberapa dokumen Word sebagai PDF fail ke surat, anda lebih baik menggunakan cara berikut. Ini dapat membolehkan anda mencapainya secara pukal.

Batch Convert & Attach Multiple Word Documents sebagai PDF Fail ke E-mel

1. Sebagai permulaan, kumpulkan dokumen Word yang anda inginkan dalam folder Windows yang sama.
2. Kemudian, lancarkan program Outlook.
3. Seterusnya, salin kod berikut ke dalam projek atau modul yang tidak digunakan.

Dim objMail As Outlook.MailItem

Sub BatchAttachMultipleWordDocumentsAsPDFToEmail()
    Dim objShell As Object
    Dim objWindowsFolder As Object
    Dim strWindowsFolder As String

    Set objMail = Outlook.Application.CreateItem(olMailItem)

    'Select the specific Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows folder:", 0, "")

    If Not objWindowsFolder Is Nothing Then
       strWindowsFolder = objWindowsFolder.self.Path & "\"

       Call ProcessFolders(strWindowsFolder)

       objMail.Display
    End If
End Sub

Sub ProcessFolders(strPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objWordApp As Word.Application
    Dim objWordDocument As Word.Document
    Dim strDocumentName As String
    Dim strPDF As String

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strPath)

    For Each objFile In objFolder.Files
        strFileExtension = objFileSystem.GetExtensionName(objFile)
        If LCase(strFileExtension) = "doc" Or LCase(strFileExtension) = "docx" Then
           Set objWordApp = CreateObject("Word.Application")
           Set objWordDocument = objWordApp.Documents.Open(objFile.Path)

           'Convert document to pdf
           strDocumentName = Left(objWordDocument.Name, (Len(objWordDocument.Name) - Len(strFileExtension)) - 1)
           strPDF = strPath & strDocumentName & ".pdf"
           objWordDocument.ExportAsFixedFormat strPDF, wdExportFormatPDF

           objWordDocument.Close False

           'Attach the pdf to email
           objMail.Attachments.Add strPDF

           Kill strPDF
        End If
    Next

    'Process all folders and subfolders
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
              ProcessFolders (objSubfolder.Path)
           End If
       Next
    End If
End Sub

4. Selepas itu, pindahkan kursor ke subrutin pertama.
5. Selepas itu, tekan "F5" untuk menjalankan makro ini dengan segera.
6. Dalam kotak dialog kecil pop timbul, pilih folder Windows tempat dokumen Word sumber disimpan.
7. Sekali gus, e-mel baru akan dibuat, di mana anda dapat melihat lampiran PDF fail, seperti screenshost berikut.

Diganggu oleh Masalah Outlook

Adakah anda terganggu oleh pelbagai masalah Outlook? Sebagai contoh, Outlook sering terjebak dalam keadaan "tidak bertindak balas" atau fail PST Outlook menjadi tidak dapat diakses, dll. Secara umum, anda boleh mencuba alat pembaikan peti masuk terlebih dahulu, scanpst, untuk menyelesaikan masalah PST. Namun, kadang-kadang, masalahnya mungkin melebihi apa yang dapat dilakukan oleh alat bawaan. Oleh itu, anda lebih baik menyimpan utiliti luaran yang lebih kuat di sekitarnya, seperti DataNumen Outlook Repair.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk pembaikan sql dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com