Нэг Excel ажлын дэвтэрт байгаа бүх ажлын хуудсыг тусдаа Outlook имэйл хэлбэрээр хэрхэн багцаар илгээх вэ

Хэрэв та Excel-ийн ажлын дэвтэр дэх бүх ажлын хуудсыг тусдаа Outlook имэйл хэлбэрээр илгээхийг хүсвэл энэ нийтлэлд танилцуулсан аргыг ашиглаж болно. Энэ нь таныг нэг нэгээр нь илгээхгүйгээр бөөнөөр нь ойлгоход тань туслах болно.

Миний өмнөх хost "Excel-ийн ажлын хуудсыг Outlook имэйлээр илгээх 2 хурдан арга”, та нэг Excel ажлын хуудсыг имэйлээр илгээх хоёр аргыг сурч болно. Хэрэв та нэг ажлын дэвтэрт байгаа бүх ажлын хуудсыг тус тусад нь имэйлээр илгээхийг хүсвэл энэ хуудсанд дурдсан хоёр арга хэрэгслийн аль нэгийг ашиглана.ost нэлээд уйтгартай, асуудалтай байх болно. Тиймээс бид "Багц илгээх"-ийг хурдан хугацаанд хэрэгжүүлэх өөр аргыг танилцуулах болно.

Нэг Excel ажлын дэвтэрт байгаа бүх ажлын хуудсыг тусдаа имэйлээр багцаар илгээнэ үү

1. Юуны өмнө та Excel-ийн ажлын номыг нээх хэрэгтэй.
2. Дараа нь Excel цонхонд орсны дараа та "Alt + F11" товчлол дээр дарах хэрэгтэй.
3. Дараа нь "Microsoft Visual Basic for Applications" нэртэй өөр цонх гарч ирнэ.
4. Үүн дээр та ашиглагдаагүй модулийг нээх эсвэл шинэ модуль оруулах хэрэгтэй.
5. Дараа нь та дараахь VBA кодыг энэ модуль руу хуулж болно.

Sub SendEachWorksheet_inOutlookEmail()
    Dim objWorksheet As Excel.Worksheet
    Dim objRange As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempFolder As String
    Dim strHTMLFile As String
    Dim objHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    For Each objWorksheet In ActiveWorkbook.Sheets
        Set objRange = objWorksheet.UsedRange
        objRange.Copy
 
        Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
        Set objTempWorksheet = objTempWorkbook.Sheets(1)
        With objTempWorksheet.Cells(1)
             .PasteSpecial xlPasteValues
             .PasteSpecial xlPasteColumnWidths
             .PasteSpecial xlPasteFormats
        End With
 
        strTempFolder = CStr(Environ("USERPROFILE")) & "\AppData\Local\Temp"
        strHTMLFile = strTempFolder & "\Temp" & Format(Now, "yyyymmddhhmmss") & ".htm"
        Set objHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
        objHTMLFile.Publish (True)
 
        Set objOutlookApp = CreateObject("Outlook.Application")
        Set objMail = objOutlookApp.CreateItem(olMailItem)
 
        Set objFileSystem = CreateObject("Scripting.FileSystemObject")
        Set objTextStream = objFileSystem.OpenTextFile(strHTMLFile)
        objMail.HTMLBody = objTextStream.ReadAll
 
        'Change the email details as per your needs
        With objMail
             .To = "test@datanumen.com"
             .Subject = objWorksheet.Name
             .Display
        End With
 
        objTextStream.Close
        objTempWorkbook.Close False
        Kill strHTMLFile
    Next
End Sub

6. Үүний дараа та F5 товчийг дарж эсвэл хэрэгслийн самбар дээрх "Ажиллуулах" дүрс дээр дарж энэ макро эхлүүлж болно.
7. Энэ Excel-ийн ажлын дэвтрийн бүх ажлын хуудсанд тохирох имэйлүүд Outlook дээр нэгэн зэрэг гарч ирнэ.
8. Эцэст нь та бүх имэйлийн дэлгэрэнгүй мэдээллийг дахин шалгаж, хамгийн сүүлд "Илгээх" товчийг дарж имэйл илгээх боломжтой.

Хэрэв нөөцлөлт байхгүй бол хүчирхэг сэргээх хэрэгслийг ашиглана уу

Өгөгдөл нөөцлөхийн ач холбогдлыг улам олон хэрэглэгчид ойлгосон. Та PST файлаа нөөцөлсөн л бол PST сэргээх гэмтлийн дараа маш энгийн байх болно. Гэхдээ үр дүнтэй, шинэчлэгдсэн PST нөөц байхгүй бол та гадны PST засварын хэрэгсэл, жишээ нь, тусламж авахаас өөр аргагүй болно. DataNumen Outlook Repair. Энэ нь эвдэрсэн PST файлуудыг сэвшээ салхи шиг засах боломжтой.

Зохиогчийн танилцуулга:

Ширли Жан бол мэдээлэл сэргээх мэргэжилтэн юм DataNumen, Үүнд мэдээлэл сэргээх технологиор дэлхийд тэргүүлэгч, Inc. sql сэргээх програм хангамжийн бүтээгдэхүүнийг засах хэтийн төлөв. Дэлгэрэнгүй мэдээллийг авна уу WWW.datanumen.com