Outlook VBA ашиглан имэйлийг хариулах, дамжуулахад өөр өөр үсгийн өнгийг хэрхэн автоматаар ашиглах вэ

Анхдагч байдлаар, та Outlook-д имэйлд хариу илгээх, дамжуулахын тулд өөр өөр үсгийн өнгийг автоматаар ашиглахыг зөвшөөрөх боломжгүй. Тиймээс хэрэв танд ийм шаардлага байгаа бол энэ хost ухаалаг арга барилд суралцах.

Outlook нь зөвхөн имэйлд хариу илгээх, дамжуулахад ашигладаг фонтыг зааж өгөхийг зөвшөөрдөг. Та "Файл"> "Сонголтууд" руу очиж болно. Дараа нь "Outlook Options" хэсэгт "Мэйл" таб руу шилжиж, "Бичиг хэрэг ба фонтууд ..." товчийг дарна уу. Дараагийн цонхонд та "Хариулах эсвэл дамжуулах" хэсэгт "фонт" товчийг харж болно. Үүнийг товшоод, дараа нь та имэйлд хариу илгээх, дамжуулах тусгай үсгийн өнгийг тохируулж болно.

Гэсэн хэдий ч олон хэрэглэгчид имэйлд хариулах эсвэл дамжуулахдаа өөр өөр үсгийн өнгө ашиглахыг найдаж байна. Outlook нь үүнд зориулсан ямар ч шууд функцийг өгдөггүй ч VBA кодоор үүнийг хэрэгжүүлэх боломжтой хэвээр байна. Одоо VBA кодын ийм хэсгийг авахын тулд уншина уу.

Имэйлийг хариулах, дамжуулахад автоматаар өөр фонтыг ашиглана

1. Учир ньtart, Outlook програмыг ажиллуулна уу.
2. Дараа нь "VBA засварлагчийг ажиллуулна уу.Таны Outlook дээр VBA кодыг хэрхэн ажиллуулах вэ".
3. Дараа нь, "Обьектийг хэрхэн яаж нэмэх вэrary VBA-ийн лавлагаа", "MS Word Object Lib-д лавлагаа нэмнэ үүrary ”гэж бичжээ.
4. Дараа нь дараах кодыг "ThisOutlookSession" төсөл рүү хуулна уу.

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

5. Үүний дараа дахинtart Энэ макрог идэвхжүүлэх Outlook.
6. Эцэст нь та хичээгээд үзээрэй.

• Имэйл сонгох эсвэл нээх.
• Дараа нь "Хариу бичих" товчийг дарна уу. Та имэйлд хариу бичихдээ зарим үгийг үндсэн хэсэгт бичиж болно. Үсгийн өнгө нь ягаан байх ёстой.
• Эсвэл "Бүгдэнд хариулах" товчийг дарна уу. Шинэ "бүгдэнд хариулах" захидалд үгсийг үндсэн хэсэгт оруулна уу. Үсгийн өнгө нь гарцаагүй ногоон өнгөтэй байна.
• Үүний нэгэн адил "Урагшлах" товчийг дарна уу. Дамжуулах шуудан дээр шинэ үгс цэнхэр өнгөөр ​​харагдах болно.

Найдвартай програм хангамж руу хандаарай

Тохиолдолд Авлигын төлөв байдал, мost хэрэглэгчид Outlook сэргээх програм хангамжид хандах хандлагатай байдаг. Зах зээл дээр ийм олон тооны програмууд байдаг. Мөн зарим нь бүр үнэ төлбөргүй байдаг. Гэсэн хэдий ч та үл мэдэгдэх эх сурвалжаас авсан хүмүүсээс болгоомжлох хэрэгтэй, учир нь тэд одоогийн хэргийг улам дордуулж болзошгүй юм. Та найдвартай, туршлагатай хэрэгсэл гэх мэт тусламж авах хэрэгтэй DataNumen Outlook Repair.

Зохиогчийн танилцуулга:

Ширли Жан бол мэдээлэл сэргээх мэргэжилтэн юм DataNumen, Үүнд мэдээлэл сэргээх технологиор дэлхийд тэргүүлэгч, Inc. эвдэрсэн кв програм хангамжийн бүтээгдэхүүнийг засах хэтийн төлөв. Дэлгэрэнгүй мэдээллийг авна уу WWW.datanumen.com