Bagaimana Batch Delete Semua Resit Baca di Outlook Anda

Untuk mengesahkan bahawa penerima telah membaca e-mel anda, anda boleh meminta resit baca semasa menulis e-mel. Dalam situasi ini, peti mel anda mungkin dipenuhi dengan resit baca sedemikian. Kini, siaran ini akan mengajar anda cara memadamkannya secara berkumpulan secara kekal.

Setelah membaca artikel “Bagaimana Batch Delete Semua Penerimaan Penghantaran di Outlook Anda", Anda mungkin memikirkan pendekatan untuk menghapus semua resit yang dibaca secara pukal. Sebenarnya, perbezaan yang nyata antara kedua-dua jenis penerimaan adalah pokoknya. Resit penghantaran mengandungi "Dikirimkan" dalam subjek tetapi resit baca mengandungi "Baca" sebagai gantinya. Oleh itu, anda boleh menggunakan cara yang sama untuk menghapus semua resit yang telah dibaca. Berikut ini, kami akan mengajar anda langkah-langkah konkrit secara terperinci.

Kumpulan Hapus Semua Resit Baca

1. Pada mulanya, mulakan Outlook anda.
2. Kemudian, pergi ke editor Outlook VBA melalui "Alt + F11" mengikut "Cara Menjalankan Kod VBA di Outlook Anda".
3. Seterusnya, di tetingkap baru, buka modul kosong dan masukkan kod berikut ke dalamnya.

Dim objOutlookFile As Outlook.Folder

Sub BatchDeleteAllReadReceipts()
    Dim objStore As Outlook.Store
    Dim objFolder As Outlook.Folder
    Dim lTotalCount As Long
 
    lTotalCount = 0
   'Process all Outlook files
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olMailItem Then
               Call ProcessFolders(objFolder, lTotalCount)
            End If
        Next
    Next
 
    'Prompt you of the results
    MsgBox lTotalCount & " read receipts are deleted!", vbInformation + vbOKOnly
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder, lCount As Long)
    Dim i As Long
    Dim objDeliveryReceipt As Outlook.ReportItem
    Dim objSubfolder As Outlook.Folder
    Dim objDeletedItems As Outlook.Items
    Dim objItem As Object
 
    For i = objCurrentFolder.Items.Count To 1 Step -1
        'Find read receipts
        If (TypeOf objCurrentFolder.Items(i) Is ReportItem) And (Left(objCurrentFolder.Items(i).Subject, 5) = "Read:") Then
           Set objDeliveryReceipt = objCurrentFolder.Items.Item(i)
           objDeliveryReceipt.Delete
 
           lCount = lCount + 1
 
           'Permanently delete them
           Set objDeletedItems = objOutlookFile.Folders("Deleted Items").Items
           For Each objItem In objDeletedItems
               If (TypeOf objItem Is ReportItem) And (Left(objItem.Subject, 5) = "Read:") Then
                  objItem.Delete
               End If
           Next
         End If
    Next
 
    'Loop subfolders recursively
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder, lCount)
       Next
    End If
End Sub

4. Selepas itu, klik subrutin pertama.
5. Akhirnya, tekan butang "F5".
6. Sekaligus, makro akan berfungsi untuk menghapus semua resit yang dibaca dari Outlook anda.
7. Apabila selesai, anda akan mendapat maklumat mengenai hasilnya, seperti tangkapan skrin di bawah.
8. Pada masa ini, anda boleh memeriksa folder mel anda. Semua resit yang dibaca telah hilang.

Pertahankan Data Outlook

Walaupun file Outlook diyakini rentan terhadap korupsi, kami dapat mengambil tindakan untuk melindunginya. Sebagai contoh, kita harus menyimpan fail Outlook dalam ukuran kecil, melindunginya dari faktor berbahaya dan menyandarkannya secara berkala. Akhir sekali, anda lebih baik menyediakan alat pembaikan PST luaran yang kuat, seperti DataNumen Outlook Repair. Ia akan memberi kesan yang besar terhadap pembaikan Outlook rosak fail.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk pembaikan sql dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com