Outlook хавтас бүрийн нийт тоог Excel рүү хэрхэн хурдан экспортлох вэ

Хэрэв та Outlook хавтас бүр дэх зүйлсийн тооны талаар тайлан авахыг хүсвэл энэ нийтлэлд танилцуулсан аргыг ашиглаж болно. Энэ нь хурдан тооцоолж, үр дүнг Excel файл руу экспортлох болно.

Миний өмнөх нийтлэлд “Outlook VBA-ээр дамжуулан хавтас доторх нийт зүйлийн тоо болон бүх дэд хавтасыг хэрхэн хурдан авах вэ", та VBA ашиглан хавтас дахь зүйлийн тоог авах аргыг сурч болно. Гэсэн хэдий ч, хэрэв та бүх хавтсанд байгаа зүйлсийг тоолохыг хүсвэл хавтас бүрийг сонгоод макро нэг нэгээр нь ажиллуулах хэрэгтэй. Энэ нь жаахан уйтгартай юм. Тиймээс бид танд тооцооллыг Excel файл руу экспортлох өөр аргыг зааж өгөх болно.

Outlook хавтас бүрийн нийт тоог Excel рүү экспортлох

1. Эхлээд Outlook програмаа эхлүүлнэ үү.
2. Дараа нь Outlook-ийн үндсэн цонхонд "Alt + F11" товчлууруудыг дар.
3. Дараа нь та хэрэглээнд ашиглагдаагүй модулийг нээх хэрэгтэй "Microsoft Visual Basic for Applications" цонхонд орох болно.
4. Дараа нь дараахь VBA кодыг хуулж аваад энэ модуль дээр буулгана уу.

Public strExcelFile As String
Public objExcelApp As Excel.Application
Public objExcelWorkbook As Excel.Workbook
Public objExcelWorksheet As Excel.Worksheet

Sub Export_CountOfItems_InEachFolder_toExcel()
    Dim objSourcePST As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Create a new Excel file
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Folder"
    objExcelWorksheet.Cells(1, 2) = "Count Items"
 
    'Select a source PST file
    Set objSourcePST = Outlook.Application.Session.PickFolder

    For Each objFolder In objSourcePST.folders
        Call ProcessFolders(objFolder)
    Next
 
    'Fit the columns from A to B
    objExcelWorksheet.Columns("A:B").AutoFit
 
    strExcelFile = "E:\Outlook\" & objSourcePST.Name & " Folder Items Count (" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim lCurrentFolderItemCount As Long
    Dim nLastRow As Integer
 
    lCurrentFolderItemCount = objCurrentFolder.Items.Count
 
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1

    'Add the values into the columns
    objExcelWorksheet.Range("A" & nLastRow) = objCurrentFolder.FolderPath
    objExcelWorksheet.Range("B" & nLastRow) = lCurrentFolderItemCount
 
    If objCurrentFolder.folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

5. Үүний дараа та Outlook макро аюулгүй байдлын түвшинг доод түвшинд өөрчлөх хэрэгтэй.
6. Дараа нь та шинээр нэмэгдсэн макро руу буцаж очоод F5 товчийг дарж энэ макро ажиллуулна.
7. Дараа нь та эх сурвалж PST файлыг сонгоод "OK" дээр дарах хэрэгтэй.
8. Макро ажиллаж дууссаны дараа та урьдчилан тодорхойлсон локал хавтас руу орж шинэ Excel файлыг хайж олох боломжтой бөгөөд энэ нь дараах дэлгэцийн зураг шиг харагдах болно.

Ядаргаатай PST алдаануудыг шийдвэрлэх

Магадгүй та Outlook ашиглах явцад янз бүрийн асуудалтай тулгарсан байх. Жижиг асуудлуудыг шийдвэрлэхийн тулд та зүгээр л хандана уу ирсэн хайрцаг засах хэрэгсэл. Гэсэн хэдий ч хэрэв асуудал нь суурилуулсан багажийн хийж чадахаас давсан ноцтой байвал та илүү хүчирхэг хэрэгсэл ашиглах хэрэгтэй. DataNumen Outlook Repair.

Зохиогчийн танилцуулга:

Ширли Жан бол мэдээлэл сэргээх мэргэжилтэн юм DataNumen, Үүнд мэдээлэл сэргээх технологиор дэлхийд тэргүүлэгч, Inc. mdf засвар програм хангамжийн бүтээгдэхүүнийг засах хэтийн төлөв. Дэлгэрэнгүй мэдээллийг авна уу WWW.datanumen.com