2 Cara Mencetak Senarai Tugas Outlook dengan Kategori Berbeza di Halaman Berbeza

Sekiranya anda telah menetapkan pelbagai kategori warna untuk tugas Outlook anda dan sekarang ingin mencetak senarai tugas dengan kategori yang berlainan di halaman yang berlainan, anda boleh merujuk artikel ini. Di sini kami akan berkongsi kepada anda 2 kaedah untuk mendapatkannya.

Untuk mengelaskan dan menguruskan tugas anda dengan baik, mungkin anda telah menerapkan kategori warna untuk tugas anda. Sekarang, jika anda ingin mencetak senarai tugas anda dengan kategori yang berlainan di halaman yang berlainan, sila baca. Berikut ini, kami akan memperkenalkan 2 cara untuk mendapatkannya.

Kaedah 1: Mencetak Senarai Tugas secara manual satu demi satu

1. Pertama, di Outlook, akses panel "Tugas".
2. Kemudian, buka folder Task.
3. Seterusnya, tekan "Ctrl + E" untuk mengaktifkan reben "Cari".
4. Setelah itu, pada tab "Cari", klik butang "Kategorikan".
5. Dari senarai juntai bawah, pilih kategori warna.
6. Kemudian, hanya tugas dengan kategori yang terpilih akan tersisa dalam senarai.
7. Sekarang, pergi ke "File"> "Print" untuk mencetak senarai tugas ini.
8. Selepas itu, dengan cara yang sama, cetak senarai tugas dengan kategori warna yang lain satu demi satu secara manual.

Kaedah 2: Batch Print the Task List oleh VBA

1. Pada awalnya, cetuskan editor VBA sesuai dengan "Cara Menjalankan Kod VBA di Outlook Anda".
2. Kemudian, tambahkan rujukan kepada “MS Excel Object Library” seperti “Cara Menambah Rujukan Perpustakaan Objek dalam VBA".
3. Seterusnya, salin kod VBA berikut ke dalam modul.

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. Selepas itu, tekan butang "F5" untuk menjalankan makro ini dengan segera.
5. Apabila makro selesai, senarai tugas dengan kategori yang berlainan akan dicetak di halaman yang berlainan, seperti yang ditunjukkan dalam tangkapan skrin berikut.

Dapatkan Kembali Data Berharga dari Fail PST Berkompromi

Sekiranya anda terkena fail PST yang tidak dapat diakses, langkah anda seterusnya tidak diragukan lagi Pembaikan PST. Dalam kes ini, pertama sekali anda boleh mencuba alat pembaikan peti masuk. Dengan syarat ia gagal, anda boleh terus mencuba alat luaran lain, seperti DataNumen Outlook Repair. Ia dapat memulihkan data PST dalam masa yang cepat.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk pulih mdf dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com