Outlook холбоо барих бүлгийн бүх гишүүдийн дэлгэрэнгүй мэдээллийг Excel рүү хэрхэн хурдан экспортлох вэ

Outlook шийдлүүд Есдүгээр сарын 29, 2025

Анхдагч байдлаар, та зөвхөн холбоо барих бүлгийн гишүүдийн нэр, имэйл хаягийг харах боломжтой. Хэрэв та гишүүдийн бусад дэлгэрэнгүй мэдээллийг авахыг хүсвэл энэ нийтлэлд танилцуулсан аргыг ашиглаж болно.

Холбоо барих бүлгийг нээхийн тулд давхар товших үед түүний цонхонд зөвхөн бүлгийн гишүүдийн нэр, имэйл хаягийг харах боломжтой. Та гишүүдийн компани, албан тушаал, утасны дугаар, бизнесийн хаяг гэх мэт бусад мэдээллийг авах боломжгүй. Ерөнхийдөө эдгээр мэдээллийг авахын тулд та өөрийн Холбоо барих хавтас дотроос гишүүдтэй харгалзах харилцагчдыг гараар олох хэрэгтэй. Энэ нь хэтэрхий төвөгтэй юм. Энд бид эдгээр мэдээллийг Excel-ийн ажлын дэвтэрт хурдан экспортлох боломжтой VBA кодын хэсгийг үзүүлэх болно.

Холбоо барих бүлгийн бүх гишүүдийн мэдээллийг Excel рүү экспортлох

Эхлэхийн тулд Outlook програмаа ажиллуулна уу.
Дараа нь та Outlook-ийн үндсэн цонхон дээрх "Alt + F11" товчлолыг дарах хэрэгтэй.
Дараа нь шинэ "Microsoft Visual Basic for Applications" цонхонд ашиглагдаагүй модулийг нээх эсвэл шинэ модулийг шууд оруулах шаардлагатай.
Дараа нь дараахь VBA кодыг хуулж аваад энэ модуль дээр буулгана уу.

Sub ExportMemberContactDetailsToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objGroupMember As Outlook.recipient
    Dim objContacts As Outlook.Items
    Dim objFoundContact As Outlook.ContactItem
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strFilename As String
 
    Set objContactGroup = Application.ActiveExplorer.Selection(1)
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkBook = objExcelApp.Workbooks.Add
    Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
    'Set the seven column headers
    With objExcelWorkSheet
         .Cells(1, 1) = "Name"
         .Cells(1, 2) = "Email Address"
         .Cells(1, 3) = "Company"
         .Cells(1, 4) = "Job Title"
         .Cells(1, 5) = "Phone Number"
         .Cells(1, 6) = "Mailing Address"
         .Cells(1, 7) = "Birthday"
    End With
 
    Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items.Restrict("[Email1Address]>''")
 
    nRow = 2
    For i = 1 To objContactGroup.MemberCount
        Set objGroupMember = objContactGroup.GetMember(i)
 
        strFilter = "[Email1Address] = '" & objGroupMember.Address & "'"
        Set objFoundContact = objContacts.Find(strFilter)
 
        If Not (objFoundContact Is Nothing) Then
           'Input the Contact Details
           With objExcelWorkSheet
                .Cells(nRow, 1) = objFoundContact.FullName
                .Cells(nRow, 2) = objFoundContact.Email1Address
                .Cells(nRow, 3) = objFoundContact.CompanyName
                .Cells(nRow, 4) = objFoundContact.JobTitle
                .Cells(nRow, 5) = objFoundContact.BusinessTelephoneNumber
                .Cells(nRow, 6) = objFoundContact.MailingAddress
             If objFoundContact.Birthday = #1/1/4501# Then
                .Cells(nRow, 7) = ""
             Else
                .Cells(nRow, 7) = objFoundContact.Birthday
             End If
           End With
       Else
           With objExcelWorkSheet
               .Cells(nRow, 1) = objGroupMember.Name
               .Cells(nRow, 2) = objGroupMember.Address
           End With
       End If
       nRow = nRow + 1
    Next
 
    'Fit the columns
    objExcelWorkSheet.Columns("A:G").AutoFit
 
    'Change the Path as per where you want to save the new Excel file
    strFilename = "E:\" & objContactGroup.DLName & " Member Contact Details.xlsx"
    'Save the Excel workbook
    objExcelWorkBook.Close True, strFilename
 
    MsgBox ("Complete!")
End Sub

Үүний дараа шалгахад хялбар болгохын тулд та шинэ VBA төслийг Quick Access Toolbar эсвэл туузанд нэмж болно.
Дараа нь Outlook-ын макро аюулгүй байдлын түвшинг доод түвшинд тохируулна уу.
Эцсийн эцэст та оролдоод үзэх боломжтой.

Эхлээд холбоо барих бүлгийг сонгоно уу.
Дараа нь Quick Access Toolbar буюу туузан дээрх макро товчийг дарна уу.
Нэн даруй макро ажиллах болно.
Дуусмагц та "Бүрэн гүйцээ!" гэсэн сануулга авах болно.
Үүний дараа та урьдчилан тодорхойлсон локал хавтас руу очиж, шинэ Excel файлыг олох боломжтой.
Үүнийг нээвэл та дараах дэлгэцийн зураг шиг бүлгийн гишүүдийн холбоо барих мэдээллийг харах болно.

Outlook-тэй холбоотой асуудлуудын өмнө бүү сандар

Хэн ч гарч ирэх алдааны мессежээс үл хамааран Outlook-ийн асуудлыг хүлээн зөвшөөрөхгүй авлигад автсан Outlook өгөгдлийн файл. Тиймээс хэрэглэгчид Outlook-ийн асуудалтай тулгарах үед сандрах хандлагатай байдаг. Хэрэв та энэ тохиолдолд тайван байхыг хүсч байвал танд хоёр хэрэгцээтэй зүйл байх ёстой. Нэг нь одоогийн Outlook мэдээллийн нөөцлөлт юм. Нөгөө нэг нь Outlook засах хүчирхэг програм хангамж юм DataNumen Outlook Repair.

Зохиогчийн танилцуулга:

Ширли Жан бол мэдээлэл сэргээх мэргэжилтэн юм DataNumen, Үүнд мэдээлэл сэргээх технологиор дэлхийд тэргүүлэгч, Inc. sql сэргээх програм хангамжийн бүтээгдэхүүнийг засах хэтийн төлөв. Дэлгэрэнгүй мэдээллийг авна уу WWW.datanumen.com