Outlook фолдерыг бүх дэд хавтас, эд зүйлээр Windows хавтсанд хэрхэн хурдан экспортлох вэ

Заримдаа та Outlook фолдерыг бүх дэд хавтас, зүйлсийн хамт Windows хавтсанд экспортлохыг хүсч магадгүй юм. Энэ нийтлэл нь Outlook VBA-г ашиглаж буй ийм аргыг танд заах болно.

Хэрэв та Outlook фолдерыг локал драйвт нэг фолдерын бүтцэд байгаа бүх зүйлтэй экспортлохыг хүсвэл гараар хадгалах, экспортлохыг сонговол танд маш их цаг хугацаа шаардагдана. Тиймээс та яагаад бусад хэрэгслийг ашигладаггүй вэ, тухайлбал экспортын хэрэгсэл эсвэл VBA код гэх мэт. VBA кодын ийм хэсгийг танд танилцуулах болно. Энэ нь танд сэвшээ салхи шиг хүрэх боломжийг олгоно.

Outlook фолдерт байгаа бүх дэд хавтас, зүйлийг Windows хавтас руу экспортлох

1. Хамгийн эхэнд Outlook програмаа эхлүүлээрэй.
2. Дараа нь Outlook-ийн үндсэн цонхонд "Alt + F11" товчлолыг дарна уу.
3. Дараа нь “Програмд ​​зориулсан Microsoft Visual Basic” цонх гарч ирнэ.
4. Дараа нь та хоосон модулийг нээгээд дараах VBA кодуудыг хуулах хэрэгтэй.

Private objFileSystem As Object
 
Private Sub ExportFolderWithAllItems()
    Dim objFolder As Outlook.Folder
    Dim strPath As String
 
    'Specify the root local folder
    'Change it as per your needs
    strPath = "E:\Outlook\"
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    'Select a Outlook PST file or Outlook folder
    Set objFolder = Outlook.Application.Session.PickFolder
 
    Call ProcessFolders(objFolder, strPath)
 
    MsgBox "Complete", vbExclamation
End Sub
 
Private Sub ProcessFolders(objCurrentFolder As Outlook.Folder, strCurrentPath As String)
    Dim objItem As Object
    Dim strSubject, strFileName, strFilePath As String
    Dim objSubfolder As Outlook.Folder
 
    'Create the local folder based on the Outlook folder
    strCurrentPath = strCurrentPath & objCurrentFolder.Name
    objFileSystem.CreateFolder strCurrentPath
 
    For Each objItem In objCurrentFolder.Items
 
        strSubject = objItem.Subject
 
        'Remove unsupported characters in the subject
        strSubject = Replace(strSubject, "/", " ")
        strSubject = Replace(strSubject, "\", " ")
        strSubject = Replace(strSubject, ":", "")
        strSubject = Replace(strSubject, "?", " ")
        strSubject = Replace(strSubject, Chr(34), " ")

        strFileName = strSubject & ".msg"
 
        i = 0
        Do Until False
           strFilePath = strCurrentPath & "\" & strFileName
           'Check if there exist a file in the same name
           If objFileSystem.FileExists(strFilePath) Then
              'Add a sequence order to the file name
              i = i + 1
              strFileName = strSubject & " (" & i & ").msg"
           Else
              Exit Do
          End If
        Loop
 
        'Save as MSG file
        objItem.SaveAs strFilePath, olMSG
    Next
 
    'Process subfolders recursively
    If objCurrentFolder.folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.folders
           Call ProcessFolders(objSubfolder, strCurrentPath & "\")
       Next
    End If
End Sub

5. Үүний дараа та Outlook нь макро тохиргоонд макро оруулахыг баталгаажуулах хэрэгтэй.
6. Эцэст нь та хичээгээд үзээрэй.

• Нэгдүгээрт, шинэ макро цонх руу буцах.
• Дараа нь "ExportFolderWithAllItems" дэд програм дээр дарна уу.
• Дараа нь F5 товчлуур дээр дарж энэ макро ажиллуулна уу.
• Үүний дараа та тодорхой хавтас сонгох хэрэгтэй.
• Эцэст нь “Бүрэн гүйцэд” гэсэн мессеж ирэхэд та урьдчилан тодорхойлсон локал фолдерт хандах боломжтой. Бүх зүйлийг ижил хавтас бүтцэд хадгалсныг та олох болно.

Outlook-ийн сүйрлээс өгөгдөл алдахаас урьдчилан сэргийлэх

Магадгүй та Outlook-ийн олон удаа гацах тохиолдолтой тулгарч байсан байх. Ихэнх тохиолдолд дахин ачаалсны дараа Outlook хэвийн ажиллах боломжтой болно. Гэсэн хэдий ч манай PST файл эвдэрч болзошгүй тохиолдол бас байдаг. Тэр үед та PST өгөгдлөө сэргээхийг хичээх болно, жишээлбэл, туршлагатай хэрэгсэл рүү дахин чиглүүлэх гэх мэт. DataNumen Outlook Repair. Энэ нь боломжтой Outlook засах алдаа, алдагдсан PST файлын өгөгдлийг хөлсөө гаргахгүйгээр гаргаж авах.

Зохиогчийн танилцуулга:

Ширли Жан бол мэдээлэл сэргээх мэргэжилтэн юм DataNumen, Үүнд мэдээлэл сэргээх технологиор дэлхийд тэргүүлэгч, Inc. SQL Server засвар програм хангамжийн бүтээгдэхүүнийг засах хэтийн төлөв. Дэлгэрэнгүй мэдээллийг авна уу WWW.datanumen.com