Cara Cepat Melampirkan Halaman Khusus Dokumen Word ke E-mel Outlook

MS Word mempunyai ciri langsung yang menyokong pengguna untuk menghantar dokumen Word semasa sebagai lampiran e-mel. Tetapi kadang-kadang, anda hanya berharap dapat melampirkan halaman tertentu dari dokumen Word ke e-mel Outlook. Sekarang, artikel ini akan berkongsi kaedah kepada anda.

Untuk mengirim keseluruhan dokumen Word sebagai lampiran e-mel dalam aplikasi MS Word, Anda cukup pergi ke menu "File" dan beralih ke tab "Simpan & Kirim", di mana Anda dapat menemukan butang "Kirim sebagai Lampiran". Namun, kadang-kadang, yang anda ingin hantar mungkin hanya halaman tertentu dari dokumen. Dalam keadaan ini, anda boleh menggunakan kaedah yang diperkenalkan dalam langkah berikut untuk mencapainya.

Lampirkan Halaman Khusus Dokumen Word ke E-mel

1. Mula-mula, anda harus membuka dokumen Word sumber yang halaman tertentu anda ingin hantarkan melalui e-mel.
2. Kemudian, setelah masuk ke tetingkap MS Word, anda perlu menekan butang "Alt + F11".
3. Seterusnya, anda akan mendapat akses ke editor VBA di MS Word.
4. Selepas itu, anda harus mengaktifkan "Microsoft Outlook Object Library ”. Anda boleh menekan "Alat"> "Rujukan" untuk mencapainya.
5. Selepas itu, anda harus menyalin kod VBA berikut ke dalam modul yang tidak digunakan.

Sub AttachSpecificPagesToOutlookEmail()
    Dim strDocumentName As String
    Dim objSelectedPages As Word.Range
    Dim objTempDocument As Word.Document
    Dim objTempRange As Word.Range
    Dim i As Long
    Dim strTempDocument As String
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    strDocumentName = Left(ActiveDocument.Name, InStr(ActiveDocument.Name, ".") - 1)
 
    'Copy the contents from Page 2 to 4
    'You can change the page as per your own needs
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=2
    Set objSelectedPages = Selection.Range
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=4
    objSelectedPages.End = Selection.Bookmarks("\Page").Range.End
    objSelectedPages.Select
    objSelectedPages.Copy
 
    'Paste the copied contents into a new Word Document
    Set objTempDocument = Word.Application.Documents.Add
    objTempDocument.Activate
    Set objTempRange = objTempDocument.Range(0, 0)
    objTempRange.PasteAndFormat (wdFormatOriginalFormatting)

    For i = objTempDocument.Paragraphs.Count To 1 Step -1
        If Len(objTempDocument.Paragraphs(i).Range) = 1 Then
           objTempDocument.Paragraphs(i).Range.Delete
        Else
           Exit For
        End If
    Next i
 
    'Save this document
    strTempDocument = "E:\" & strDocumentName & " (Excerpt).doc"
    objTempDocument.SaveAs2 strTempDocument, wdFormatDocument
 
    'Attach the new document to a new Outlook email
    On Error Resume Next
    Set objOutlookApp = GetObject(, "Outlook.Application")
    If objOutlookApp Is Nothing Then
       Set objOutlookApp = CreateObject("Outlook.Application")
    End If
 
    Set objMail = objOutlookApp.CreateItem(olMailItem)
    objMail.Attachments.Add (strTempDocument)
    objMail.Display
 
    objTempDocument.Close False
    Kill strTempDocument
End Sub

6. Akhirnya, anda boleh menjalankan makro ini. Cukup tekan butang kekunci F5 atau ketuk ikon "Jalankan" di bar alat.
7. Setelah makro selesai, e-mel Outlook baru akan dipaparkan, yang disertakan dengan petikan dokumen sumber Word, seperti tangkapan skrin berikut:

Ekstrak Data Maksimum dari Fail Outlook yang rosak

Sekiranya anda telah menggunakan Outlook selama beberapa dekad, anda mungkin berhadapan dengan pelbagai masalah Outlook, termasuk mesej ralat dalaman yang timbul, kerosakan tiba-tiba dan juga kerosakan fail yang serius. Kerana kenyataan bahawa scanpst, alat pembaikan bawaan, hanya dapat mengatasi masalah kecil, lebih baik anda menyimpan alat pembaikan luaran yang berguna, katakan DataNumen Outlook Repair. Ia dapat memperoleh data maksimum dari fail data Outlook yang rosak.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk memperbaiki sql dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com