2 Kaedah Mengira E-mel dengan Cepat oleh Pengirim di Outlook Anda

Sekiranya anda ingin menghitung e-mel oleh pengirim, anda boleh merujuk artikel ini. Di sini kami akan mendedahkan 2 pendekatan cepat untuk anda.

Untuk mengetahui pengirim yang paling aktif untuk anda, anda mungkin mahu mengira e-mel mengikut pengirim. Walaupun Outlook tidak menyediakan ciri langsung untuk ini, anda masih boleh mencari beberapa penyelesaian, seperti Kaedah 1 berikut. Jika anda fikir Kaedah 1 terlalu membosankan, anda boleh memilih Kaedah 2. Ia jauh lebih berkesan kerana ia menggunakan VBA untuk mengira e-mel mengikut pengirim dengan cepat dan mengeksport kiraan ke Excel. Sekarang baca terus dua cara secara terperinci. Di sini kita akan mengambil e-mel dalam Peti Masuk sebagai contoh.

Kaedah 1: Dapatkan Kiraan setelah Mengumpulkan Item mengikut Medan "Dari"

1. Sebagai permulaan, lancarkan aplikasi Outlook.
2. Kemudian, buka folder peti masuk.
3. Seterusnya, beralih ke tab "Lihat".
4. Selanjutnya, pilih "Dari" dalam kumpulan "Pengaturan".
5. Sekali gus, semua item peti masuk telah dipisahkan ke dalam kumpulan yang berbeza mengikut pengirim yang berbeza.
6. Sekarang, untuk mengira item dari pengirim tertentu, anda boleh memilih semua item dalam kumpulan yang berkaitan dan tekan kekunci "Enter". Dalam amaran pop timbul, anda dapat melihat jumlahnya.

Ini bermaksud cukup mudah, tetapi jumlah item sebenarnya merangkumi jenis item lain, seperti jemputan mesyuarat, permintaan tugas dan penerimaan, bukan hanya jumlah e-mel. Oleh itu, jika anda hanya mahu mengira e-mel, anda boleh menggunakan cara berikut sebagai gantinya.

Kaedah 2: Hitung E-mel oleh Pengirim dengan Outlook VBA

1. Untuk permulaan, tekan butang kekunci "Alt + F11" dalam Outlook.
2. Kemudian, dayakan “MS Excel Object Library” mengikut “Cara Menambah Rujukan Perpustakaan Objek dalam VBA".
3. Seterusnya, salin kod di bawah ke dalam modul yang tidak digunakan.

Sub CountInboxEmailsbySender()
    Dim objDictionary As Object
    Dim objInbox As Outlook.Folder
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim strSender As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varSenders As Variant
    Dim varItemCounts As Variant
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
 
    For i = objInbox.Items.Count To 1 Step -1
        If objInbox.Items(i).Class = olMail Then
           Set objMail = objInbox.Items(i)
           strSender = objMail.SenderEmailAddress
 
           If objDictionary.Exists(strSender) Then
              objDictionary.Item(strSender) = objDictionary.Item(strSender) + 1
           Else
              objDictionary.Add strSender, 1
           End If
        End If
    Next

    Set objExcelApp = CreateObject("Excel.Application")
    objExcelApp.Visible = True
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    With objExcelWorksheet
         .Cells(1, 1) = "Sender"
         .Cells(1, 2) = "Count"
    End With
 
    varSenders = objDictionary.Keys
    varItemCounts = objDictionary.Items
 
    For i = LBound(varSenders) To UBound(varSenders)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
        With objExcelWorksheet
             .Cells(nLastRow, 1) = varSenders(i)
             .Cells(nLastRow, 2) = varItemCounts(i)
        End With
    Next
 
    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

3. Selepas itu, tekan butang “F5”.
4. Apabila makro selesai, fail Excel baru akan dipaparkan.
5. Seperti yang anda lihat, ia mengandungi jumlah e-mel masuk dari pengirim yang berbeza.

Buang Masalah Mengecewakan Outlook

Mungkin anda pernah menghadapi banyak masalah dalam Outlook anda. Untuk mengatasinya dengan berkesan, anda mungkin memerlukan cara yang serba boleh dan hebat. Namun, sebenarnya, tidak ada kaedah seperti itu. Apa yang boleh anda lakukan adalah berhati-hati dengan operasi anda sendiri di Outlook dan membuat sandaran biasa. Sudah tentu, jika boleh, kami mencadangkan agar anda lebih baik menyimpan alat pembaikan yang berpengalaman, seperti DataNumen Outlook Repair. Ia dapat menyelesaikan pelbagai masalah dan pembaikan PST PST yang rosak fail seperti angin.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk pulih Sql Server dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com