Тодорхой домэйн бүхий бүх имэйл хаягийг Outlook харилцагчдаас хэрхэн яаж багц аргаар устгах вэ

Заримдаа та тодорхой домэйнтэй бүх имэйл хаягийг харилцагчаасаа устгах болно гэж найдаж магадгүй юм. Ийм нөхцөлд та үүнийг нэг нэгээр нь хийх хүсэлгүй байх ёстой. Тиймээс энэ хost танд илүү ухаалаг аргыг заах болно.

Жишээлбэл, компани нэрээ өөрчилдөг. Үүний зэрэгцээ компанийн домэйн өөрчлөгддөг. Гэсэн хэдий ч Outlook дээр та имэйл хаяг нь хуучин домэйнд байдаг олон компанийг энэ компанид хадгалсан болно. Мэдээжийн хэрэг эдгээр имэйл хаяг хүчингүй болсон. Ийм нөхцөлд, хэрэв та эдгээр имэйл хаягийг нэг дор устгахыг хүсвэл дараах аргыг ашиглаж болно.

Тодорхой домэйн бүхий бүх имэйл хаягийг Харилцагчдаас устгах

1. Учир ньtart, Outlook VBA засварлагч руу "Alt + F11" товчлолоор нэвтрэх.
2. Дараа нь шинэ цонхонд дараах VBA кодыг хоосон модульд байрлуулна уу.

Dim strDomain As String

Sub BatchRemoveAllEmailAddressesInSpecificDomain()
    Dim objStore As Store
    Dim objFolder As Folder
    Dim lTotalCount As Long
 
    'Input the specific domain
    strDomain = InputBox("Enter the specific domain:", , "@false.com")
 
    If Len(strDomain) <> 0 Then
       lTotalCount = 0
       'Process all Contact folders in your Outlook
       For Each objStore In Application.Session.Stores
           For Each objFolder In objStore.GetRootFolder.Folders
               If objFolder.DefaultItemType = olContactItem Then
                  Call ProcessContactFolders(objFolder, lTotalCount)
               End If
           Next
       Next
 
       'Prompt you
       MsgBox lTotalCount & " email addresses in " & strDomain & " are removed!", vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessContactFolders(ByVal objCurrentFolder As Folder, ByRef lCount As Long)
    Dim objContacts As Items
    Dim i As Long
    Dim objContact As ContactItem
 
    Set objContacts = objCurrentFolder.Items
 
    For i = objContacts.Count To 1 Step -1
        If TypeName(objContacts(i)) = "ContactItem" Then
           Set objContact = objContacts(i)
 
           'Check 3 email addresses of each contact
           If InStr(objContact.Email1Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email1Address = ""
              objContact.Email1DisplayName = ""
           ElseIf InStr(objContact.Email2Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email2Address = ""
              objContact.Email2DisplayName = ""
           ElseIf InStr(objContact.Email3Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email3Address = ""
              objContact.Email3DisplayName = ""
           End If
 
           objContact.Save
        End If
     Next
 
     If objCurrentFolder.Folders.Count > 0 Then
        For Each objSubfolder In objCurrentFolder.Folders
            Call ProcessContactFolders(objSubfolder, lCount)
        Next
     End If
End Sub

3. Үүний дараа курсорыг "BatchRemoveAllEmailAddressesInSpecificDomain" дэд програмд ​​оруулна уу.
4. Эцэст нь "F5" товчлуур дээр дарж энэ макрог идэвхжүүлнэ үү.
5. Үүний дараа гарч ирэх харилцах цонхыг тодорхой домэйнд оруулна уу.
6. "OK" дээр дарсны дараа макро ажиллах болно.
7. Үүнийг дуусгасны дараа танд үр дүнгийн талаар мессеж ирэх болно.
8. Одоо та харилцагчдыг шалгаж болно. Тодорхой домэйнтэй бүх имэйл хаяг алга болсон байх ёстой.

Outlook файлаа хадгална уу

Таны Outlook -ийг тойрсон эрсдэл улам бүр нэмэгдсээр байгаа тул Outlook -ийн үнэ цэнэтэй өгөгдлөө хамгаалах нь улам бүр хэцүү болж байна. Жишээлбэл, та өгөгдлийн нөөцлөлтийг тогтмол хийж байхаас гадна үйл ажиллагаандаа анхааралтай хандах хэрэгтэй. Үл мэдэгдэх илгээгчдийн имэйлд шууд итгэх нь ухаалаг хэрэг биш юм. Үгүй бол энэ нь вирус агуулсан бол таны Outlook файл халдвар авах болно. Тэр үед та хичээх хэрэгтэй Outlook засвар гэх мэт гайхалтай засах хэрэгслээр дамжуулан DataNumen Outlook Repair.

Зохиогчийн танилцуулга:

Ширли Жан бол мэдээлэл сэргээх мэргэжилтэн юм DataNumen, Үүнд мэдээлэл сэргээх технологиор дэлхийд тэргүүлэгч, Inc. сэргээх Sql Server програм хангамжийн бүтээгдэхүүнийг засах хэтийн төлөв. Дэлгэрэнгүй мэдээллийг авна уу WWW.datanumen.com