Давхардсан Outlook зүйлийг VBA-ээр дамжуулан фолдерт хэрхэн хурдан устгах вэ?

Хэрэв та Outlook дээрх давхардсан зүйлсийг устгахыг хүсвэл нэг нэгээр нь хайж, устгах нь нэлээд төвөгтэй байх болно. Энэ бичлэг нь танд Outlook VBA ашиглан үүнийг хэрхэн хурдан дуусгахыг заах болно.

Миний өмнөх нийтлэлд “Outlook дээр давхардсан имэйлийг хэрхэн хурдан олж устгах вэ”, давхардсан имэйлийг хайж олох, устгах аргад суралцаж, имэйлийг эхлээд сэдвээр нь, дараа нь хүлээн авсан цаг, дараа нь хавсралтаар нь ангилж, давхардсан зүйлсийг олж, хамгийн сүүлд давхардсан имэйлийг сонгоод "Устгах" товчийг дарна уу. Хэдийгээр энэ арга нь арай илүү тохиромжтой мэт боловч Outlook VBA-г ашиглахтай харьцуулахад хамаагүй илүү төвөгтэй юм. Дараах VBA кодуудын тусламжтайгаар та имэйл, ажил, холбоо барих хаяг, уулзалтаас үл хамааран нэг товшилтоор давхардсан зүйлсийг хурдан арилгах боломжтой. Одоо кодыг нарийвчлан авахын тулд уншина уу.

Фолдер дахь Outlook-ийн давхардсан зүйлсийг устгана уу

1. Эхлэхийн тулд Outlook програмаа ажиллуулна уу.
2. Дараа нь “Alt + F11” товчлууруудыг дарна уу.
3. VBA засварлагчийн дараагийн цонхонд давхар товшиж ашиглагдаж байгаа модулийг нээх эсвэл "Insert" > "Module" гэснээр шинэ модулийг шууд оруулна.
4. Дараа нь модульд дараах VBA кодуудыг хуулж буулгана уу.

Sub RemoveDuplicateItems()
    Dim objFolder As Folder
    Dim objDictionary As Object
    Dim i As Long
    Dim objItem As Object
    Dim strKey As String

    Set objDictionary = CreateObject("scripting.dictionary")
    'Select a source folder
    Set objFolder = Outlook.Application.Session.PickFolder

    If Not (objFolder Is Nothing) Then
       For i = objFolder.Items.Count To 1 Step -1
           Set objItem = objFolder.Items.Item(i)
 
           Select Case objFolder.DefaultItemType
                  'Check email subject, body and sent time
                  Case olMailItem
                       strKey = objItem.Subject & "," & objItem.Body & "," & objItem.SentOn
                  'Check appointment subject, start time, duration, location and body
                  Case olAppointmentItem
                       strKey = objItem.Subject & "," & objItem.Start & "," & objItem.Duration & "," & objItem.Location & "," & objItem.Body
                  'Check contact full name and email address
                  Case olContactItem
                       strKey = objItem.FullName & "," & objItem.Email1Address & "," & objItem.Email2Address & "," & objItem.Email3Address
                  'Check task subject, start date, due date and body
                  Case olTaskItem
                       strKey = objItem.Subject & "," & objItem.StartDate & "," & objItem.DueDate & "," & objItem.Body
           End Select
 
           strKey = Replace(strKey, ", ", Chr(32))
 
           'Remove the duplicate items
           If objDictionary.Exists(strKey) = True Then
              objItem.Delete
           Else
              objDictionary.Add strKey, True
           End If
       Next i
    End If
End Sub

5. Үүний дараа энэ макрог дижитал гарын үсэг зурж, Outlook-ын макро аюулгүй байдлын түвшинг бага болгож өөрчил.
6. Дараа нь та энэ шинэ VBA төслийг ажиллуулж болно. Хэрэгслийн самбар дээрх "Ажиллуулах" дүрс дээр шууд дарна уу.
7. Дараа нь та давхардсан зүйлсийг устгахыг хүссэн хавтасаа сонгох шаардлагатай болно.
8. Эцэст нь сонгосон хавтас дахь давхардсан зүйлсийг нэг дор устгах болно.

Эмзэг PST өгөгдлийг хамгаалах

PST файл нь авлигад өртөмтгий байдаг тул та PST файлаа хамгаалахын тулд маш их хүчин чармайлт гаргах хэрэгтэй. Жишээлбэл, та Outlook-ийг буруу хаахаас урьдчилан сэргийлэх хэрэгтэй. Цаашилбал, та бат бөх бэлтгэх хэрэгтэй Outlook засах гэх мэт хэрэгсэл DataNumen Outlook Repair Энэ нь таны PST-г цаг тухайд нь аврах боломжтой болно.

Зохиогчийн танилцуулга:

Ширли Жан бол мэдээлэл сэргээх мэргэжилтэн юм DataNumen, Үүнд мэдээлэл сэргээх технологиор дэлхийд тэргүүлэгч, Inc. сэргээх SQL Server програм хангамжийн бүтээгдэхүүнийг засах хэтийн төлөв. Дэлгэрэнгүй мэдээллийг авна уу WWW.datanumen.com