Bagaimana Mengesahkan Semua Pautan Pautan dalam Dokumen Word Anda melalui VBA

Dalam artikel ini, kami akan menunjukkan kepada anda cara automatik untuk mengesahkan kumpulan cepat semua hiperpautan dalam dokumen Word anda melalui VBA.

Dokumen Word boleh mengandungi banyak hiperpautan, ratusan malah. Antaranya, beberapa pautan tidak sah yang gagal membawa anda ke halaman web yang betul. Oleh itu, kami ingin menawarkan anda cara untuk menyemak semua pautan dalam dokumen melalui VBA dengan cepat.

Pasang dan Simpan Makro Word

1. Pertama sekali, buka editor VBA dengan "Alt+ F11".
2. Kemudian klik projek "Normal".
3. Seterusnya klik tab "Sisipkan" pada menu bar alat.
4. Dan pilih "Modul" pada menu.
5. Klik dua kali pada modul untuk membuka ruang pengeditan dan tampal kod berikut di sana:

Function CheckURL(strURL As String) As Boolean
  Dim objDemand As Object
  Dim varResult As Variant
 
  On Error GoTo ErrorHandler
  Set objDemand = CreateObject("WinHttp.WinHttpRequest.5.1")
 
  With objDemand
    .Open "GET", strURL, False
    .Send
    varResult = .StatusText
  End With
 
  Set objDemand = Nothing
 
  If varResult = "OK" Then
    CheckURL = True
  Else
    CheckURL = False
  End If
 
ErrorHandler:
End Function

Sub ReturnURLCheck()
  Dim objLink As Hyperlink
  Dim strLinkText As String
  Dim strLinkAddress As String
  Dim strResult As String
  Dim nInvalidLink As Integer, nTotalLinks As Integer
  Dim objDoc As Document
 
  Application.ScreenUpdating = False
 
  Set objDoc = ActiveDocument
  nTotalLinks = objDoc.Hyperlinks.Count
  nInvalidLink = 0
 
  With objDoc
    For Each objLink In .Hyperlinks
      strLinkText = objLink.Range.Text
      strLinkAddress = objLink.Address
 
      If Not CheckURL(strLinkAddress) Then
        nInvalidLink = nInvalidLink + 1
        strResult = frmCheckURLs.txtShowResult.Text
        frmCheckURLs.txtShowResult.Text = strResult & nInvalidLink & ". Invalid Link Information:" & vbNewLine & _
                                          "Displayed Text: " & strLinkText & vbNewLine & _
                                           "Address: " & strLinkAddress & vbNewLine & vbNewLine
      End If
    Next objLink
 
    frmCheckURLs.txtTotalLinks.Text = nTotalLinks 
    frmCheckURLs.txtNumberOfInvalidLinks.Text = nInvalidLink
    frmCheckURLs.Show Modal
 
  End With
  Application.ScreenUpdating = True
End Sub

Sub HighlightInvalidLinks()
  Dim objLink As Hyperlink
  Dim strLinkAddress As String
  Dim strResult As String
  Dim objDoc As Document
 
  Set objDoc = ActiveDocument
 
  With objDoc
    For Each objLink In .Hyperlinks
      strLinkAddress = objLink.Address
 
      If Not CheckURL(strLinkAddress) Then
        objLink.Range.HighlightColorIndex = wdYellow
      End If
    Next objLink
  End With
End Sub

6. Klik seterusnya "Simpan".
7. Kemudian tetapkan butang untuk makro. Anda boleh merujuk artikel berikut untuk maklumat terperinci:

Cara Menghapus Pemformatan Teks Tampal dengan Makro dan VBA di Word Anda

Buat Borang Pengguna

Dengan borang pengguna, anda boleh melihat dengan jelas jumlah pautan dalam dokumen semasa, bilangan pautan tidak sah dan butiran lanjut.

1. Pertama, klik "Sisipkan" di bar alat sekali lagi. Tetapi kali ini, pilih "Borang Pengguna".
2. Seterusnya tekan "F4" untuk membuka "Tetingkap Properties" di sudut kiri bawah. Saiz tingkap boleh laras.
3. Sekarang namakan borang pengguna sebagai "frmCheckURLs".
4. Tetapkan kapsyen sebagai "Semak URL".
5. Kemudian tetapkan fon dengan betul.
6. Seterusnya klik butang "Kotak Alat" di bar alat.
7. Sekarang klik "Label" pada kotak alat. Gunakan tetikus untuk menyeret label segi empat tepat pada borang pengguna.
8. Klik pada label untuk mengaktifkan tetingkap sifatnya. Tetapkan nama label sebagai "lblInvalidURLs", dan labelkan kapsyen sebagai "URL Tidak Sah:".
9. Seterusnya pilih fon dan warna hadapan yang sesuai untuk teks kapsyen label.
10. Pilih "Kotak Teks" pada kotak alat dan masukkan kotak teks pada borang pengguna. Laraskan saiznya.
11. Kemudian tetapkan nama kotak teks sebagai "txtShowResult".
12. Tetapkan fon dan warna depan seperti yang dikehendaki.
13. Cari "MultiLine", dan tetapkannya "True".
14. Cari "Bar Skrol" dan pilih bar menegak.
15. Seterusnya buat dua lagi label dan kotak teks.
16. Kemudian namakan label pertama sebagai "lblTotalLinks" dan tetapkan kapsyen sebagai "Jumlah pautan dalam dokumen ini".
17. Dan namakan label kedua sebagai "lblNumberOfInvalidLinks" dan tetapkan kapsyen sebagai "Bilangan pautan tidak sah".
18. Namakan kotak teks pertama sebagai "txtTotalLinks", dan yang kedua sebagai "txtNumberOfInvalidLinks".
19. Kemudian cari kawalan butang arahan pada kotak alat. Buat dua butang arahan, seperti di bawah:
20. Namakan butang pertama sebagai "cmdbtnClose", dan teks kapsyennya sebagai "Tutup".
21. Namakan butang kedua sebagai "btnCloseAndHighlightInvalidURLs", dan teks kapsyennya sebagai "Tutup & Serlahkan URL Tidak Sah".
22. Klik dua kali seterusnya pada butang "Tutup" dan butang "Tutup & Serlahkan URL Tidak Sah" masing-masing. Masukkan kod seperti berikut:

Jalankan Makro

Klik butang yang anda tetapkan kepada makro. Berikut adalah kesan akhir:

Anda boleh melihat maklumat terperinci tentang setiap pautan yang gagal pada kotak teks besar kiri. Dan anda boleh memilih untuk menutup borang pengguna secara terus atau menutupnya sambil menyerlahkan semua pautan yang rosak dalam dokumen.

Tangani Isu Perkataan Berhati-hati

Perkataan mudah terdedah kepada kesilapan. Oleh itu ia menjadi amat penting untuk betulkan Kata dengan betul. Kebanyakan masa, alat terbina dalam tidak dapat banyak membantu anda. Oleh itu, pilihan utama anda adalah untuk mendapatkan alat pembaikan pihak ketiga.

Pengenalan Pengarang:

Vera Chen adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk baiki xlsx dan pdf membaiki produk perisian. Untuk maklumat lebih lanjut, lawati www.datanumen.com