Тодорхой слайдыг хэрхэн хурдан хавсаргах вэ a PowerPoint Таны Outlook имэйлд үзүүлэх танилцуулга

Хэрэв та тодорхой слайдуудыг задлахыг хүсвэл a PowerPoint Та танилцуулгыг тусдаа шинэ үзүүлэн рүү илгээж, Outlook имэйлд хавсаргавал та энэ нийтлэлд хуваалцсан аргыг ашиглаж болно.

Бүхэл бүтэн хавсаргахын оронд PowerPoint Хэрэв та үзүүлэнгийн тодорхой слайдуудыг хавсаргахыг хүсвэл ерөнхийдөө эхлээд шинэ үзүүлэн рүү тодорхой слайдуудыг хуулах хэрэгтэй. Энэ нь хэтэрхий төвөгтэй юм. Тиймээс бид үүнийг нэг дор хэрэгжүүлэх аргыг танд үзүүлэх болно.

a-ийн тусгай слайдуудыг хавсаргана уу PowerPoint Имэйлд үзүүлэх танилцуулга

1. Эхлээд тодорхой зүйлийг нээнэ үү PowerPoint танилцуулга.
2. Дараа нь PowerPoint програмын цонхонд "Alt + F11" товчийг дарж VBA засварлагч руу нэвтэрнэ үү.
3. Дараа нь шинэ цонхонд "Оруулах" > ​​"Модуль" дээр дарж шинэ модуль үүсгэнэ үү.
4. Дараа нь дараахь VBA кодыг хуулж аваад энэ модуль дээр буулгана уу.

Sub AttachSpecificSlidesToOutlookEmail()
    Dim objActivePresetation As Presentation
    Dim objSlide As Slide
    Dim n As Long
    Dim strName As String
    Dim strTempPresetation As String
    Dim objTempPresetation As Presentation
    Dim objOutlookApp As Object
    Dim objMail As Object
 
    Set objActivePresetation = ActivePresentation
 
    For Each objSlide In objActivePresetation.Slides
        objSlide.Tags.Delete ("Selected")
    Next
 
    'Add a tag "Selected" to the selected slides
    For n = 1 To ActiveWindow.Selection.SlideRange.Count
        ActiveWindow.Selection.SlideRange(n).Tags.Add "Selected", "YES"
    Next n
 
    strName = objActivePresetation.Name
    strName = Left(strName, InStrRev(strName, ".") - 1)
    strTempPresetation = Environ("TEMP") & "\" & strName & ".pptx"
 
    'Copy the active presentation to a temp presentation
    objActivePresetation.SaveCopyAs strTempPresetation
    Set objTempPresetation = Presentations.Open(strTempPresetation)
 
    'Remove the untagged slides
    For n = objTempPresetation.Slides.Count To 1 Step -1
        If objTempPresetation.Slides(n).Tags("Selected") <> "YES" Then
           objTempPresetation.Slides(n).Delete
        End If
    Next n
 
    objTempPresetation.Save
    objTempPresetation.Close
 
    'Attach the temp presentation to a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objMail = objOutlookApp.CreateItem(olMailItem)
 
    'Change the email details as per your needs
    With objMail
         .To = "test@datanumen.com"
         .Subject = strName
         .Body = "Dear," & vbCr & vbCr & vbTab & "Specific slides are extracted and attached."
         .Attachments.Add strTempPresetation
         .Display
    End With
End Sub

5. Үүний дараа та одоогийн цонхыг хааж болно.
6. Дараа нь "Файл" > "Сонголтууд" > "Түргэн хандалтын хэрэгслийн мөр" рүү очиж, Хурдан нэвтрэх хэрэгслийн самбарт шинэ макро нэмнэ үү.
7. Эцэст нь та энэ макрог туршиж үзэх боломжтой.

• Эхлээд задлахыг хүссэн слайдуудаа сонгоно уу.
• Дараа нь Quick Access Toolbar дээрх макро товчийг дарна уу.
• Нэг дор Outlook имэйл гарч ирэх бөгөөд үүнд нь PowerPoint Эх сурвалжаас авсан танилцуулга.

Үр дүнтэй сэргээх хэрэгслийг ашигла

Бидний мэдэж байгаагаар Outlook нь суурилуулсан засварын хэрэгслээр хангагдсан байдаг - Сканнердах. Гэсэн хэдий ч энэ нь Outlook дээрх жижиг алдаануудыг даван туулж чадна. Хэрэв танд ноцтой хохирол учирсан бол энэ нь үр нөлөө үзүүлэхгүй. Энэ үед танд өөр хүчирхэг, найдвартай засварын хэрэгсэл, жишээ нь DataNumen Outlook Repair. Үүний тусламжтайгаар та гэмтсэн Outlook файлаа аврах боломжтой болно.

Зохиогчийн танилцуулга:

Ширли Жан бол мэдээлэл сэргээх мэргэжилтэн юм DataNumen, Үүнд мэдээлэл сэргээх технологиор дэлхийд тэргүүлэгч, Inc. гэмтсэн mdf програм хангамжийн бүтээгдэхүүнийг засах хэтийн төлөв. Дэлгэрэнгүй мэдээллийг авна уу WWW.datanumen.com