Тодорхой хэдэн өдрийн дараа Outlook имэйлийг тодорхой илгээгчээс хэрхэн яаж устгах вэ

Outlook програмаа тодорхой өдрөөс эхлэн тодорхой илгээгчээс ирсэн имэйлийг автоматаар устгахыг зөвшөөрөхийн тулд та энэ нийтлэлийг уншиж болно. VBA кодыг авахын тулд ашиглах дэлгэрэнгүй алхмуудыг эндээс харуулах болно.

Имэйлийг автоматаар устгах тухайд та эхлээд "AutoArchive" функцын талаар бодож магадгүй юм. Гэхдээ энэ нь имэйлийг автоматаар архивлах үед тодорхой илгээгчдийг шүүж чадахгүй. Жишээлбэл, хэрэв та x өдрийн дараа тодорхой илгээгчийн имэйлийг автоматаар устгахыг хүсвэл дараахь хэрэгслийг ашиглах хэрэгтэй.

X хоногийн дараа тодорхой илгээгчээс имэйлийг автоматаар устгах

1. Хамгийн эхэнд Outlook програмаа ажиллуулна уу.
2. Дараа нь Outlook VBA редакторыг “Таны Outlook дээр VBA кодыг хэрхэн ажиллуулах вэ".
3. Дараа нь дараахь VBA кодыг “ThisOutlookSession” төсөлд хуулж ав.

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
 
    Call DeleteEmailsFromSpecificSenderAfterXDays
End Sub

Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'From the specific sender
       If objMail.SenderEmailAddress = "bob_black@datanumen.com" Then
          'Set expiry time - after 5 days
          objMail.ExpiryTime = objMail.ReceivedTime + 4
          objMail.Save
       End If
    End If
End Sub

Private Sub DeleteEmailsFromSpecificSenderAfterXDays()
    Dim strFilter As String
    Dim objExpiredItems As Outlook.Items
    Dim objExpiredMail As Outlook.MailItem
 
    strFilter = "[ExpiryTime] <= " & Chr(34) & Now & Chr(34)
 
    'Get all expired items
    Set objExpiredItems = objInboxItems.Restrict(strFilter)
 
    For i = objExpiredItems.Count To 1 Step -1
        If objExpiredItems(i).Class = olMail Then
           Set objExpiredMail = objExpiredItems(i)
 
           'Auto delete expired emails from the specific sender
           If objExpiredMail.SenderEmailAddress = "bob_black@datanumen.com" Then
              objExpiredMail.Delete
           End If
        End If
    Next
End Sub

4. Үүний дараа энэ макрог идэвхжүүлэхийн тулд Outlook-г дахин эхлүүлнэ үү.
5. Тэр үеэс хойш тодорхой илгээгчийн шинэ имэйл Ирсэн имэйлд ирэх бүрт хүлээн авах өдрөөс хойш тодорхой хоногийн хугацаа өгөх болно.
6. Дараа нь та Outlook-г эхлүүлэх бүрт Outlook нь тухайн илгээгчийн хугацаа нь дууссан имэйлийг автоматаар шалгаж, устгах болно.

Авлигын дараа Outlook өгөгдлийг сэргээнэ үү

Магадгүй та Outlook дээр янз бүрийн алдаа, бэрхшээлтэй тулгарсан байх. Дараа нь та Outlook-ийн авлигатай нүүр тулж байсан уу? Жишээлбэл, хэрэв та Outlook-оос байнга буруу гардаг бол таны PST файл гэмтэх хандлагатай байдаг. Ерөнхийдөө ийм тохиолдолд та нөөцөөс Outlook өгөгдлийг авахаар сонгож болно. Эсвэл та ашиглаж болно ирсэн хайрцаг засах хэрэгсэл гэх мэт найдвартай гадны хэрэгсэл DataNumen Outlook Repair.

Зохиогчийн танилцуулга:

Ширли Жан бол мэдээлэл сэргээх мэргэжилтэн юм DataNumen, Үүнд мэдээлэл сэргээх технологиор дэлхийд тэргүүлэгч, Inc. sql сэргээх програм хангамжийн бүтээгдэхүүнийг засах хэтийн төлөв. Дэлгэрэнгүй мэдээллийг авна уу WWW.datanumen.com