Cara Mengembangkan Semua Folder Secara Automatik melalui VBA semasa Memulakan Outlook Anda

Ramai pengguna berharap semua folder boleh dikembangkan secara automatik apabila mereka melancarkan Outlook mereka. Pada hakikatnya, Outlook tidak menyokongnya secara semula jadi. Oleh itu, untuk merealisasikannya, anda perlu menggunakan kod VBA. Catatan ini akan memberi anda panduan ringkas.

Anda mungkin telah mencipta banyak subfolder di bawah folder lalai dalam Outlook. Memandangkan terdapat begitu banyak folder, untuk mengaksesnya dengan cepat pada bila-bila masa, anda mungkin ingin memastikan semua folder sentiasa dikembangkan. Langkah pertama ialah menjadikan Outlook mengembangkan folder secara automatik semasa permulaan. Jelas sekali, tiada fungsi asli sedemikian dalam Outlook. Oleh itu, anda perlu menggunakan makro. Selepas itu, kami akan mengajar anda cara melakukannya dengan VBA. Mengenai cara menggunakan VBA, anda boleh merujuk artikel lain – “Cara Menjalankan Kod VBA di Outlook Anda".

Kembangkan Semua Folder Secara Automatik semasa Memulakan Outlook

1. Untuk permulaan, tekan "Alt + F11" di Outlook anda untuk mengakses editor VBA.
2. Kemudian, di tetingkap baru, masukkan kod ke dalam proyek "ThisOutlookSession".

'Auto expand all folders on startup
Private Sub Application_Startup()
    Call ExpandAllFolders
End Sub

Private Sub ExpandAllFolders()
    Dim objCurrentFolder As Outlook.Folder
    Dim objStore As Outlook.Store
    Dim objFileFolders As Outlook.Folders
    Dim objFolder As Outlook.Folder
   
    Set objCurrentFolder = Application.ActiveExplorer.CurrentFolder
 
    'Process all email accounts in your Outlook
    For Each objStore In Outlook.Application.Session.Stores
        Set objFileFolders = objStore.GetRootFolder.Folders
 
        For Each objFolder In objFileFolders
            Call LoopFolders(objFolder)
        Next
 
        DoEvents
        Set Application.ActiveExplorer.CurrentFolder = objCurrentFolder
    Next
End Sub

Sub LoopFolders(ByVal objCurFolder As Outlook.Folder)
    Dim objSubfolder As Outlook.Folder
 
    Set Application.ActiveExplorer.CurrentFolder = objCurFolder
    DoEvents
 
    'Process all subfolders recursively
    If objCurFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurFolder.Folders
           Call LoopFolders(objSubfolder)
       Next
    End If
End Sub

3. Selepas itu, tutup penyunting VBA.
4. Selepas itu, keluar dari aplikasi Outlook dengan betul.
5. Kemudian, mulakan Outlook anda. Pada ketika ini, makro akan berjalan secara automatik.
6. Selepas Outlook dimulakan, anda dapat melihat bahawa semua folder telah dikembangkan, seperti yang ditunjukkan dalam gambar di bawah.

Simpan Semua Makro Berbahaya di Bay

Adakah anda pernah menerima e-mel yang dilampirkan dengan fail yang mencurigakan atau disertakan dengan pautan yang tidak diketahui? Biasanya, semasa menghadapi e-mel seperti itu, anda harus meningkatkan kewaspadaan anda. Anda tidak seharusnya mudah mempercayai mereka kerana mereka mungkin membawa virus. Sebaik sahaja anda memuat turun lampiran atau membuka pautan, bukan sahaja Outlook tetapi juga komputer mungkin diserang. Pada masa itu, anda mesti baiki Outlook fail. Ini mungkin cukup menarik kecuali anda mempunyai sandaran Outlook yang dikemas kini atau menggunakan alat pemulihan yang kuat, seperti DataNumen Outlook Repair.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk SQL Server rasuah dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com