Cara Auto Tetapkan Waktu Peringatan yang Berbeza untuk Mesyuarat Outlook dalam Kategori Warna yang berbeza

Sekiranya anda mengklasifikasikan mesyuarat Outlook mengikut kategori warna dan ingin menetapkan masa peringatan yang berbeza untuk mesyuarat dalam kategori warna yang berbeza, anda boleh merujuk artikel ini. Di sini kami akan mengajar anda untuk merealisasikannya dengan Outlook VBA.

Contohnya, anda membahagikan mesyuarat kepada dua kumpulan. Satu berada dalam kategori warna "Luar Tapak" kerana lokasi mesyuarat terlalu jauh, dan satu lagi berada dalam kategori warna "Di Tapak" kerana lokasinya berada di sini. Sekarang, anda mahu Outlook boleh menetapkan masa peringatan mesyuarat "luar tapak" secara automatik sebagai 1 jam sebelum permulaan dan mesyuarat "di tapak" sebagai 15 minit sebelum permulaan. Melihat keperluan ini, selepas ini, kami akan berkongsi kaedah pantas.

Auto Tetapkan Peringatan Berbeza untuk Mesyuarat dalam Kategori Warna yang berbeza

1. Sebagai permulaan, lancarkan aplikasi Outlook anda.
2. Kemudian, tekan butang kekunci "Alt + F11" untuk mengakses tetingkap editor VBA.
3. Seterusnya, di tetingkap berikutnya, salin dan tampal kod VBA di bawah ke dalam projek "ThisOutlookSession".

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

4. Kemudian, anda perlu klik pada subrutin "Application_Startup" dan tekan butang kekunci "F5" untuk menjalankan makro ini.
5. Sejak itu, setiap kali pertemuan baru ditambahkan ke kalendar lalai atau anda mengubah rapat yang ada, Outlook akan memeriksa secara automatik kategori rapat dan menetapkan waktu peringatan secara automatik.

Hilangkan Kesalahan Outlook

Pelbagai isu mungkin berlaku pada Outlook dari semasa ke semasa. Oleh itu, adalah sangat penting bagi pengguna untuk mempelajari cara menangani isu Outlook. Sebagai permulaan, lebih baik anda membuat sandaran data Outlook secara berkala. Selain itu, jika mampu milik, adalah dicadangkan untuk menyimpan sandaran data yang berkesan. Pembaikan Outlook alat berdekatan, seperti DataNumen Outlook Repair. Ia dapat mengimbas fail PST anda untuk mengetahui masalah Outlook dan kemudian menyelesaikannya dengan mudah.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk pemulihan sql dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com