Cara Auto Merakam Jumlah Jumlah E-mel Masuk Setiap Hari dalam Fail Excel

Artikel ini akan mengajar anda bagaimana membiarkan Outlook menghitung secara automatik berapa banyak e-mel yang anda terima setiap hari dan menuliskan nombor tersebut ke dalam fail Excel.

Ramai pengguna diminta untuk mengira jumlah e-mel yang diterima setiap hari. Selain itu, untuk pemeriksaan yang lebih mudah di masa depan, banyak yang terbiasa merekodkan jumlah keseluruhan ke dalam file Excel. Dalam kes ini, sudah tentu anda boleh memilih untuk mengira dan mencatat secara manual setiap hari. Namun, agak menyusahkan. Dan anda mungkin lupa melakukannya kadang-kadang. Oleh itu, anda mesti menginginkan kaedah yang berguna, yang dapat menjadikan Outlook untuk melakukannya secara automatik. Sebagai tindak balas kepada keperluan ini, kami akan mengajar anda cara menggunakan VBA untuk merealisasikannya sebagai berikut.

Auto Catat Jumlah Jumlah E-mel Masuk Setiap Hari dalam Fail Excel

1. Pada awalnya, lancarkan aplikasi Outlook anda.
2. Kemudian tekan pintasan kekunci "Alt + F11" di tetingkap utama Outlook.
3. Selanjutnya di tetingkap editor VBA pop timbul, buka projek "ThisOutlookSession".
4. Selepas itu, salin dan tampal kod VBA berikut ke dalam projek ini.

Private Sub Application_Reminder(ByVal Item As Object)
    If Item.Class = olTask And Item.Subject = "Update Email Count" Then
       Call GetAllInboxFolders
    End If
End Sub

Private Sub GetAllInboxFolders()
    Dim objInboxFolder As Outlook.Folder
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim lEmailCount As Long
 
    lEmailCount = 0
    Set objInboxFolder = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Call UpdateEmailCount(objInboxFolder, lEmailCount)
 
    ‘Change the path to the Excel file
    strExcelFile = "E:\Email\Email Count.xlsx"
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorksheet.Range("B" & nNextEmptyRow) = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
    objExcelWorksheet.Range("C" & nNextEmptyRow) = lEmailCount
 
    'Fit the columns from A to C
    objExcelWorksheet.Columns("A:C").AutoFit
   
    'Save the changes and close the Excel file
    objExcelWorkbook.Close SaveChanges:=True
End Sub

Private Sub UpdateEmailCount(objFolder As Outlook.Folder, ByRef lCurEmailCount As Long)
    Dim objItems As Outlook.Items
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim strDay As String
    Dim strReceivedDate As String
    Dim lEmailCount As Long
    Dim objSubFolder As Outlook.Folder
 
    Set objItems = objFolder.Items
 
    objItems.SetColumns ("ReceivedTime")
    strDay = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
 
    For Each objItem In objItems
        If objItem.Class = olMail Then
           Set objMail = objItem
           strReceivedDate = Year(objMail.ReceivedTime) & "-" & Month(objMail.ReceivedTime) & "-" & Day(objMail.ReceivedTime)
           If strReceivedDate = strDay Then
              lCurEmailCount = lCurEmailCount + 1
           End If
        End If
    Next
 
    'Process the subfolders in the folder recursively
    If (objFolder.Folders.Count > 0) Then
       For Each objSubFolder In objFolder.Folders
           Call UpdateEmailCount(objSubFolder, lCurEmailCount)
       Next
    End If
End Sub

5. Seterusnya, tandatangani kod ini dan ubah tetapan makro Outlook anda untuk membenarkan makro yang ditandatangani.
6. Selepas itu, anda perlu membuat tugas berulang setiap hari.

• Pertama, klik butang "Task Baru" di panel Tasks.
• Di tetingkap Tugas Baru pop timbul, klik butang "Kambuhan".
• Kemudian pada kotak dialog berikutnya, pilih "Harian", "Setiap 1 hari" dan "Tanpa tarikh akhir" dan terakhir tekan "OK".
• Kemudian ubah subjek tugas dan peringatan mengikut keperluan anda.
• Akhirnya klik butang "Simpan & Tutup".

7. Mulai sekarang, setiap kali peringatan tugas ini memberi amaran, Outlook akan mengira secara automatik e-mel yang diterima semalam dan kemudian mencatat nombor tersebut ke dalam fail Excel, seperti tangkapan skrin berikut:

Melarikan diri dari Kehilangan Data PST Kekal

Tidak ada yang bersedia menerima kehilangan data PST kekal. Walau bagaimanapun, fail Outlook PST terdedah kepada kerosakan. Oleh itu, anda harus membuat langkah berjaga-jaga yang mencukupi, seperti membuat sandaran data PST yang konsisten dan terkini dan menyimpan yang kuat Pemulihan PST alat di sekitar, seperti DataNumen Outlook Repair.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk pembaikan sql dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com