2 Cara Cepat untuk Mengekstrak Bahagian dari Dokumen Word Anda

Dalam artikel ini, kami akan menawarkan kepada anda 2 cara cepat dan mudah untuk mengekstrak bahagian dari dokumen Word anda ke satu atau beberapa yang lain.

Ia sering berlaku untuk mengekstrak kandungan dari satu dokumen ke dokumen yang lain. Dan dalam artikel sebelumnya, kami telah membincangkan cara mengekstrak halaman dari dokumen. Untuk maklumat terperinci, anda boleh merujuk artikel ini: 2 Cara Pantas untuk Mengekstrak Halaman Individu dari Dokumen Word Anda

Hari ini, kami akan menunjukkan cara mengekstrak mengikut bahagian.    

Kaedah 1: Ekstrak Bahagian Semasa ke Dokumen Baru

1. Pertama sekali, letakkan kursor di bahagian sasaran.
2. Seterusnya tekan "Alt + F11" untuk memanggil editor VBA di Word.
3. Kemudian di lajur kiri, klik "Normal".
4. Dan pada bar menu, klik "Masukkan".
5. Kemudian pilih "Module" pada menu drop-down itu.
6. Klik dua kali untuk membuka modul baru dan tampal kod berikut di sana:

Sub SaveCurrentSectionAsNewDoc()
  Dim strFolder As String
  Dim dlgFile As FileDialog
  Dim strNewFileName As String
  Dim objDocAdded As Document
  Dim objDoc As Document
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  ' Pick a place to store the new file.
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  strNewFileName = InputBox("Enter new file name here: ", "File Name")
 
  ' Select and copy current section range.
  objDoc.Bookmarks("\Section").Range.Select
  Selection.Copy
 
  ' Open a new document to paste the above selection.
  Set objDocAdded = Documents.Add
  Selection.Paste
 
  ' Save and close the new document.
  objDocAdded.SaveAs FileName:=strFolder & strNewFileName & ".docx"
  objDocAdded.Close
End Sub

7. Seterusnya, klik "Jalankan" pada bar menu atau tekan "F5".
8. Kemudian akan muncul tetingkap "Browse". Pilih tempat untuk menyimpan dokumen baru dan klik "OK".
9. Dan di kotak "Nama Fail", masukkan nama untuk fail baru dan klik "OK".

Sekarang anda telah mengekstrak bahagian tersebut ke dokumen baru.

Kaedah 2: Ekstrak Setiap Bahagian dalam Dokumen kepada Individu Baru

Dengan cara ini dapat membantu anda memproses semua bahagian dalam satu kumpulan. Sudah tentu, kita juga memerlukan makro.

1. Untuk bermula, buka dokumen sasaran.
2. Kemudian ikuti langkah dalam kaedah 1 untuk memasang dan menjalankan makro.
3. Hanya kali ini ganti makro dengan yang ini:

Sub SaveEachSectionAsADoc()
  Dim objDocAdded As Document
  Dim objDoc As Document
  Dim nSectionNum As Integer
  Dim strFolder As String

  Dim dlgFile As FileDialog
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  ' Pick a location to keep new files.
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  ' Step through each section in current document, copy and paste each to a new one.
  For nSectionNum = 1 To ActiveDocument.Sections.Count
    Selection.GoTo What:=wdGoToSection, Which:=wdGoToNext, Name:=nSectionNum
    ActiveDocument.Sections(nSectionNum).Range.Copy
 
    Set objDocAdded = Documents.Add
    Selection.Paste
 
    ' Save and close new documents.
    objDocAdded.SaveAs FileName:=strFolder & "Section " & nSectionNum & ".docx"
    objDocAdded.Close
  Next nSectionNum
End Sub

4. Namun, di tetingkap "Browse", pilih jalan penyimpanan dan klik "OK".

Betulkan Kesalahan Kata-kata yang Mengiritasi

Adalah biasa untuk menemui beberapa kesalahan Word semasa menggunakannya. Menjengkelkan mungkin, kita mesti meluangkan masa untuk memulihkan perkataan secepat mungkin. Kerana semakin lama kita menangguhkannya, semakin teruk kehilangan data. Oleh itu, disarankan untuk menggunakan utiliti pembaikan terlebih dahulu.

Pengenalan Pengarang:

Vera Chen adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk xls rosak dan pdf membaiki produk perisian. Untuk maklumat lebih lanjut, lawati www.datanumen.com